Arduino:Примеры/Web AjaxBuzzer

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску
Версия для печати больше не поддерживается и может содержать ошибки обработки. Обновите закладки браузера и используйте вместо этого функцию печати браузера по умолчанию.

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Управление зуммером через браузерный интерфейс (AJAX)[1]

Этот пример показывает, как воспроизводить звуки с помощью библиотеки Webduino, Ethernet-модуля и зуммера. Продолжительность звука задается пользователем через интерфейс в браузере (с использованием подхода AJAX).

Код

/* Управление зуммером через браузерный интерфейс (AJAX)(Webduino) */

#include "SPI.h"
#include "Ethernet.h"
#include "WebServer.h"

// ПОСТАВЬТЕ ЗДЕСЬ СОБСТВЕННОЕ ЗНАЧЕНИЕ:
static uint8_t mac[6] = { 0x02, 0xAA, 0xBB, 0xCC, 0x00, 0x22 };

// ВЫСТАВЬТЕ ТУТ ЗНАЧЕНИЕ, СООТВЕТСТВУЮЩЕЕ СЕТИ ВАШЕГО ХОСТА:
static uint8_t ip[4] = { 192, 168, 1, 210 }; // area 51!

/* Все URL этого сервера будут начинаться с /buzz, потому что именно
 * так мы определили значение PREFIX. Мы также будем прослушивать 
 * порт 80, стандартный порт для HTTP */
#define PREFIX "/buzz"
WebServer webserver(PREFIX, 80);

/* Пьезодинамик подключен к 3-ому контакту Ethernet-модуля */
#define BUZZER_PIN 3

/* Это количество микросекунд, в течение которых будет работать 
 * динамик после включения и до выключения */
int buzzDelay = 0;

/* Переключатель, используемый только для включения динамика при 
 * каждом проходе через блок loop() */ 
char toggle = 0;

/* Это команда, используемая сервером по умолчанию. Она обрабатывает 
 * запросы GET и POST. При запросе GET она возвращает простую страницу 
 * с несколькими кнопками. При запросе POST она сохраняет полученное 
 * значение в переменную buzzDelay, тем самым меняя продолжительность 
 * звука, издаваемого динамиком */
void buzzCmd(WebServer &server, WebServer::ConnectionType type, char *, bool)
{
  if (type == WebServer::POST)
  {
    bool repeat;
    char name[16], value[16];
    do
    {
      /* Если данных, доступных для считывания, нет, то функция 
       * readPOSTparam() возвращает «false». Мы указываем в ней 
       * буферы для хранения строковых значений «name» и «value», 
       * а также длину этих буферов. */
      repeat = server.readPOSTparam(name, 16, value, 16);

      /* Это стандартная функция для сравнения строк. При точном 
       * соответствии она возвращает «0». Мы обращаемся к ней, 
       * спрашивая соответствие с параметром «buzz» */
      if (strcmp(name, "buzz") == 0)
      {
	/* Используем функцию strtoul(), чтобы преобразовать числовую  
	 * строку в целое число для переменной buzzDelay */
        buzzDelay = strtoul(value, NULL, 10);
      }
    } while (repeat);
    
    // Обработав данные запроса POST, приказываем браузеру 
    // перезагрузить страницу при помощи метода GET:
    server.httpSeeOther(PREFIX);
    return;
  }

  /* при запросе GET или HEAD отправляем стандартное сообщение, что запрос был успешным. */
  server.httpSuccess();

  /* при запросе HEAD не показываем контент страницы */
  if (type == WebServer::GET)
  {
    /* сохраняем HTML в программной памяти при помощи макроса P() */
    P(message) = 
"<!DOCTYPE html><html><head>"
  "<title>Webduino AJAX Buzzer Example</title>"
  "<link href='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/themes/base/jquery-ui.css' rel=stylesheet />"
  //"<meta http-equiv='Content-Script-Type' content='text/javascript'>"
  "<script src='http://ajax.googleapis.com/ajax/libs/jquery/1.6.4/jquery.min.js'></script>"
  "<script src='http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.16/jquery-ui.min.js'></script>"
  "<style> #slider { margin: 10px; } </style>"
  "<script>"
    "function changeBuzz(event, ui) { $('#indicator').text(ui.value); $.post('/buzz', { buzz: ui.value } ); }"
    "$(document).ready(function(){ $('#slider').slider({min: 0, max:8000, change:changeBuzz}); });"
  "</script>"
"</head>"
"<body style='font-size:62.5%;'>"
  "<h1>Test the Buzzer!</h1>"
  "<div id=slider></div>"
  "<p id=indicator>0</p>"
"</body>"
"</html>";

    server.printP(message);
  }
}

void setup()
{
  // задаем контакт для зуммера и выставляем его в режим OUTPUT:
  pinMode(BUZZER_PIN, OUTPUT);

  // инициируем коммуникацию между библиотекой Ethernet и платой Wiznet:
  Ethernet.begin(mac, ip);

  /* регистрируем команду, вызываемую по умолчанию (активируется при запросе http://x.x.x.x/buzz). */
  webserver.setDefaultCommand(&buzzCmd);

  /* приказываем серверу ждать подключений */
  webserver.begin();
}

void loop()
{
  // вечно обрабатываем входящие соединения (по одному за раз):
  webserver.processConnection();

  /* если задержка не выставлена на «0», при каждом проходе через
   * блок loop() включаем и выключаем динамик. */
  if ((++toggle & 1) && (buzzDelay > 0))
  {
    digitalWrite(BUZZER_PIN, HIGH);
    delayMicroseconds(buzzDelay);
    digitalWrite(BUZZER_PIN, LOW);
  }
}

См.также

Внешние ссылки