Arduino:Примеры/ScanNetworks

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Сканирование WiFi-сетейArduino -

Это скетч при помощи платы Arduino и модуля Arduino WiFi Shield сканирует близлежащие 802.11b/g сети. Затем, проведя сканирование, Arduino при помощи Serial Monitor показывает информацию о себе и найденных сетях. Но на подключение к сети этот пример не запрограммирован.

Необходимое оборудование

  • Сетевой модуль Arduino WiFi Shield;
  • Плата Arduino, совместимая с Shield;

Цепь

WiFi Shield для SPI-соединения с модулем HDG104 использует 10-ый, 11-ый, 12-ый и 13-ый контакты. Для управления SS-контактом SD-карты используется 4-ый цифровой контакт.

Откройте Serial Monitor, чтобы видеть сети, найденные WiFi Shield. Впрочем, количество сетей, которые он может найти, будет не таким большим, как если бы это был компьютер.

На картинке выше модуль WiFi Shield установлен поверх платы Arduino.

Код

/*
Этот скетч печатает на Serial Monitor MAC-адрес WiFi Shield, 
а затем с его помощью сканирует доступные WiFi-сети. 
При этом сканирование происходит каждые 10 секунд, но самого
подключения, собственно, не происходит. 

Цепь:
* WiFi Shield, подключенный к Arduino

Создан 13 июля 2010 пользователем dlf (Metodo2 srl),
модифицирован 21 июня 2012 
Томом Иго (Tom Igoe) и Джеймсом Деком (Jaymes Dec).
*/

#include <SPI.h>
#include <WiFi.h>

void setup() {
  // Инициализируем последовательную передачу данных и ждем открытия порта:
  Serial.begin(9600); 
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для Leonardo)
  }

  // Проверяем наличие WiFi Shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");  //  "WiFi Shield не подключен"
    // Дальше не продолжаем:
    while(true);
  } 

  // Показываем MAC-адрес WiFi Shield в окне Serial Monitor:
  printMacAddress();

  // Сканируем близлежащие сети:
  Serial.println("Scanning available networks...");  //  "Сканируем доступные сети..."
  listNetworks();
}

void loop() {
  delay(10000);
  // Еще раз то же самое, только в блоке loop():
  Serial.println("Scanning available networks...");  //  "Сканируем доступные сети..."
  listNetworks();
}

//  Пользовательская функция, с помощью которой мы будем выводить MAC-адрес на Serial Monitor:
void printMacAddress() {
  // MAC-адрес вашего WiFi Shield:
  byte mac[6];                     

  // Поэтапная печать MAC-адреса:
  WiFi.macAddress(mac);
  Serial.print("MAC: ");  //  "MAC-адрес: "
  Serial.print(mac[5],HEX);
  Serial.print(":");
  Serial.print(mac[4],HEX);
  Serial.print(":");
  Serial.print(mac[3],HEX);
  Serial.print(":");
  Serial.print(mac[2],HEX);
  Serial.print(":");
  Serial.print(mac[1],HEX);
  Serial.print(":");
  Serial.println(mac[0],HEX);
}

// Пользовательская функция, с помощью которой мы будем сканировать доступные сети:
void listNetworks() {
  // Сканируем сети:
  Serial.println("** Scan Networks **");  //  "** Сканирование сетей **"

  int numSsid = WiFi.scanNetworks();
  if (numSsid == -1)
  { 
    Serial.println("Couldn't get a wifi connection");   //  "Доступных сетей нет"

    while(true);
  } 

  // Показываем количество доступных сетей:
  Serial.print("number of available networks:");  //  "Число доступных сетей: "

  Serial.println(numSsid);

  // Показываем номер и название каждой обнаруженной сети:
  for (int thisNet = 0; thisNet<numSsid; thisNet++) {
    Serial.print(thisNet);
    Serial.print(") ");
    Serial.print(WiFi.SSID(thisNet));
    Serial.print("\tSignal: ");  //  "\tСигнал: "
    Serial.print(WiFi.RSSI(thisNet));
    Serial.print(" dBm");
    Serial.print("\tEncryption: ");  //  "\tШифрование: "
    printEncryptionType(WiFi.encryptionType(thisNet));
  }
}

//  Пользовательская функция для считывания и отображения типа шифрования:
void printEncryptionType(int thisType) {
  switch (thisType) {
  case ENC_TYPE_WEP:
    Serial.println("WEP");
    break;
  case ENC_TYPE_TKIP:
    Serial.println("WPA");
    break;
  case ENC_TYPE_CCMP:
    Serial.println("WPA2");
    break;
  case ENC_TYPE_NONE:
    Serial.println("None");  //  "Без шифрования"
    break;
  case ENC_TYPE_AUTO:
    Serial.println("Auto");  //  "Автоматически"
    break;
  } 
}

См.также

  1. ConnectNoEncryption : Demonstrates how to connect to an open network
  2. ConnectWithWEP : Demonstrates how to connect to a network that is encrypted with WEP
  3. ConnectWithWPA : Demonstrates how to connect to a network that is encrypted with WPA2 Personal
  4. ScanNetworks : Displays all WiFi networks in range
  5. WiFiChatServer : Set up a simple chat server
  6. WiFiWebClient : Connect to a remote webserver
  7. WiFiWebClientRepeating: Repeatedly make HTTP calls to a server
  8. WiFiWebServer : Serve a webpage from the WiFi shield

Внешние ссылки