Arduino:Примеры/TemperatureWebPanel

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Температурная веб-панель[1]

Этот пример показывает, как при помощи библиотеки Bridge и встроенного веб-сервера Arduino Yun отобразить данные, полученные от аналогового датчика.

Подготовьте вашу SD-карту, создав в ее корневой директории пустую папку под названием «arduino», а в ней подпапку под названием «www». Благодаря этому Yun создаст связь с SD-картой по пути «/mnt/sd».

В этой папке будет находиться простая веб-страница и копия zepto.js (мини-версии jQuery). Когда вы загрузите свой скетч, эти файлы будут размещены в папке «/arduino/www/TemperatureWebPanel» на вашей SD-карте.

Чтобы увидеть результат работы этого скетча, надо пройти по ссылке «http://arduino.local/sd/TemperatureWebPanel».

Во время работы Linux и скетча SD-карту можно вынуть, но не стоит делать этого в тот момент, когда система будет записывать на нее необходимые данные.

Необходимое оборудование

  • Плата Arduino Yun;
  • Температурный датчик TMP36;
  • SD-карта;

Цепь

Компьютер и Yun должны находиться в одной беспроводной сети. Температурный датчик подключите к 1-ому аналоговому контакту, а карту microSD вставьте в SD-слот на Yun.

Код

Подключаем библиотеки Bridge, YunServer и YunClient.

#include <Bridge.h>
#include <YunServer.h>
#include <YunClient.h>

Инстанцинируем сервер, с помощью которого Yun будет «прослушивать» подключающихся клиентов.

YunServer server;

Создаем строку, в которой будем хранить информацию о времени начала работы скетча, а также переменную, в которой будем хранить число, отображающее количество посещений страницы.

String startString;
long hits = 0;

В секции setup() начинаем последовательную передачу данных и инициализируем Bridge. Будет нелишним воспользоваться здесь встроенным светодиодом, оповещающим о начале и завершении активации Bridge.

void setup() {
  Serial.begin(9600);

  pinMode(13,OUTPUT);
  digitalWrite(13, LOW);
  Bridge.begin();
  digitalWrite(13, HIGH);

Задаем 0-ой и 2-ой аналоговые контакты в качестве питающего и заземляющего контактов для датчика TMP36 (благодаря этому можно обойтись без макетной платы Breadboard).

pinMode(A0, OUTPUT);
  pinMode(A2, OUTPUT);
  digitalWrite(A0, HIGH);
  digitalWrite(A2, LOW);

Далем так, чтобы сервер прослушивал входящие подключения только от локального хоста, а затем запускаем его.

server.listenOnLocalhost();
  server.begin();

Создаем экземпляр класса Process, с помощью которого будем получать информацию о времени начала скетча. Для этого запускаем команду date, а результат записываем созданную ранее строку.

Process startTime;
  startTime.runShellCommand("date");
  while(startTime.available()) {
    char c = startTime.read();
    startString += c;
  }
}

В секции loop() инстанцинируем класс YunClient, чтобы получать информацию о клиентах, идущих от сервера.

YunClient client = server.accept();

Если подключился новый клиент, то считываем присланную им команду, а затем выводим ее на Serial Monitor.

if (client) {
    String command = client.readString();
    command.trim();        //удаляем пробельные символы
    Serial.println(command);

Если команда – это «temperature», фиксируем время и считываем данные с температурного датчика.

if (command == "temperature") {

      Process time;
      time.runShellCommand("date");
      String timeString = "";
      while(time.available()) {
        char c = time.read();
        timeString += c;
      }
      Serial.println(timeString);
      int sensorValue = analogRead(A1);

Конвертируем данные датчика в градусы Цельсия.

// конвертируем считанные данные в милливольты:
      float voltage = sensorValue *  (5000/ 1024); 
      // конвертируем милливольты в градусы Цельсия:
      float temperature = (voltage - 500)/10;

Выводим на Serial Monitor данные о текущем времени, температуре, времени начала работы скетча и количестве посещений страницы – все это при помощи функции client.print().

client.print("Current time on the Yun: "); // "Текущее время на Yun: "
      client.println(timeString);
      client.print("<br>Current temperature: "); // "<br>Температура сейчас: "
      client.print(temperature);
      client.print(" degrees C"); // " градусов Цельсия"
      client.print("<br>This sketch has been running since "); // "<br>Этот скетч работает с "
      client.print(startString);
      client.print("<br>Hits so far: "); // "<br>Количество посещений страницы на данный момент: "
      client.print(hits);
    }

Закрываем соединение, чтобы освободить все неиспользованные ресурсы, а затем поднимаем значение счетчика посещений страницы.

client.stop();
    hits++;
  }

Делаем небольшую паузу перед тем, как начать снова.

delay(50); // пауза в 50 миллисекунд
}

Весь скетч полностью – ниже:

/*
Температурный веб-интерфейс
Этот пример показывает, как посредством библиотеки Bridge и встроенного веб-сервиса Yun обрабатывать данные от аналогового датчика.
Цепь:
 * Температурный датчик TMP36 подключен к 1-ому аналоговому контакту
 * SD-карта, подсоединенная к SD-слоту Arduino Yún

Подготовьте SD-карту, создав в корневой директории 
пустую папку под названием «arduino» и подпапку под названием «www».
Благодаря этому Yun создаст связь с SD-картой по пути «/mnt/sd».

В этой папке будет находиться простая веб-страница и копия zepto.js (мини-версии jQuery). 
Когда вы загрузите скетч, эти файлы будут размещены в папке «/arduino/www/TemperatureWebPanel» на SD-карте.

Чтобы увидеть результат работы скетча, пройдите по ссылке http://arduino.local/sd/TemperatureWebPanel.

Во время работы Linux и скетча SD-карту можно вынуть, но не стоит делать этого в тот момент, когда система будет записывать на нее необходимые данные. 
Создан 6 июля 2013 Томом Иго (Tom Igoe).
Этот код не защищен авторским правом.

 */
#include <Bridge.h>
#include <YunServer.h>
#include <YunClient.h> 

// Прослушиваем порт 5555 (это порт по умолчанию).
// Веб-сервер Yun будет перенаправлять туда все HTTP-запросы. 
YunServer server;
String startString;
long hits = 0;

void setup() {
  Serial.begin(9600);

  // Инициализируем Bridge
  pinMode(13,OUTPUT);
  digitalWrite(13, LOW);
  Bridge.begin();
  digitalWrite(13, HIGH);

  // Делаем 0-ой и 2-ой аналоговые контакты питанием и «землей» для датчика TMP36:
  pinMode(A0, OUTPUT);
  pinMode(A2, OUTPUT);
  digitalWrite(A0, HIGH);
  digitalWrite(A2, LOW);

  // Делаем так, чтобы прослушивать только те входящие соединения,
  // которые идут от локального хоста (т.е. не от внешней сети):
  server.listenOnLocalhost();
  server.begin();

  // Фиксируем время начала работы скетча:
  Process startTime;
  startTime.runShellCommand("date");
  while(startTime.available()) {
    char c = startTime.read();
    startString += c;
  }
}

void loop() {
  // «Берем» клиентов, идущих от сервера:
  YunClient client = server.accept();

  // Есть ли новый клиент?
  if (client) {
    // Считываем команду
    String command = client.readString();
    command.trim();        // удаляем пробельные символы
    Serial.println(command);
    // Эта команда – «temperature»?
    if (command == "temperature") {

      // Запрашиваем у сервера и фиксируем текущее время:
      Process time;
      time.runShellCommand("date");
      String timeString = "";
      while(time.available()) {
        char c = time.read();
        timeString += c;
      }
      Serial.println(timeString);
      int sensorValue = analogRead(A1);
      // конвертируем считанные данные в милливольты:
      float voltage = sensorValue *  (5000/ 1024); 
      // конвертируем милливольты в градусы Цельсия:
      float temperature = (voltage - 500)/10;
      // Выводим данные на Serial Monitor:
      client.print("Current time on the Yun: ");  // "Текущее время на Yun: "
      client.println(timeString);
      client.print("<br>Current temperature: ");  // "<br>Температура сейчас: "
      client.print(temperature);
      client.print(" degrees C");  // " градусов Цельсия"
      client.print("<br>This sketch has been running since ");
      client.print(startString);  // "<br>Этот скетч работает с "
      client.print("<br>Hits so far: ");  // "<br>Количество посещений страницы на данный момент: "
      client.print(hits);
    }

    // Закрываем соединение и высвобождаем ресурсы:
    client.stop();
    hits++;
  }

  delay(50); // Пауза каждые 50 миллисекунд
}

См.также

Внешние ссылки