Arduino:Примеры/Чтение и запись произвольных данных на SD карту

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Проверка/Оформление/Редактирование: Мякишев Е.А.



Чтение и запись произвольных данных на SD карту

Данный пример демонстрирует чтение запись произвольных данных на SD-карту с использованием платы Arduino Uno и любой платы расширения(шилд), работающей с SD-картами или MicroSD-картами(Cooking HAcks Micro SD shiled, Arduino Wireless SD shiled, Arduino Ethernet SD shiled, Arduino Wi-Fi SD shield, Adafruit data logging shield, SparkFun MicroSD shield).

Необходимые компоненты

Монтажная схема

Соедините выбранную вами плату расширения с платой Arduino Uno.

Код

#include <SD.h>                                           // Подключаем библиотеку SD
 
/*
Используемые по умолчанию контакты для библиотеки SD.
Если вы используете Arduino Ethernet SD shiled или любую
другую плату расширения использующую эти контакты,
то ничего менять не надо
MOSI = 11 контакт
MISO = 12 контакт
SCLK = 13 контакт
*/
 
#define CS_PIN 10                                         // Контакт выбора
                                                          // Примечание: если вы используете Arduino Ethernet SD shiled
                                                          // необходимо изменить номер контакта на 4.
                                                          // Если ваша плата расширения использует другой контакт
                                                          // вам необходимо его изменить на правильный.    


int refresh_rate = 5000;                                  // Скорость опроса по умолчанию 5 сек.

void setup()
{
  Serial.begin(9600);                                     // Инициализация последовательного соединения на скорости 9600 бод
  Serial.println("Initializing Card");                    // Распечатываем в мониторе последовательного порта "Initializing Card"("Инициализация карты")
  pinMode(CS_PIN, OUTPUT);                                // Определяем CS(контакт выбора) контакт как выход
 
  // Инициализация SD-карты
  if (!SD.begin(CS_PIN))
  {
    Serial.println("Card Failure");                        // Распечатываем в мониторе последовательного порта "Card Failure"("Сбой подключения к SD-карте")
    return;                                                // Останавливаем выполнение программы
  }
  Serial.println("Card Ready");                            // Распечатываем в мониторе последовательного порта "Card Ready"("Карта готова к работе")
 
  //Чтение конфигурационного файла speed.txt
  File commandFile = SD.open("speed.txt");
  if (commandFile)
  {
     Serial.println("Reading Command File");               // Распечатываем в мониторе последовательного порта "Reading Command File"("Чтение конфигурационного файла")
  
     while(commandFile.available())
     {
       refresh_rate = commandFile.parseInt();
     }
     Serial.print("Refresh Rate = ");                     // Распечатываем в мониторе последовательного порта "Refresh Rate = " ("Частота обновления = ")
     Serial.print(refresh_rate);                          // Распечатываем в мониторе последовательного порта значение переменной refresh_rate
     Serial.println("ms");                                // Распечатываем в мониторе последовательного порта "ms"("мс.")
     commandFile.close();                                 // Закрываем файл
  }  
  else
  {
    Serial.println("Could not read command file.");       // Распечатываем в мониторе последовательного порта "Could not read command file."("Не удалось прочитать конфигурационный файл")
    return;                                               // Останавливаем выполнение программы
  } 
}

void loop()
{
  long timeStamp = millis();                              // Временная метка
  String dataString = "Hello World!";
 
  // Открываем файл и записываем в него данные
  File dataFile = SD.open("log.csv", FILE_WRITE);
  if (dataFile)
  {
    dataFile.print(timeStamp);
    dataFile.print(",");
    dataFile.println(dataString);
    dataFile.close();                                    // Внимание! Данные не будут записаны, пока вы не закроете соединение!
  
    // Распечатываем в мониторе последовательного порта те же данные для отладки 
    Serial.print(timeStamp);
    Serial.print(",");
    Serial.println(dataString);
  }
  else
  {
    Serial.println("Couldn't open log file");           // Распечатываем в мониторе последовательного порта "Couldn't open log file"("Не удалось открыть файл журнала")
  }
  delay(refresh_rate);                                  // Задержка длительностью refresh_rate
}

См.также

Внешние ссылки