Arduino:Примеры/Гайд по использованию радиочастотного трансивера nRF24L01 (2,4 ГГц) с Arduino

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.



Гайд по использованию радиочастотного трансивера nRF24L01 (2,4 ГГц) с Arduino[1]

Эта статья объясняет, что такое радиочастотный трансивер nRF24L01, рассказывает о его характеристиках и содержит скетч Arduino, который вы можете использовать в своих проектах.

Описание

Радиочастотные модули вроде nRF24L01 очень популярны среди тех, кто увлекается проектами на базе Arduino. Трансивер nRF24L01 применим во множестве проектов, где требуется беспроводное управление. Кроме того, это трансивер, и это значит, что это устройство может и получать, и передавать данные.

Характеристики

  • Цена: низкая, около 2 долларов
  • Количество чипов: один
  • Дальность действия антенны: не более 1000 метров (на открытой местности, со скоростью 250 Кбит/сек)
  • Энергопотребление: очень низкое
  • Входное напряжение: 3,3 вольта
  • Напряжение на контактах: допустимо использование 5 вольт

Где купить?

Радиочастотные трансиверы вроде nRF24L01 можно купить на eBay (к примеру, тут). Они продаются в двух версиях: с внешней антенной (увеличенная дальность действия) и со встроенной антенной (уменьшенная дальность).

Необходимые компоненты

Для нашего проекта понадобятся следующие компоненты:

  • Две платы Arduino (см. на eBay)
  • Два радиочастотных трансивера (см. на eBay)
  • Макетная плата (см. на eBay)

Библиотека Radiohead

Кроме того, для этого проекта понадобится библиотека Radiohead. Она отлично работает и совместима со всеми радиочастотными модулями, имеющимися на рынке. Более подробно об этом проекте можно почитать тут.

  • Загрузите ее отсюда
  • Распакуйте скачанный архив
  • Установите библиотеку Radiohead в IDE Arduino
  • Перезапустите IDE Arduino

Распиновка

Модуль nRF24L01, вид сверху

Схема и код для клиента

Подключите клиентскую часть проекта в соответствии со схемой ниже:

Важно! Входное напряжение должно быть в диапазоне от 1,9 до 3,6 вольт. Если его превысить, вы можете запросто поджарить свой модуль.

Теперь загрузите на Arduino скетч ниже. Он уже будет встроен в IDE Arduino, т.к. двумя разделами выше вы установили в нее библиотеку Radiohead. Чтобы открыть скетч, кликните в IDE Arduino по Файл > Примеры > Radiohead > nrf24 > nrf24_client (File > Examples > Radiohead > nrf24 > nrf24_client).

// Скетч «nrf24_client»

#include <SPI.h>
#include <RH_NRF24.h>

// создаем экземпляр класса для трансивера:
RH_NRF24 nrf24;
// RH_NRF24 nrf24(8, 7);   // для электрической совместимости с Mirf
// RH_NRF24 nrf24(8, 10);  // для Leonardo; также понадобится 
                           // явно определить контакт SS 
// RH_NRF24 nrf24(8, 7);   // для RFM73 на Anarduino Mini

void setup() 
{
  Serial.begin(9600);
  while (!Serial)
    ; // ждем подключения последовательного порта
      // (нужно только для Leonardo):
  if (!nrf24.init())
    Serial.println("init failed");  //  "инициализация не удалась"
  // по умолчанию после инициализации трансивер настраивается
  // со следующими параметрами: 2,402 ГГц (канал 2), 2 Мбит/сек, 0 дБм
  if (!nrf24.setChannel(1))
    Serial.println("setChannel failed");
    //  "не удалось выполнить функцию setChannel()"
  if (!nrf24.setRF(RH_NRF24::DataRate2Mbps,   
      RH_NRF24::TransmitPower0dBm))
    Serial.println("setRF failed");    
    //  "не удалось выполнить функцию setRF()"
}


void loop()
{
  Serial.println("Sending to nrf24_server");  //  "Отправка данных...
                                              //  ...на nrf24_server"
  // отправляем сообщение на nrf24_server:
  uint8_t data[] = "Hello World!";  //  "Привет, мир!"
  nrf24.send(data, sizeof(data));
  
  nrf24.waitPacketSent();
  // теперь ждем ответа:
  uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
  uint8_t len = sizeof(buf);

  if (nrf24.waitAvailableTimeout(500))
  { 
    // ответное сообщение уже должно прийти:   
    if (nrf24.recv(buf, &len))
    {
      Serial.print("got reply: ");  //  "получили ответ: "
      Serial.println((char*)buf);
    }
    else
    {
      Serial.println("recv failed");  //  "не удалось выполнить... 
                                      //  ...функцию recv()"
    }
  }
  else
  {
    Serial.println("No reply, is nrf24_server running?");
    //  "Ответа нет, nrf24_server вообще запущен?"
  }
  delay(400);
}

Схема и код для сервера

Подключите серверную часть проекта в соответствии со схемой ниже:

Важно! Входное напряжение должно быть в диапазоне от 1,9 до 3,6 вольт. Если его превысить, вы можете запросто поджарить свой модуль.

Теперь загрузите на Arduino скетч ниже. Он уже будет встроен в IDE Arduino, т.к. тремя разделами выше вы установили в нее библиотеку Radiohead. Чтобы открыть скетч, кликните в IDE Arduino по Файл > Примеры > Radiohead > nrf24 > nrf24_server (File > Examples > Radiohead > nrf24 > nrf24_server).

// Скетч «nrf24_server»

#include <SPI.h>
#include <RH_NRF24.h>

// создаем экземпляр класса для трансивера:
RH_NRF24 nrf24;
// RH_NRF24 nrf24(8, 7);   // для электрической совместимости с Mirf
// RH_NRF24 nrf24(8, 10);  // для Leonardo; также понадобится 
                           // явно определить контакт SS
// RH_NRF24 nrf24(8, 7);   // для RFM73 на Anarduino Mini

void setup() 
{
  Serial.begin(9600);
  while (!Serial) 
    ; // ждем подключения последовательного порта
      // (нужно только для Leonardo):
  if (!nrf24.init())
    Serial.println("init failed");  //  "инициализация не удалась"
  // по умолчанию после инициализации трансивер настраивается
  // со следующими параметрами: 2,402 ГГц (канал 2), 2 Мбит/сек, 0 дБм
  if (!nrf24.setChannel(1))
    Serial.println("setChannel failed");
    //  "не удалось выполнить функцию setChannel()"
  if (!nrf24.setRF(RH_NRF24::DataRate2Mbps, RH_NRF24::TransmitPower0dBm))
    Serial.println("setRF failed");  
    //  "не удалось выполнить функцию setRF()"  
}

void loop()
{
  if (nrf24.available())
  {
    // сообщение уже должно прийти:  
    uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
    uint8_t len = sizeof(buf);
    if (nrf24.recv(buf, &len))
    {
//      NRF24::printBuffer("request: ", buf, len);
      Serial.print("got request: ");  //  "получен запрос: "
      Serial.println((char*)buf);
      
      // отправляем ответ:
      uint8_t data[] = "And hello back to you";  //  "И тебе привет!"
      nrf24.send(data, sizeof(data));
      nrf24.waitPacketSent();
      Serial.println("Sent a reply");  //  "Отправляем ответ"
    }
    else
    {
      Serial.println("recv failed");  //  "не удалось выполнить... 
                                      //  ...функцию recv()"
    }
  }
}

Демонстрация

В этом проекте клиент отправляет серверу через трансивер сообщение «Hello, world!» (т.е. «Привет, мир!», а сервер в ответ отправляет сообщение «And hello back to you» (т.е. «И тебе привет»). Оба сообщения будут показаны в мониторе порта, а сам он будет выглядеть следующим образом:

Слева сообщения выводятся на PuTTY.org. Справа – на монитор порта IDE Arduino.

Качество связи

Не ждите от этого модуля слишком многого. Он работает очень неплохо, когда приемник и передатчик находятся рядом. Но если разместить их далеко друг от друга, связь может быть потеряна.

Кроме того, качество связи может зависеть и от других факторов. Это зависит от того, много ли радиочастотного шума в окружающем пространстве, есть ли в нем какие-нибудь преграды и используется ли внешняя антенна.

См.также

Внешние ссылки