Arduino:Примеры/AtCommand

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Отправка AT-запросов к XBee-модулю[1]

Этот пример показывает, как при помощи библиотеки XBee извлекать информацию о адресе XBee-модуля, а также о статусе ассоциации. Кроме того, если эти команды не будут выполнены успешно, скетч сообщит о коде ошибки. Все это выполняется при помощи AT-запросов.

Код

/**
 * Автор – Эндрю Рэпп (Andrew Rapp). 2009 год, все права защищены.
 *
 * Этот файл – часть библиотеки XBee-Arduino.
 *
 * Библиотека XBee для Arduino – это бесплатное ПО: его можно 
 * распространять и/или модифицировать согласно условиям Универсальной 
 * общественной лицензии GNU, изданной Фондом свободного ПО – будь то 
 * 3-тья или более поздняя версия этой лицензии (на ваш выбор).
 *
 * Библиотека XBee-Arduino распространяется бесплатно в надежде на то, 
 * что окажется полезной, но БЕЗО ВСЯКОЙ ГАРАНТИИ; включая даже 
 * обязательную гарантию на КОММЕРЧЕСКОЕ КАЧЕСТВО и ПРИГОДНОСТЬ 
 * КОНКРЕТНОЙ ЦЕЛИ. Более подробно читайте в Универсальной 
 * общественной лицензии GNU.
 *
 * Вы должны получить копию Универсальной общественной лицензии GNU 
 * вместе с библиотекой XBee-Arduino. Если не получили, ее можно найти 
 * на http://www.gnu.org/licenses/.
 */

#include <XBee.h>
#include <SoftwareSerial.h>

/*
Этот пример – для XBee-модуля Series 1 (с прошивкой 10C8 или новее) 
или Series 2. Он отправляет к XBee-модулю несколько AT-запросов и 
проверяет, были ли они успешными.

Чтобы видеть информацию об XBee-коммуникации, этот пример использует 
библиотеку SoftSerial. Я использую плату Modern Device USB BUB
(http://moderndevice.com/connect) и просматриваю выдачу при помощи 
монитора порта в IDE Arduino.
*/

// Задаем TX и RX контакты для SoftSerial.
// Подключаем 8-ой контакт Arduino к TX-контакту конвертера USB-Serial:
uint8_t ssRX = 8;
// Подключаем 9-ый контакт Arduino к RX-контакту конвертера USB-Serial:
uint8_t ssTX = 9;
// Не забудьте подключить все устройства к общей «земле»: XBee, Arduino и конвертер USB-Serial
SoftwareSerial nss(ssRX, ssTX);

XBee xbee = XBee();

// Адрес XBee-модуля (фрагмент Serial High):
uint8_t shCmd[] = {'S','H'};
// Адрес XBee-модуля (фрагмент Serial Low):
uint8_t slCmd[] = {'S','L'};
// Статус ассоциации:
uint8_t assocCmd[] = {'A','I'};

AtCommandRequest atRequest = AtCommandRequest(shCmd);

AtCommandResponse atResponse = AtCommandResponse();

void setup() { 
  Serial.begin(9600);
  xbee.begin(Serial);
  // Запускаем коммуникацию SoftSerial:
  nss.begin(9600);
  
  // Делаем небольшую задержку на старте – чтобы подождать пока 
  // инициируется модуль XBee. Если вы не получаете ответа, то это 
  // значение имеет смысл увеличить.
  delay(5000);
}

void loop() {

  // Извлекаем фрагмент Serial High:
  sendAtCommand();
  
  // Извлекаем фрагмент Serial Low:
  atRequest.setCommand(slCmd);  
  sendAtCommand();

  // Извлекаем статус ассоциации:
  atRequest.setCommand(assocCmd);  
  sendAtCommand();
  
  // Готово.  Жмем на кнопку сброса Arduino, чтобы перезапустить скетч:
  while (1) {};
}

void sendAtCommand() {
  nss.println("Sending command to the XBee");  //  "Отправка команды XBee-модулю" 

  // Отправляем команду:
  xbee.send(atRequest);

  // Ждем 5 секунд ответа о статусе:
  if (xbee.readPacket(5000)) {
    // Получили ответ!

    // Проверка на получение ответа:
    if (xbee.getResponse().getApiId() == AT_COMMAND_RESPONSE) {
      xbee.getResponse().getAtCommandResponse(atResponse);

      if (atResponse.isOk()) {
        nss.print("Command [");  //  "Команда ["
        nss.print(atResponse.getCommand()[0]);
        nss.print(atResponse.getCommand()[1]);
        nss.println("] was successful!");    //  "] была выполнена успешно!"

        if (atResponse.getValueLength() > 0) {
          nss.print("Command value length is ");    //  "Размер значения, полученного командой - "
          nss.println(atResponse.getValueLength(), DEC);

          nss.print("Command value: ");  //  "Значение, полученное командой: "
          
          for (int i = 0; i < atResponse.getValueLength(); i++) {
            nss.print(atResponse.getValue()[i], HEX);
            nss.print(" ");
          }

          nss.println("");
        }
      } 
      else {
        nss.print("Command return error code: ");  //  "Код ошибки, возвращенный командой: "
        nss.println(atResponse.getStatus(), HEX);
      }
    } else {
      nss.print("Expected AT response but got ");  //  "Ожидался AT-ответ, но получили "
      nss.print(xbee.getResponse().getApiId(), HEX);
    }   
  } else {
    // Если выполнение команды не удалось:
    if (xbee.getResponse().isError()) {
      nss.print("Error reading packet.  Error code: ");    //  "Ошибка при чтении пакета. Код ошибки: "
      nss.println(xbee.getResponse().getErrorCode());
    } 
    else {
      nss.print("No response from radio");    //  "XBee-модуль не отвечает"
    }
  }
}

См.также

Внешние ссылки