Arduino:Примеры/WiFiWebServer

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Веб-сервер при помощи WiFi Shield[1]

В этом примере вы при помощи платы Arduino и модуля WiFi Shield создадите простой веб-сервер. Также понадобится библиотека WiFi, с помощью которой ваш девайс сможет отвечать на HTTP-запросы. Когда все будет готово, откройте браузер и введите в адресную строку IP-адрес вашего WiFi Shield, после чего Arduino ответит HTML-кодом, с помощью которого отобразит входные данные ото всех шести аналоговых контактов.

Этот пример написан для работы с сетями, использующими WPA-шифрование. Если вы используете WEP-зашифрованную сеть, соответствующим образом поменяйте функцию Wifi.begin().

Необходимое оборудование

  • Сетевой модуль Arduino WiFi Shield;
  • Плата Arduino, совместимая с WiFi Shield;
  • 6 аналоговых датчиков, присоединенных к аналоговым контактам Arduino (с 0-ого по 5-ый) – опционально;

Цепь

WiFi Shield для SPI-соединения с модулем HDG104 использует 10-ый, 11-ый, 12-ый и 13-ый контакты. Для управления SS-контактом SD-карты используется 4-ый цифровой контакт.

Также для этого примера понадобится доступ к 802.11b/g сети, подключенной к интернету. Кроме того, в скетче надо будет поменять сетевые настройки, чтобы они соответствовали сети, к которой вы собираетесь подключиться.

Для сетей, использующих шифрование через WPA и WPA Personal, понадобятся SSID и пароль. К сети, использующей шифрование через WPA Enterprise, Shield подключиться не сможет.

Пароли к сетям с WEP-шифрованием – это шестнадцатеричные строки, называемые «ключами». Причем WEP-сеть может иметь 4 разных ключа, каждому из которых будет присвоен свой собственный «индекс». Таким образом, для WEP-зашифрованных сетей вам понадобятся SSID, ключ и индекс ключа.

На картинке выше сетевой модуль WiFi Shield установлен поверх платы Arduino.

Внимание

Для этого примера не требуется SD-карта. Однако, если карта будет вставлена, но использоваться не будет, скетч может зависнуть, потому что 4-ый контакт используется как SS-контакт (активация через LOW) SD-карты, а будучи неиспользованным, он по умолчанию выставляется в INPUT. Два возможных решения:

  • Выньте SD-карту;
  • Добавьте в блок setup() следующие строчки кода:
pinMode(4, OUTPUT);
digitalWrite(4, HIGH);

Код

/*
Веб-сервер с помощью WiFi Shield
 
Простой веб-сервер, который при помощи модуля WiFi Shield показывает
значения от входных аналоговых контактов.

Этот пример написан для работы с WPA-зашифрованными сетями.
Если вы имеете дело с WEP-зашифрованной сетью, просто
соответствующим образом поменяйте функцию Wifi.begin().

Цепь:
* WiFi Shield, подключенный к Arduino
* Аналоговые датчики, подключенные к контактам с A0 по A5 (опционально)

Создан 13 июля 2010 пользователем dlf (Metodo2 srl),
модифицирован 31 мая 2012 Томом Иго (Tom Igoe).
*/

#include <SPI.h>
#include <WiFi.h>


char ssid[] = "yourNetwork";      // название (SSID) вашей сети 
char pass[] = "secretPassword";   // пароль к вашей сети
int keyIndex = 0;                 // индекс ключа к вашей сети (нужно только для WEP)

int status = WL_IDLE_STATUS;

WiFiServer server(80);

void setup() {
  // Инициализируем последовательную передачу данных и ждем открытия порта:
  Serial.begin(9600); 
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для Leonardo)
  }
  
  // Проверяем наличие WiFi Shield
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");  //  "WiFi Shield не подключен"
    // Дальше не продолжаем:
    while(true);
  } 
 
  // Пробуем подключиться к WiFi-сети:
  while ( status != WL_CONNECTED) { 
    Serial.print("Attempting to connect to SSID: ");  //  "Пытаемся подключиться к SSID: "
    Serial.println(ssid);
    // Подключаемся к сети зашифрованной через WPA или WPA2.  
    // Если вы подключаетесь к WEP-зашифрованной сети, нижеследующую строчку кода надо будет подредактировать:    
    status = WiFi.begin(ssid, pass);

    // Ждем подключения 10 секунд:
    delay(10000);
  } 
  server.begin();
  // Итак, мы подключились, поэтому выводим на Serial Monitor
  // информацию о сети и сетевом оборудовании:
  printWifiStatus();
}


void loop() {
  // Прослушиваем подключающихся клиентов:
  WiFiClient client = server.available();
  if (client) {
    Serial.println("new client");    //  "Новый клиент"
    // HTTP-запрос заканчивается пустой строкой:
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // Если вы добрались до конца строки (получили символ новой строки),
        // и эта строка – пустая, значит это конец HTTP-запроса,
        // и, следовательно, мы можем приступить к отправке ответа:
        if (c == '\n' && currentLineIsBlank) {
          // Отправляем стандартный заголовок для HTTP-ответа:
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // после выполнения запроса соединение будет отключено
          client.println("Refresh: 5");  // автоматически обновляем страницу каждые 5 секунд
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // Показываем данные от всех аналоговых датчиков:
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");       
          }
          client.println("</html>");
           break;
        }
        if (c == '\n') {
          // Вы начинаете новую строчку:
          currentLineIsBlank = true;
        } 
else if (c != '\r') {
          // В текущей строке еще есть символы:
          currentLineIsBlank = false;
        }
      }
    }
    // Даем браузеру время, чтобы получить данные:
    delay(1);
    
    // Отключаем соединение:
    client.stop();
    Serial.println("client disonnected"); //  "Клиент отключился"
  }
}

// Пользовательская функция для отображения на Serial Monitor
// информации о сети и используемом сетевом оборудовании:
void printWifiStatus() {
  // Показываем SSID (название) сети, к которой подключились:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // Показываем IP-адрес WiFi Shield:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");  //  "IP-адрес: "
  Serial.println(ip);

  // Показываем мощность приемного сигнала:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");  //  "Мощность сигнала (RSSI): "
  Serial.print(rssi);
  Serial.println(" dBm");
}

См.также

  1. ConnectNoEncryption : Demonstrates how to connect to an open network
  2. ConnectWithWEP : Demonstrates how to connect to a network that is encrypted with WEP
  3. ConnectWithWPA : Demonstrates how to connect to a network that is encrypted with WPA2 Personal
  4. ScanNetworks : Displays all WiFi networks in range
  5. WiFiChatServer : Set up a simple chat server
  6. WiFiWebClient : Connect to a remote webserver
  7. WiFiWebClientRepeating: Repeatedly make HTTP calls to a server
  8. WiFiWebServer : Serve a webpage from the WiFi shield

Внешние ссылки