Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/BarometricPressureWebServer

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Веб-сервер, публикующий данные от датчика атмосферного давления[1]

Этот пример показывает, как при помощи SPI-соединения считывать данные с датчика атмосферного давления SCP1000, а также то, как потом публиковать эти данные в интернет при помощи тандема Arduino и Ethernet Shield, работающих в качестве простого веб-сервера. Используя библиотеку Ethernet, ваш девайс будет отвечать на HTTP-запросы посредством передачи браузеру HTML-кода для отображения данных о температуре и атмосферном давлении, считанных с датчика.

Настроив цепь и загрузив скетч (см. ниже), просто введите в браузере IP-адрес Ethernet Shield, и на экране появятся данные от датчика.

Более подробно о том, как работает датчика атмосферного давления, можно узнать из примера «Использование SPI для считывания данных с датчика атмосферного давления».

Необходимое оборудование

  • Плата с датчиком атмосферного давления SCP1000;
  • Сетевой модуль Arduino Ethernet Shield;

Цепь

Датчик атмосферного давления нужно подсоединить к 6-ому, 7-ому, 11-ому, 12-ому и 13-ому контактам тандема «Arduino и Shield», а также запитать его через выходной 3,3-вольтовый контакт. Контакт DRDY (Data Ready, т.е. «данные готовы для считывания») подключите к 6-ому цифровому контакту, а контакт CSB (Chip Select; т.е. «выбор ведомого устройства») – к 7-ому.

Контакт MOSI (Master Out, Slave In; для передачи данных от ведущего устройства к ведомому) должен быть подключен к 11-ому цифровому контакту, а его «брат-близнец» MISO (Master In, Slave Out; для передачи данных от ведомого устройства к ведущему) – к 12-ому. И, наконец, контакт SCK (Serial Clock; для передачи последовательного тактового сигнала) подключите к 13-ому цифровому контакту, а также убедитесь, что оба устройства подключены к одной и той же «земле».

Закончив с подключением контактов, подсоедините Ethernet Shield к сети при помощи Ethernet-кабеля. Кроме того, вам надо будет поменять сетевые настройки, чтобы они соответствовали вашей сети.

BaromettricPressureSensorWebServer bb.png

Модуль Ethernet Shield крепится поверх платы Arduino.

Схема

BaromettricPressureSensorWebServer sch.png

Код

  1. /*
  2. Отображение данных от датчика атмосферного давления SCP1000
  3.  
  4. Этот скетч служит для вывода данных от датчика атмосферного давления на веб-страницу.
  5. Более подробно об этом датчике можно прочесть тут:
  6. - http://www.sparkfun.com/commerce/product_info.php?products_id=8161
  7. - http://www.vti.fi/en/support/obsolete_products/pressure_sensors
  8.  
  9. Этот скетч создан на основе примера Нэйтана Зидле (Nathan Seidle) для PIC:
  10. http://www.sparkfun.com/datasheets/Sensors/SCP1000-Testing.zip
  11.  
  12. Цепь:
  13. Датчик SCP1000 подключен к 6-ому, 7-ому, 11-ому, 12-ому и 13-ому цифровым контактам.
  14. * DRDY – к 6-ому
  15. * CSB – к 7-ому
  16. * MOSI – к 11-ому
  17. * MISO – к 12-ому
  18. * SCK – к 13-ому
  19.  
  20. Создан 31 июля 2010 Томом Иго (Tom Igoe)
  21. */
  22.  
  23. #include <Ethernet.h>
  24. // Датчик коммуницирует через SPI, поэтому подключаем соответствующую библиотеку:
  25. #include <SPI.h>
  26.  
  27.  
  28. // Здесь указываем MAC-адрес для Ethernet-контроллера:
  29. byte mac[] = {
  30.   0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
  31. // Указываем IP-адрес контроллера:
  32. IPAddress ip(192,168,1,20);
  33. IPAddress gateway(192,168,1,1);
  34. IPAddress subnet(255, 255, 255, 0);
  35.  
  36.  
  37. // Инициализируем библиотеку Ethernet Server
  38. // с необходимыми для нас IP-адресом и портом
  39. // (порт 80 используется для HTTP по умолчанию):
  40. EthernetServer server(80);
  41.  
  42.  
  43. // Адреса регистров памяти датчика:
  44. const int PRESSURE = 0x1F;      // 3 самых важных бита данных о давлении
  45. const int PRESSURE_LSB = 0x20;  // 16 менее важных битов данных о давлении
  46. const int TEMPERATURE = 0x21;   // 16 битов данных о температуре
  47.  
  48. // Контакты, которые используются для подключения к датчику
  49. // (другие необходимые вам контакты управляются библиотекой SPI):
  50. const int dataReadyPin = 6;
  51. const int chipSelectPin = 7;
  52.  
  53. float temperature = 0.0;
  54. long pressure = 0;
  55. long lastReadingTime = 0;
  56.  
  57. void setup() {
  58.   // Запускаем библиотеку SPI:
  59.   SPI.begin();
  60.  
  61.   // Запускаем Ethernet-соединение и работу сервера:
  62.   Ethernet.begin(mac, ip);
  63.   server.begin();
  64.  
  65.   // Инициализируем контакты Data Ready (DRDY) и Chip Select (CSB):
  66.   pinMode(dataReadyPin, INPUT);
  67.   pinMode(chipSelectPin, OUTPUT);
  68.  
  69.   Serial.begin(9600);
  70.  
  71.   // Настраиваем SCP1000, чтобы в данных было меньше шума:
  72.   writeRegister(0x02, 0x2D);
  73.   writeRegister(0x01, 0x03);
  74.   writeRegister(0x03, 0x02);
  75.  
  76.   // Даем немного времени датчику и Ethernet Shield – чтобы настроиться:
  77.   delay(1000);
  78.  
  79.   // Выставляем датчик в режим высокого разрешения – чтобы начать считывание:
  80.   writeRegister(0x03, 0x0A);
  81.  
  82. }
  83.  
  84. void loop() {
  85.   // Проверяем данные от датчика не чаще одного раза в секунду:
  86.   if (millis() - lastReadingTime > 1000){
  87.     // Если данные готовы, приступаем к их считыванию.
  88.     // Ничего не делам, пока контакт DRDY не получит значение HIGH:
  89.     if (digitalRead(dataReadyPin) == HIGH) {
  90.       getData();
  91.       // Делаем временную отметку о времени последнего считывания:
  92.       lastReadingTime = millis();
  93.     }
  94.   }
  95.  
  96.   // Слушаем входящие Ethernet-соединения:
  97.   listenForEthernetClients();
  98. }
  99.  
  100. void getData() {
  101.   Serial.println("Getting reading");  //  "Начинаем считывание"
  102.   // Считываем данные о температуре:
  103.   int tempData = readRegister(0x21, 2);
  104.  
  105.   // Конвертируем их в градусы Цельсия и выводим на экран:
  106.   temperature = (float)tempData / 20.0;
  107.  
  108.   // Считываем 3 самых важных бита в данных о давлении:
  109.   byte  pressureDataHigh = readRegister(0x1F, 1);  
  110.   pressureDataHigh &= 0b00000111; // вам нужны лишь биты со 2-ого по 0-ой
  111.  
  112.   // Считываем другие 16 битов данных о давлении:
  113.   unsigned int pressureDataLow = readRegister(0x20, 2);    
  114.   // Соединяем обе части в одного 19-битное число:
  115.   pressure = ((pressureDataHigh << 16) | pressureDataLow)/4;
  116.  
  117.   Serial.print("Temperature: ");  //  "Температура: "
  118.   Serial.print(temperature);
  119.   Serial.println(" degrees C");  //  " градусов Цельсия"
  120.   Serial.print("Pressure: " + String(pressure));  //  "Давление: "
  121.   Serial.println(" Pa"); //  " паскалей"
  122. }
  123. void listenForEthernetClients() {
  124.   // Слушаем подключающихся клиентов:
  125.   EthernetClient client = server.available();
  126.   if (client) {
  127.     Serial.println("Got a client");  //  "Клиент подключен"
  128.     // HTTP-запрос заканчивается пустой линией:
  129.     boolean currentLineIsBlank = true;
  130.     while (client.connected()) {
  131.       if (client.available()) {
  132.         char c = client.read();
  133.         // Если вы добрались до конца строки (получили символ новой строки),
  134.         // и эта строка – пустая, это значит, что это конец HTTP-запроса,
  135.         // так что теперь можно слать ответ:
  136.         if (c == '\n' && currentLineIsBlank) {
  137.           // Отправляем стандартный для HTTP-ответа заголовок:
  138.           client.println("HTTP/1.1 200 OK");
  139.           client.println("Content-Type: text/html");
  140.           client.println();
  141.           // Передаем считанные данные (в HTML-формате):
  142.           client.print("Temperature: ");
  143.           client.print(temperature);
  144.           client.print(" degrees C");
  145.           client.println("<br />");
  146.           client.print("Pressure: " + String(pressure));
  147.           client.print(" Pa");
  148.           client.println("<br />");  
  149.           break;
  150.         }
  151.         if (c == '\n') {
  152.           // Начинаем новую строку:
  153.           currentLineIsBlank = true;
  154.         }
  155.         else if (c != '\r') {
  156.           // У нас есть символ в текущей строке:
  157.           currentLineIsBlank = false;
  158.         }
  159.       }
  160.     }
  161.     // Даем браузеру немного времени, чтобы получить данные:
  162.     delay(1);
  163.     // Прерываем соединение:
  164.     client.stop();
  165.   }
  166. }
  167.  
  168. // Передаем на SCP1000 команду записи:
  169. void writeRegister(byte registerName, byte registerValue) {
  170.   // SCP1000 ожидает, что имя регистра указано в первых («верхних») шести битах байта:
  171.   registerName <<= 2;
  172.   // Сама команда (считывание или запись) располагается в двух последних («нижних») битах:
  173.   registerName |= 0b00000010; // команда записи
  174.  
  175.   // Даем контакту Chip Select значение LOW, чтобы выбрать девайс:
  176.   digitalWrite(chipSelectPin, LOW);
  177.  
  178.   SPI.transfer(registerName); // отсылаем адрес регистра
  179.   SPI.transfer(registerValue); // отсылаем значение, чтобы записать его в регистр
  180.  
  181.   // Даем контакту Chip Select значение HIGH, чтобы отменить выбор девайса:
  182.   digitalWrite(chipSelectPin, HIGH);
  183. }
  184.  
  185.  
  186. // Считываем данные из регистра SCP1000:
  187. unsigned int readRegister(byte registerName, int numBytes) {
  188.   byte inByte = 0;           // данные, считанные через SPI
  189.   unsigned int result = 0;   // результат, который нужно вернуть
  190.  
  191.   // SCP1000 ожидает, что название регистра будет в первых («верхних») шести битах байта:
  192.   registerName <<=  2;
  193.   // Команда (считывание или запись) идет в последних («нижних») двух битах:
  194.   registerName &= 0b11111100; // команда считывания
  195.  
  196.   // Даем контакту Chip Select значение LOW, чтобы выбрать девайс:
  197.   digitalWrite(chipSelectPin, LOW);
  198.   // Отсылаем девайсу информацию о регистре, данные которого хотим сосчитать:
  199.   int command = SPI.transfer(registerName);
  200.   // Отсылаем «0», чтобы сосчитать первый возвращенный байт:
  201.   inByte = SPI.transfer(0x00);
  202.  
  203.   result = inByte;
  204.   // Если было возвращено более одного байта,
  205.   // перемещаемся от первого байта ко второму:
  206.   if (numBytes > 1){
  207.     result = inByte << 8;
  208.     inByte = SPI.transfer(0x00);
  209.     result = result |inByte;
  210. }
  211.   // Даем контакту Chip Select значение HIGH, чтобы отменить выбор девайса:
  212.   digitalWrite(chipSelectPin, HIGH);
  213.   // Возвращаем результат:
  214.   return(result);
  215. }

См.также

  1. Arduino Ethernet Shield
  2. Getting started with the ethernet shield
  3. Ethernet library
  4. ChatServer
  5. ChatClient
  6. WebClient
  7. WebServer
  8. PachubeClient?
  9. PachubeClientString?
  10. BarometricPressureWebServer
  11. UDPSendReceiveString
  12. UdpNtpClient

Внешние ссылки

  1. Arduino - Barometric Pressure Web Server