Arduino:Примеры/Блокировка ПК на основе показаний фоторезистора

Материал из Онлайн справочника
Перейти к навигации Перейти к поиску

Проверка/Оформление/Редактирование: Мякишев Е.А.


Pixel Art Mini Meow Animated.gif Черновик


Блокировка ПК на основе показаний фоторезистора

Данный пример демонстрирует блокировку ПК на основе показаний фоторезистора с использованием Arduino Leonardo. Arduino Leonardo обладает возможностью эмулировать работу USB-устройств(например, клавиатуры или мыши), в результате мы можем эмулировать нажатия комбинация клавиш.

В этом примере при достижении показаний фоторезистора ниже пороговых мы будем блокировать компьютер комбинацией клавиш  Win  +  L .

Необходимые компоненты

Монтажная схема

Соберите схему согласно монтажной схеме.

Arduino leonardo example keyboard lock pc 1 bb.png

Код

Pixel Art Mini Meow Animated.gif Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Он специально устроен таким образом, что работает только при нажатии кнопки.


 1 #include <Keyboard.h>                                  
 2 
 3 #define LIGHT      0                                   // фоторезистор подключаем к 0-му аналоговому выводу
 4 #define LED        3                                   // светодиод подключаем к 3-му выводу
 5 #define BUTTON     2                                   // кнопку подключаем к 2-му выводу
 6 
 7 #define THRESHOLD 50                                   // пороговое значение для блокировки компьютера
 8                                                        // ВНИМАНИЕ! Здесь вы должны подставить свое вычисленное значение
 9                                                        // для своего фоторезистора.
10 
11 boolean lastButton = LOW;                              // последнее состояние кнопки
12 boolean currentButton = LOW;                           // текущее состояние кнопки
13 boolean lock = false;                                  // по умолчанию блокировка компьютера запрещена
14 
15 void setup()
16 {
17   pinMode (LED, OUTPUT);                               // устанавливаем вывод LED(т.е. 3-ий) как выход
18   Keyboard.begin();                                    // запускаем эмуляцию клавиатуры
19 }
20 
21 void loop()
22 {
23   currentButton = debounce(lastButton);                // считываем состояние кнопки с использованием функции "антидребезга"
24  
25   if (lastButton == LOW && currentButton == HIGH)      // если кнопку нажали, то
26     lock = !lock;                                      // инвертируем переменную lock для разрешения/запрета блокировки компьютера
27   
28   lastButton = currentButton;                          // сохраняем текущее состояние кнопки как последнее состояние
29  
30   if (lock)                                            // если блокировка компьютера разрешена
31   {
32     digitalWrite(LED, HIGH);                           // включаем светодиод
33         
34     if (millis() % 1000 == 0)                          // если время кратно 1000
35     {
36       int brightness = analogRead(LIGHT);              // считываем значение с фоторезистора
37       if (brightness < THRESHOLD)                      // если значение ниже порогового
38         {
39           Keyboard.press(KEY_LEFT_GUI);                // нажимаем и удерживаем нажатой клавишу Win
40           Keyboard.press('l');                         // нажимаем и удерживаем нажатой клавишу L
41           delay(100);                                  // задержка 100 мс.
42           Keyboard.releaseAll();                       // отпускаем все клавиши
43          }
44      }          
45   }
46   else                                                 // иначе, блокировка компьютера запрещена
47   {
48     digitalWrite(LED, LOW);                            // отключаем светодиод
49   }
50 }
51 
52 /*
53 * Функция для предотвращения дребезга контакта
54 * last    - последнее состояние кнопки
55 * current - текущее состояние кнопки
56 */
57 boolean debounce(boolean last)
58 {
59   boolean current = digitalRead(BUTTON);              // считываем состояние кнопки
60   if (last != current)                                // если предыдущее и текущее состояние кнопки отлючаются
61   {
62     delay(5);                                         // ждем 5мс
63     current = digitalRead(BUTTON);                    // считываем заново
64   }
65   return current;                                     // возвращаем текущее состояние кнопки
66 }

См.также

Внешние ссылки