Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/Гайд по использованию радиочастотного трансивера nRF24L01 (2,4 ГГц) с Arduino

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2703 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Гайд по использованию радиочастотного трансивера nRF24L01 (2,4 ГГц) с Arduino[1]

Эта статья объясняет, что такое радиочастотный трансивер nRF24L01, рассказывает о его характеристиках и содержит скетч Arduino, который вы можете использовать в своих проектах.

Описание

Радиочастотные модули вроде nRF24L01 очень популярны среди тех, кто увлекается проектами на базе Arduino. Трансивер nRF24L01 применим во множестве проектов, где требуется беспроводное управление. Кроме того, это трансивер, и это значит, что это устройство может и получать, и передавать данные.

Характеристики

  • Цена: низкая, около 2 долларов
  • Количество чипов: один
  • Дальность действия антенны: не более 1000 метров (на открытой местности, со скоростью 250 Кбит/сек)
  • Энергопотребление: очень низкое
  • Входное напряжение: 3,3 вольта
  • Напряжение на контактах: допустимо использование 5 вольт

Где купить?

Радиочастотные трансиверы вроде nRF24L01 можно купить на eBay (к примеру, тут). Они продаются в двух версиях: с внешней антенной (увеличенная дальность действия) и со встроенной антенной (уменьшенная дальность).

Nrf-where-to-buy.jpg

Необходимые компоненты

Для нашего проекта понадобятся следующие компоненты:

  • Две платы Arduino (см. на eBay)
  • Два радиочастотных трансивера (см. на eBay)
  • Макетная плата (см. на eBay)

Библиотека Radiohead

Кроме того, для этого проекта понадобится библиотека Radiohead. Она отлично работает и совместима со всеми радиочастотными модулями, имеющимися на рынке. Более подробно об этом проекте можно почитать тут.

  • Загрузите ее отсюда
  • Распакуйте скачанный архив
  • Установите библиотеку Radiohead в IDE Arduino
  • Перезапустите IDE Arduino

Распиновка

Модуль nRF24L01, вид сверху

Схема и код для клиента

Подключите клиентскую часть проекта в соответствии со схемой ниже:

Nrf24-radiohead-with-Arduino.png

Важно! Входное напряжение должно быть в диапазоне от 1,9 до 3,6 вольт. Если его превысить, вы можете запросто поджарить свой модуль.

Теперь загрузите на Arduino скетч ниже. Он уже будет встроен в IDE Arduino, т.к. двумя разделами выше вы установили в нее библиотеку Radiohead. Чтобы открыть скетч, кликните в IDE Arduino по Файл > Примеры > Radiohead > nrf24 > nrf24_client (File > Examples > Radiohead > nrf24 > nrf24_client).

  1. // Скетч «nrf24_client»
  2.  
  3. #include <SPI.h>
  4. #include <RH_NRF24.h>
  5.  
  6. // создаем экземпляр класса для трансивера:
  7. RH_NRF24 nrf24;
  8. // RH_NRF24 nrf24(8, 7);   // для электрической совместимости с Mirf
  9. // RH_NRF24 nrf24(8, 10);  // для Leonardo; также понадобится
  10.                            // явно определить контакт SS
  11. // RH_NRF24 nrf24(8, 7);   // для RFM73 на Anarduino Mini
  12.  
  13. void setup()
  14. {
  15.   Serial.begin(9600);
  16.   while (!Serial)
  17.     ; // ждем подключения последовательного порта
  18.       // (нужно только для Leonardo):
  19.   if (!nrf24.init())
  20.     Serial.println("init failed");  //  "инициализация не удалась"
  21.   // по умолчанию после инициализации трансивер настраивается
  22.   // со следующими параметрами: 2,402 ГГц (канал 2), 2 Мбит/сек, 0 дБм
  23.   if (!nrf24.setChannel(1))
  24.     Serial.println("setChannel failed");
  25.     //  "не удалось выполнить функцию setChannel()"
  26.   if (!nrf24.setRF(RH_NRF24::DataRate2Mbps,  
  27.       RH_NRF24::TransmitPower0dBm))
  28.     Serial.println("setRF failed");    
  29.     //  "не удалось выполнить функцию setRF()"
  30. }
  31.  
  32.  
  33. void loop()
  34. {
  35.   Serial.println("Sending to nrf24_server");  //  "Отправка данных...
  36.                                               //  ...на nrf24_server"
  37.   // отправляем сообщение на nrf24_server:
  38.   uint8_t data[] = "Hello World!";  //  "Привет, мир!"
  39.   nrf24.send(data, sizeof(data));
  40.  
  41.   nrf24.waitPacketSent();
  42.   // теперь ждем ответа:
  43.   uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
  44.   uint8_t len = sizeof(buf);
  45.  
  46.   if (nrf24.waitAvailableTimeout(500))
  47.   {
  48.     // ответное сообщение уже должно прийти:  
  49.     if (nrf24.recv(buf, &len))
  50.     {
  51.       Serial.print("got reply: ");  //  "получили ответ: "
  52.       Serial.println((char*)buf);
  53.     }
  54.     else
  55.     {
  56.       Serial.println("recv failed");  //  "не удалось выполнить...
  57.                                       //  ...функцию recv()"
  58.     }
  59.   }
  60.   else
  61.   {
  62.     Serial.println("No reply, is nrf24_server running?");
  63.     //  "Ответа нет, nrf24_server вообще запущен?"
  64.   }
  65.   delay(400);
  66. }

Схема и код для сервера

Подключите серверную часть проекта в соответствии со схемой ниже:

Nrf24-radiohead-with-Arduino.png

Важно! Входное напряжение должно быть в диапазоне от 1,9 до 3,6 вольт. Если его превысить, вы можете запросто поджарить свой модуль.

Теперь загрузите на Arduino скетч ниже. Он уже будет встроен в IDE Arduino, т.к. тремя разделами выше вы установили в нее библиотеку Radiohead. Чтобы открыть скетч, кликните в IDE Arduino по Файл > Примеры > Radiohead > nrf24 > nrf24_server (File > Examples > Radiohead > nrf24 > nrf24_server).

  1. // Скетч «nrf24_server»
  2.  
  3. #include <SPI.h>
  4. #include <RH_NRF24.h>
  5.  
  6. // создаем экземпляр класса для трансивера:
  7. RH_NRF24 nrf24;
  8. // RH_NRF24 nrf24(8, 7);   // для электрической совместимости с Mirf
  9. // RH_NRF24 nrf24(8, 10);  // для Leonardo; также понадобится
  10.                            // явно определить контакт SS
  11. // RH_NRF24 nrf24(8, 7);   // для RFM73 на Anarduino Mini
  12.  
  13. void setup()
  14. {
  15.   Serial.begin(9600);
  16.   while (!Serial)
  17.     ; // ждем подключения последовательного порта
  18.       // (нужно только для Leonardo):
  19.   if (!nrf24.init())
  20.     Serial.println("init failed");  //  "инициализация не удалась"
  21.   // по умолчанию после инициализации трансивер настраивается
  22.   // со следующими параметрами: 2,402 ГГц (канал 2), 2 Мбит/сек, 0 дБм
  23.   if (!nrf24.setChannel(1))
  24.     Serial.println("setChannel failed");
  25.     //  "не удалось выполнить функцию setChannel()"
  26.   if (!nrf24.setRF(RH_NRF24::DataRate2Mbps, RH_NRF24::TransmitPower0dBm))
  27.     Serial.println("setRF failed");  
  28.     //  "не удалось выполнить функцию setRF()"  
  29. }
  30.  
  31. void loop()
  32. {
  33.   if (nrf24.available())
  34.   {
  35.     // сообщение уже должно прийти:  
  36.     uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
  37.     uint8_t len = sizeof(buf);
  38.     if (nrf24.recv(buf, &len))
  39.     {
  40. //      NRF24::printBuffer("request: ", buf, len);
  41.       Serial.print("got request: ");  //  "получен запрос: "
  42.       Serial.println((char*)buf);
  43.      
  44.       // отправляем ответ:
  45.       uint8_t data[] = "And hello back to you";  //  "И тебе привет!"
  46.       nrf24.send(data, sizeof(data));
  47.       nrf24.waitPacketSent();
  48.       Serial.println("Sent a reply");  //  "Отправляем ответ"
  49.     }
  50.     else
  51.     {
  52.       Serial.println("recv failed");  //  "не удалось выполнить...
  53.                                       //  ...функцию recv()"
  54.     }
  55.   }
  56. }

Демонстрация

В этом проекте клиент отправляет серверу через трансивер сообщение «Hello, world!» (т.е. «Привет, мир!», а сервер в ответ отправляет сообщение «And hello back to you» (т.е. «И тебе привет»). Оба сообщения будут показаны в мониторе порта, а сам он будет выглядеть следующим образом:

Serial-communication.jpg

Слева сообщения выводятся на PuTTY.org. Справа – на монитор порта IDE Arduino.

Качество связи

Не ждите от этого модуля слишком многого. Он работает очень неплохо, когда приемник и передатчик находятся рядом. Но если разместить их далеко друг от друга, связь может быть потеряна.

Кроме того, качество связи может зависеть и от других факторов. Это зависит от того, много ли радиочастотного шума в окружающем пространстве, есть ли в нем какие-нибудь преграды и используется ли внешняя антенна.

См.также

Внешние ссылки

  1. randomnerdtutorials.com - Complete Guide for nRF24L01 – 2.4GHz RF Transceiver Module With Arduino