Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/Гайд по использованию RTC-модуля DS1307 или DS3231 с Arduino

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Гайд по использованию RTC-модуля DS1307 или DS3231 с Arduino[1]

Эта статья объясняет, как использовать RTC-модуль (от «real time clock», что значит «часы реального времени») DS1307 вместе с платой Arduino. Впрочем, данное руководство подойдет и для других RTC-модулей вроде DS3231. RTC-модуль можно использовать как часы, таймер и т.д.

Описание

На то, как выглядит RTC-модуль, можно посмотреть на картинке ниже (вид спереди и сзади).

Rtc-front-and-back-view.png

Перед тем, как использовать RTC-модуль, вам нужно припаять к нему гребешок контактов.

Как видно на картинке выше, модуль оснащен запасной батарейкой. Благодаря этому модуль может по-прежнему считать время, даже не будучи подключенным к питанию от Arduino.

Другими словами, при каждом включении/выключении модуля время не сбрасывается.

Этот модуль использует коммуникацию типа I2C. Это значит, что он коммуницирует с Arduino при помощи всего 2 контактов.

Где купить?

RTC-модули стоят недорого и очень распространены. На eBay такой модуль можно купить примерно за 2 доллара.

Подключение контактов

В подключении RTC-модуля нет ничего сложного:

  • Контакт SCL на RTC-модуле – к контакту A5 на Arduino
  • Контакт SDA – к контакту A4
  • Контакт VCC – к контакту 5V
  • Контакт GND – к контакту GND

Если вы используете не Uno, а другую плату Arduino, то у нее контакты SCL и SDA могут находиться в других местах:

  • Arduino Nano: контакт SDA – это контакт A4, а SCL – это A5
  • Arduino MEGA и Arduino Leonardo: контакт SDA – это контакт 20, а SCL – это контакт 21

Скетч: Показ времени и даты на мониторе порта IDE Arduino

Схема

Подключите друг к другу RTC-модуль и плату Arduino в соответствии со схемой ниже:

Fritzing-RTC.png

Код

Для работы с RTC-модулем нужно сделать две важные вещи:

  • Настроить в скетче текущее время, чтобы RTC-модуль знал, сколько время.
  • Сделать так, чтобы текущее время не сбрасывалось, чтобы RTC-модуль всегда сообщал правильное время, даже будучи выключенным.

Настраиваем текущее время

Чтобы настроить текущее время, вам нужно поменять значения в функции setDS3231time().

Time setting RTC module.jpg

Параметры этой функции выделены красным и расположены в следующем порядке: секунды, минуты, часы, дни недели, дата, месяц и год. Воскресенье – это «1», а суббота – это «7». И не забудьте убрать знаки комментария (т.е. 2 слеша) у этой строчки.

Настроив текущее время, вы можете загрузить на Arduino код ниже. Он написан Джоном Боксэллом (John Boxall) с сайта tronixstuff.com. Соответствующее руководство можно почитать тут.

  1. // Автор – Джон Боксэлл (John Boxall), from http://tronixstuff.com
  2.  
  3. #include "Wire.h"
  4. #define DS3231_I2C_ADDRESS 0x68
  5. // конвертируем обычные десятичные значения в двоично-десятичный код:
  6. byte decToBcd(byte val){
  7.   return( (val/10*16) + (val%10) );
  8. }
  9. // конвертируем двоично-десятичный код в обычные десятичные значения:
  10. byte bcdToDec(byte val){
  11.   return( (val/16*10) + (val%16) );
  12. }
  13. void setup(){
  14.   Wire.begin();
  15.   Serial.begin(9600);
  16.   // задаем текущее время;
  17.   // секунды, минуты, часы, день недели, дата, месяц, год:
  18.   // setDS3231time(30,42,16,5,13,10,16);
  19. }
  20. void setDS3231time(byte second, byte minute, byte hour, byte dayOfWeek, byte
  21. dayOfMonth, byte month, byte year){
  22.   // передаем данные о времени и дате на DS3231:
  23.   Wire.beginTransmission(DS3231_I2C_ADDRESS);
  24.   // выставляем регистр указателей DS3231 на регистр «00h»,
  25.   // т.е. на регистр, в котором хранятся данные о секундах:
  26.   Wire.write(0);
  27.   Wire.write(decToBcd(second)); // задаем секунды
  28.   Wire.write(decToBcd(minute)); // задаем минуты
  29.   Wire.write(decToBcd(hour)); // задаем часы
  30.   Wire.write(decToBcd(dayOfWeek));
  31.   // задаем день недели (1 – это воскресенье, 7 – это суббота)
  32.   Wire.write(decToBcd(dayOfMonth)); // задаем дату (от 1 до 31)
  33.   Wire.write(decToBcd(month)); // задаем месяц
  34.   Wire.write(decToBcd(year)); // задаем год (от 0 до 99)
  35.   Wire.endTransmission();
  36. }
  37. void readDS3231time(byte *second,
  38. byte *minute,
  39. byte *hour,
  40. byte *dayOfWeek,
  41. byte *dayOfMonth,
  42. byte *month,
  43. byte *year){
  44.   Wire.beginTransmission(DS3231_I2C_ADDRESS);
  45.   // выставляем регистр указателей DS3231 на регистр «00h»:
  46.   Wire.write(0);
  47.   Wire.endTransmission();
  48.   Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  49.   // запрашиваем у DS3231 семь байтов начиная с регистра «00h»:
  50.   *second = bcdToDec(Wire.read() & 0x7f);
  51.   *minute = bcdToDec(Wire.read());
  52.   *hour = bcdToDec(Wire.read() & 0x3f);
  53.   *dayOfWeek = bcdToDec(Wire.read());
  54.   *dayOfMonth = bcdToDec(Wire.read());
  55.   *month = bcdToDec(Wire.read());
  56.   *year = bcdToDec(Wire.read());
  57. }
  58. void displayTime(){
  59.   byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
  60.   // извлекаем данные из DS3231:
  61.   readDS3231time(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month,
  62.   &year);
  63.   // отправляем их на монитор порта:
  64.   Serial.print(hour, DEC);
  65.   // при показе конвертируем байтовую переменную в десятичное число:
  66.   Serial.print(":");
  67.   if (minute<10){
  68.     Serial.print("0");
  69.   }
  70.   Serial.print(minute, DEC);
  71.   Serial.print(":");
  72.   if (second<10){
  73.     Serial.print("0");
  74.   }
  75.   Serial.print(second, DEC);
  76.   Serial.print(" ");
  77.   Serial.print(dayOfMonth, DEC);
  78.   Serial.print("/");
  79.   Serial.print(month, DEC);
  80.   Serial.print("/");
  81.   Serial.print(year, DEC);
  82.   Serial.print(" Day of week: ");  //  " День недели: "
  83.   switch(dayOfWeek){
  84.   case 1:
  85.     Serial.println("Sunday");  //  "Воскресенье"
  86.     break;
  87.   case 2:
  88.     Serial.println("Monday");  //  "Понедельник"
  89.     break;
  90.   case 3:
  91.     Serial.println("Tuesday");  //  "Вторник"
  92.     break;
  93.   case 4:
  94.     Serial.println("Wednesday");  //  "Среда"
  95.     break;
  96.   case 5:
  97.     Serial.println("Thursday");  //  "Четверг"
  98.     break;
  99.   case 6:
  100.     Serial.println("Friday");  //  "Пятница"
  101.     break;
  102.   case 7:
  103.     Serial.println("Saturday");  //  "Суббота"
  104.     break;
  105.   }
  106. }
  107. void loop(){
  108.   displayTime();
  109.  // показываем на мониторе порта текущие данные RTC-модуля  
  110.   delay(1000); // секундная задержка
  111. }

Делаем так, чтобы время не сбивалось

Если вы не хотите, чтобы время сбрасывалось при каждом выключении RTC-модуля, вам нужно закомментировать функцию, которая задает текущее время, а потом загрузить скетч снова.

Retaining time RTC module.jpg

Это очень важный момент. Если этого не сделать, то при каждом сбросе RTC-модуля время тоже будет сбрасываться на то, чтобы было указано при первой настройке. То есть текущее время показано не будет.

Демонстрация

Откройте монитор порта на скорости 9600 бод, чтобы посмотреть результат. Ниже – монитор порта, показывающий текущую дату и время.

Demonstration DS1307 RTC.png

См.также

Внешние ссылки

  1. randomnerdtutorials.com - Guide for Real Time Clock (RTC) Module with Arduino (DS1307 and DS3231)