Электронный компонент:Набор компонентов Grove Speech Recognizer для распознавания речи

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 1892 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Набор компонентов Grove Speech Recognizer для распознавания речи[1]

Grove Speech Recognizer cover 1.jpg

Этот набор предназначен для конструирования Arduino-проектов в области умного дома. Он состоит из базовых устройств для домашней автоматизации вроде распознавателя речи, ИК-передатчика и т.д. Также в комплекте есть руководство с инструкциями по сборке нескольких демо-проектов – например, для проигрывания музыки после голосовой команды «Включить музыку» или включения освещения после голосовой команды «Включить свет».

Купить набор Grove Speech Recognizer можно по этой ссылке.

Список компонентов

Пример использования: Включение телевизора

Иногда некоторыми системами хочется управлять не с помощью пультов, а голосовыми командами. В пультах используется, как правило, управление при помощи ИК-излучения, поэтому сначала нам нужно узнать, какой код запускается при нажатии на каждую кнопку пульта, а затем поместить этот код в нашу программу. В результате голос будет активировать код кнопок, благодаря чему системами можно будет управлять аналогично тому, как это происходит при помощи пульта дистанционного управления.

Для проекта понадобятся следующие компоненты:

Извлечение кода кнопок при помощи Grove-модуля с ИК-приемником

Сначала загрузите библиотеку «IRSendRev». Для этого кликните в IDE Arduino на Скетч > Подключить библиотеку... > Добавить .ZIP библиотеку (Sketch > Include Library > Add .ZIP Library...), а затем в открывшемся меню выберите скачанный ZIP-архив с библиотекой и нажмите на кнопку «Open». Далее выполните следующие действия:

  • Откройте скетч-пример «recv». Для этого кликните в IDE Arduino на Файл > Примеры > IRSendRev > recv (File > Examples > IRSendRev > recv)
  • Загрузите скетч в Arduino Uno
  • Подключите базовый Grove-шилд к Arduino Uno. Затем подключите Grove-модуль с ИК-приемником к порту D2 на шилде. Вы можете подключить его к другому порту, но тогда нужно будет поменять в коде номер контакта:
const int pinRecv = 2;
  • Откройте монитор порта IDE Arduino

Теперь нажмите на пульте какую-нибудь кнопку. В результате монитор порта должен показать подробную информацию о коде кнопки, которая была нажата. Это выглядит примерно так:

IR Receiver IR controller 2.png

Скопируйте куда-нибудь информацию о коде кнопки. Если конкретнее, нам понадобятся следующие данные:

+------------------------------------------------------+
LEN = 9
START_H: 179    START_L: 88
DATA_H: 11    DATA_L: 33

DATA_LEN = 4
DATA: 0x80    0x7E    0x10    0xEF
DATA: 128    126    16    239
+------------------------------------------------------+

Редактирование скетча-примера

Теперь давайте воспользуемся добытой информацией о коде кнопки:

Во-первых, отредактируйте данные о кнопке:

  1. unsigned char dtaSend[20];
  2.  
  3. void dtaInit()
  4. {
  5.   ............
  6. }

Во-вторых, отредактируйте эту информацию согласно данным, извлеченным благодаря ИК-приемнику:

  1. unsigned char dtaSend[20];
  2.  
  3. void dtaInit()
  4. {
  5.     dtaSend[BIT_LEN]        = 9;    // размер буфера (не считая
  6.                                     // самих данных о размере буфера)
  7.     dtaSend[BIT_START_H]    = 179;  // время стартового сигнала HIGH
  8.     dtaSend[BIT_START_L]    = 88;   // время стартового сигнала LOW
  9.     dtaSend[BIT_DATA_H]     = 11;   // время «длинного» сигнала
  10.     dtaSend[BIT_DATA_L]     = 33;   // время «короткого» сигнала
  11.  
  12.     dtaSend[BIT_DATA_LEN]   = 4;    // количество отправляемых данных;
  13.                                     // если оно другое, вам нужно
  14.                                     // уменьшить или увеличить
  15.                                     // количество dtaSend[BIT_DATA+x]
  16.  
  17.     dtaSend[BIT_DATA+0]     = 128;  // отправляемые данные
  18.     dtaSend[BIT_DATA+1]     = 126;
  19.     dtaSend[BIT_DATA+2]     = 16;
  20.     dtaSend[BIT_DATA+3]     = 239;
  21.     //dtaSend[BIT_DATA+4]     = 192;
  22.     //dtaSend[BIT_DATA+5]     = 63;
  23. }

Количество отправляемых данных равно «4»:

DATA_LEN = 4

Поэтому две последние строчки можно удалить:

    //dtaSend[BIT_DATA+4]     = 192;
    //dtaSend[BIT_DATA+5]     = 63;

Разумеется, можно задать и другие кнопки:

  1. #include <IRSendRev.h>
  2.  
  3. #define BIT_LEN         0
  4. #define BIT_START_H     1
  5. #define BIT_START_L     2
  6. #define BIT_DATA_H      3
  7. #define BIT_DATA_L      4
  8. #define BIT_DATA_LEN    5
  9. #define BIT_DATA        6
  10.  
  11. const int ir_freq = 38;
  12.  
  13. unsigned char OpenTV[20];
  14. unsigned char CloseTV[20];
  15. unsigned char IncreaseTemp[20];
  16. unsigned char DecreaseTemp[20];
  17.  
  18. void OpenTVInit()
  19. {
  20.     OpenTV[BIT_LEN]        = 11;
  21.     OpenTV[BIT_START_H]    = 179;
  22.     /*............ пропуск ............*/
  23. }
  24.  
  25. void CloseTVInit()
  26. {
  27.     CloseTV[BIT_LEN]        = 11;
  28.     CloseTV[BIT_START_H]    = 179;
  29.     /*............ пропуск ............*/
  30. }
  31.  
  32. void IncreaseTempInit()
  33. {
  34.     IncreaseTemp[BIT_LEN]        = 11;
  35.     IncreaseTemp[BIT_START_H]    = 179;
  36.     /*............ пропуск ............*/
  37. }
  38.  
  39. void DecreaseTempInit()
  40. {
  41.     DecreaseTemp[BIT_LEN]        = 11;
  42.     DecreaseTemp[BIT_START_H]    = 179;
  43.    /*............ пропуск ............*/
  44. }
  45.  
  46. void setup()
  47. {
  48.     OpenTVInit();
  49.     CloseTVInit();
  50.     IncreaseTempInit();
  51.     DecreaseTempInit();
  52. }
  53.  
  54. void loop()
  55. {
  56.     IR.Send(OpenTV, 38);
  57.     delay(200);
  58.     IR.Send(CloseTV, 38);
  59.     delay(200);
  60.     IR.Send(IncreaseTemp, 38);
  61.     delay(200);
  62.     IR.Send(DecreaseTemp, 38);
  63.  
  64.     delay(2000);
  65. }

Добавление в скетч-пример распознавателя речи

Таблица ниже содержит значения, возвращаемые распознавателем речи при считывании разных голосовых команд.

Команда Возвращаемое значение
Turn on the light (Включить свет) 1
Turn off the light (Выключить свет) 2
Play music (Проиграть музыку) 3
Pause (Пауза) 4
Next (Следующий) 5
Previous (Предыдущий) 6
Up (Вверх) 7
Down (Вниз) 8
Turn on the TV (Включить телевизор) 9
Turn off the TV (Выключить телевизор) 10
Increase temperature (Увеличить температуру) 11
Decrease temperature (Уменьшить температуру) 12
What’s time (Сколько время) 13
Open the door (Открыть дверь) 14
Close the door (Закрыть дверь) 15
Left (Влево) 16
Right (Вправо) 17
Stop (Стоп) 18
Start (Старт) 19
Mode one (Режим номер один) 20
Mode two (Режим номер два) 21
Go (Вперед) 22

Скетч-пример ниже использует команды «Turn on the TV» (т.е. «Включить телевизор») и «Turn off the TV» (т.е. «Выключить телевизор»).

Сначала определяем код кнопок для включения/выключения телевизора, а затем добавляем соответствующий код в скетч-пример «send». В итоге скетч-пример должен выглядеть следующим образом:

  1. #include <IRSendRev.h>
  2. #include <SoftwareSerial.h>
  3.  
  4. /*======== Исходные данные для пульта ========*/
  5.  
  6. #define BIT_LEN         0
  7. #define BIT_START_H     1
  8. #define BIT_START_L     2
  9. #define BIT_DATA_H      3
  10. #define BIT_DATA_L      4
  11. #define BIT_DATA_LEN    5
  12. #define BIT_DATA        6
  13. const int ir_freq = 38;                 //  38 кГц
  14.  
  15. /* ========  Используемые кнопки  ========*/
  16.  
  17. unsigned char OpenTV[20];
  18. unsigned char CloseTV[20];
  19.  
  20.  
  21. /*=========  Контакты для распознавателя речи  ==========*/
  22.  
  23. #define SOFTSERIAL_RX_PIN  5
  24. #define SOFTSERIAL_TX_PIN  6
  25.  
  26. SoftwareSerial speech(SOFTSERIAL_RX_PIN,SOFTSERIAL_TX_PIN);
  27.  
  28.  
  29. /* =======  Запись ИК-данных  ========*/
  30. /* ====  Получить их можно с помощью ИК-ресивера  ==== */
  31.  
  32. void OpenTVInit()
  33. {
  34.     OpenTV[BIT_LEN]        = 9;    // размер буфера (не считая
  35.                                    // самих данных о размере буфера)
  36.     OpenTV[BIT_START_H]    = 180;  // время стартового сигнала HIGH
  37.                                    // для «Включить телевизор»  
  38.     OpenTV[BIT_START_L]    = 88;   // время стартового сигнала LOW
  39.                                    // для «Включить телевизор»  
  40.     OpenTV[BIT_DATA_H]     = 11;   // время «длинного» сигнала
  41.     OpenTV[BIT_DATA_L]     = 33;   // время «короткого» сигнала
  42.  
  43.     OpenTV[BIT_DATA_LEN]   = 4;    // количество отправляемых данных;
  44.                                    // если оно другое, вам нужно
  45.                                    // уменьшить или увеличить
  46.                                    // количество OpenTV[BIT_DATA+x]
  47.  
  48.     OpenTV[BIT_DATA+0]     = 50;   // отправляемые данные
  49.     OpenTV[BIT_DATA+1]     = 166;
  50.     OpenTV[BIT_DATA+2]     = 80;
  51.     OpenTV[BIT_DATA+3]     = 175;
  52. }
  53.  
  54. void CloseTVInit()
  55. {
  56.     CloseTV[BIT_LEN]        = 9;    // размер буфера (не считая
  57.                                     // самих данных о размере буфера)
  58.     CloseTV[BIT_START_H]    = 178;  // время стартового сигнала HIGH
  59.                                     // для «Выключить телевизор»  
  60.     CloseTV[BIT_START_L]    = 89;   // время стартового сигнала LOW
  61.                                     // для «Выключить телевизор»  
  62.     CloseTV[BIT_DATA_H]     = 10;   // время «длинного» сигнала
  63.     CloseTV[BIT_DATA_L]     = 33;   // время «короткого» сигнала
  64.  
  65.     CloseTV[BIT_DATA_LEN]   = 4;    // количество отправляемых данных;
  66.                                     // если оно другое, вам нужно
  67.                                     // уменьшить или увеличить
  68.                                     // количество CloseVT[BIT_DATA+x].
  69.  
  70.     CloseTV[BIT_DATA+0]     = 50;   // отправляемые данные
  71.     CloseTV[BIT_DATA+1]     = 166;
  72.     CloseTV[BIT_DATA+2]     = 168;
  73.     CloseTV[BIT_DATA+3]     = 87;
  74. }
  75.  
  76.  
  77. void setup()
  78. {
  79.     OpenTVInit()
  80.     CloseTVInit()
  81.     Serial.begin(9600);
  82.     speech.begin(9600);
  83.     speech.listen();
  84. }
  85.  
  86. void loop()
  87. {
  88.     int a=0;
  89.  
  90.     if(speech.available())
  91.     {
  92.         a = speech.read();  // считываем значение, которое вернул
  93.                             // распознаватель речи
  94.         switch (a)
  95.         {
  96.             case 9:         //  если (возвращаемое значение),
  97.                             //  то отправляем ИК-данные
  98.             IR.Send(OpenTV, 38);
  99.             delay(1000);
  100.             break;
  101.             case 10:
  102.             IR.Send(CloseTV, 38);
  103.             delay(1000);
  104.             break;
  105.             default:
  106.             break;
  107.         }
  108.     }
  109. }

Пример использования: Управление музыкой

Как видите, в таблице возвращаемых значений (см. выше) много команд, связанных с музыкой – вроде «Play music», «Pause», «Stop», «Previous», «Next». Давайте попробуем сделать проект, демонстрирующий использование этих команд.

Во-первых, загрузите и установите библиотеку «Grove_Serial_MP3_Player_V2.0». Сделайте это, кликнув в IDE Arduino на Скетч > Подключить библиотеку... > Добавить .ZIP библиотеку (Sketch > Include Library > Add .ZIP Library...), а затем в открывшемся меню выбрав скачанный ZIP-архив с библиотекой и нажав на кнопку «Open».

Полезные функции для использования Grove-модуля MP3 V2

Библиотека «Grove_Serial_MP3_Player_V2.0» имеет несколько удобных функций для управления Grove-модулем MP3 V2.0. Самые основные перечислены ниже:

  • Функция PlayPause()
    • Проигрывание музыки.
  • Функция PlayResume()
    • Возобновление проигрывания музыки.
  • Функция PlayNext()
    • Переход к следующей песне.
  • Функция PlayPrevious()
    • Переход к предыдущей песне.
  • Функция PlayLoop()
    • Проигрывание всех песен по кругу.
  • Функция SetVolume(uint8_t volume)
    • Задает громкость. Значение по умолчанию – «0x0E», диапазон допустимых значений – от «0x00» до «0x1E».
  • Функция IncreaseVolume()
    • Увеличивает громкость.
  • Функция DecreaseVolume()
    • Уменьшает громкость.

Кроме того, в библиотеке есть и более специализированные функции, на которые тоже стоит обратить внимание:

  • Функция SelectPlayerDevice(uint8_t device)
    • Выбирает SD-карту, с которой будет проигрываться музыка. Значение по умолчанию – «0x02».
  • Функция SpecifyMusicPlay(uint16_t index)
    • Выбирает трек, который нужно включить, по названию файла. Названия треков должны быть заданы определенным образом (см. картинку ниже). Таким образом, в аргументе можно указать, например, значение «005».
Type of songs 3.png
  • Функция SpecifyfolderPlay(uint8_t folder, uint8_t index)
    • Выбирает трек, который нужно включить, по названиям папки и файла.
Form of folder 3.png

Примечание: Диапазон значений для папок варьируется между «01» и «99». Следовательно, названия папок, используемые этой библиотекой, могут быть только в диапазоне между «01» и «99». Обратите внимание, что у первых десяти значений первой цифрой должен быть «0», т.е. они должны выглядеть как «01», «02», «03» и т.д.

Таким образом, чтобы проиграть трек «005» в папке «01», в скетч нужно вписать такую функцию:

SpecifyfolderPlay(1,5);

Кроме того, каждая песня длится определенное время, поэтому если вы хотите, чтобы несколько песен проигрывалось друг за другом, можно воспользоваться двумя способами:

  1. delay(время) – задает задержку, пока трек не закончится
  2. while(QueryPlayStatus() != 0) – если функция QueryPlayStatus() возвращает «0», то трек закончился, а если «1», то еще не закончился

Как правило, легче использовать второй способ:

SpecifyMusicPlay(1);
while(QueryPlayStatus() != 0);
SpecifyMusicPlay(2);
while(QueryPlayStatus() != 0);
SpecifyMusicPlay(3);
while(QueryPlayStatus() != 0);

Скетч

Окей, а теперь давайте объединим MP3-плеер с распознавателем речи. Скетч ниже позволяет управлять некоторыми функциями MP3-плеера: проигрыванием музыки, паузой, возобновлением, переключением на следующую песню и переключением на предыдущую песню.

  1. #include <SoftwareSerial.h>
  2. #include <MP3Player_KT403A.h>
  3.  
  4. /****** Контакты для MP3-плеера ******/
  5. SoftwareSerial mp3(2, 3);
  6.  
  7. /****** Контакты для распознавателя речи ******/
  8. #define SOFTSERIAL_RX_PIN  5
  9. #define SOFTSERIAL_TX_PIN  6
  10.  
  11. SoftwareSerial speech(SOFTSERIAL_RX_PIN,SOFTSERIAL_TX_PIN);
  12.  
  13.  
  14. void setup()
  15. {
  16.     mp3.begin(9600);
  17.     speech.begin(9600);
  18.     Serial.begin(9600);
  19.     delay(100);
  20.  
  21.     SelectPlayerDevice(0x02);  //  выбираем SD-карту
  22.                                //  как устройство, с которого
  23.                                //  будет проигрываться музыка
  24.     SetVolume(0x15);           //  задаем громкость;
  25.                                //  диапазон: 0x00-0x1E
  26. }
  27.  
  28. void loop()
  29. {
  30.     int a=0;
  31.     if(speech.available())
  32.     {
  33.         a = speech.read();  //  считываем значение,
  34.                             //  возвращаемое распознавателем речи
  35.         switch (a)
  36.         {
  37.             case 3:               //  голосовая команда: «Play music»
  38.             SpecifyMusicPlay(1);  //  MP3: включить трек «001»
  39.             break;
  40.             case 4:               //  голосовая команда: «Pause»
  41.             PlayPause();          //  MP3: остановить музыку
  42.             break;
  43.             case 19:              //  голосовая команда: «Start»
  44.             PlayResume();         //  MP3: возобновить проигрывание
  45.             break;
  46.             case 5:               //  голосовая команда: «Next»
  47.             PlayNext();           //  MP3: включить следующий трек
  48.             break;
  49.             case 6:               //  голосовая команда: «Previous»
  50.             PlayPrevious();       //  MP3: включить предыдущий трек
  51.             break;
  52.             default:
  53.             break;
  54.         }
  55.  
  56.         delay(1000);
  57.     }
  58. }

Вещание текущего времени

Grove-модуль с MP3-плеером также можно использовать для того, чтобы создать систему, которая будет вещать текущее время. Для этой системы понадобятся распознаватель речи, MP3-плеер и часы реального времени.

Настройка времени

Сначала загружаем и устанавливаем библиотеку «RTC_DS1307», необходимую для использования Grove-модуля для часов реального времени. Сделайте это, кликнув в IDE Arduino на Скетч > Подключить библиотеку... > Добавить .ZIP библиотеку (Sketch > Include Library > Add .ZIP Library...), а затем в открывшемся меню выбрав скачанный ZIP-архив с библиотекой и нажав на кнопку «Open».

  • Откройте скетч-пример «SetTimeAndDisplay», кликнув в IDE Arduino на Файл > Примеры > RTC_DS1307 > SetTimeAndDisplay (File > Examples > RTC_DS1307 > SetTimeAndDisplay)
  • Подключите базовый Grove-шилд к Arduino Uno, а затем подключите Grove-модуль с часами реального времени к I2C-интерфейсу на базовом Grove-шилде
  • Задайте текущее время:
clock.fillByYMD(2016,1,19);  //  23 мая 2016 года
clock.fillByHMS(15,28,30);   //  15:28:30
clock.fillDayOfWeek(Mon);    //  Среда
  • Загрузите модифицированную программу на Arduino Uno.

Вещаемый текст

Как известно, для вещания времени достаточно 69 цифр (от «0» до «59»). Кроме того, перед вещанием самого времени можно добавить какой-нибудь текст. Например, «It’s», что можно перевести как «сейчас». Таким образом, в целом на SD-карту нужно загрузить 61 звуковой файл.

Но при использовании SD-карты нужно соблюдать определенные правила:

  • SD-карта должна быть типа FAT32
  • Перед добавлением треков SD-карту нужно отформатировать. Во время записи треков не должно совершаться никаких других действий
  • Порядок проигрывания треков зависит от порядка их записи. То есть, если мы хотим проигрывать треки по порядку, то эти треки на SD-карту тоже нужно записывать по порядку

К слову, разработчики пронумеровали все звуковые файлы (всего их 61) в папке, поэтому их можно просто загрузить, а потом записать на SD-карту. Разумеется, перед этим карту нужно отформатировать.

Название звукового файла Номер файла на SD-карте Проговариваемый текст
000 Первый 0
001 Второй 1
... ... ...
059 Шестидесятый 59
060 Шестьдесят первый «It’s»

Сборка системы

  • Подключите базовый Grove-шилд к Arduino Uno, затем подключите Grove-модуль с MP3-плеером к порту D2 на базовом Grove-шилде, затем подключите Grove-модуль с распознавателем речи к порту D5 на базовом Grove-шилде и, наконец, подключите Grove-модуль с часами реального времени к порту I2C на базовом Grove-шилде
  • Скопируйте код ниже в новый скетч IDE Arduino, а затем загрузите программу на Arduino Uno
  • Скажите «Hi Cell, what’s the time?», и система должна проговорить текущее время
  1. #include <Wire.h>
  2. #include "DS1307.h"
  3. #include <SoftwareSerial.h>
  4. #include <MP3Player_KT403A.h>
  5.  
  6. /******* Контакты для MP3-плеера ******/
  7. SoftwareSerial mp3(2, 3);
  8.  
  9. /******* Контакты для распознавателя речи ******/
  10. #define SOFTSERIAL_RX_PIN  5
  11. #define SOFTSERIAL_TX_PIN  6
  12.  
  13. SoftwareSerial speech(SOFTSERIAL_RX_PIN,SOFTSERIAL_TX_PIN);
  14.  
  15. /******* Задаем объект для класса DS1307 ******/
  16. DS1307 clock;
  17.  
  18. void setup ()
  19. {
  20.   mp3.begin(9600);
  21.   speech.begin(9600);
  22.   clock.begin();
  23.   Serial.begin(9600);
  24.   delay(100);
  25.  
  26.   SelectPlayerDevice(0x02);  //  выбираем SD-карту, с которой будут
  27.                              //  проигрываться звуковые файлы
  28.   SetVolume(0x15);           //  задаем громкость: диапазон: 0x00-0x1E
  29. }
  30.  
  31. void loop ()
  32. {
  33.   int a=0;
  34.   speech.listen();  //  начинаем получать данные от программного порта
  35.                     //  распознавателя речи
  36.   if(speech.available())
  37.   {
  38.     a = speech.read();  //  считываем значение, возвращаемое
  39.                         //  распознавателем речи
  40.     if(a==13)
  41.     {
  42.       clock.getTime();        //  считываем время
  43.                               //  от часов реального времени
  44.       int b=1+clock.hour;     //  считываем часы; поскольку
  45.                               //  первый трек – это «0»,
  46.                               //  то для трека со словами «It’s»,
  47.                               //  который находится в самом конце,
  48.                               //  к «60» нужно добавить «1»
  49.        int c=1+clock.minute;  //  считываем минуты; поскольку
  50.                               //  первый трек – это «0»,
  51.                               //  то для трека со словами «It’s»,
  52.                               //  который находится в самом конце,
  53.                               //  к «60» нужно добавить «1»
  54.  
  55.       mp3.listen();           //  начинаем получение данных
  56.                               //  от программного порта MP3-плеера
  57.       SpecifyMusicPlay(61);   //  номер «It’s» на SD-карте – это «61»
  58.       while(QueryPlayStatus() != 0);  //  когда закончится
  59.                                       //  предыдущий трек,
  60.                                       //  начинаем проигрывать
  61.                                       //  следующую трек
  62.       SpecifyMusicPlay(b);  //  проигрываем трек, сохраненный
  63.                             //  на SD-карте под названием «b»
  64.       while(QueryPlayStatus() != 0);
  65.       SpecifyMusicPlay(c);  //  проигрываем трек, сохраненный
  66.                             //  на SD-карте под названием «c»
  67.  
  68.       while(QueryPlayStatus() != 0);
  69.     }
  70.   }
  71.     delay(1000);
  72. }

Полезные ссылки

См.также

Внешние ссылки

  1. wiki.seeed.cc - Grove Speech Recognizer Kit for Arduino