Arduino:Примеры/SendandReceiveBinaryArguments

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Получение и отправка команд с двоичными аргументами [1]

Этот пример является расширенной версией примера «Получение и отправка команд с аргументами» и демонстрирует, как отправлять и получать несколько бинарных значений.

Код

// *** Получение и отправка команд с двоичными аргументами ***

// Это расширенная версия примера «Получение и отправка команд 
// с аргументами». Здесь демонстрируется более компактный и быстрый 
// способ передачи данных – посредством двоичных значений. 
// Запись логов отключена, а символы новой строки удаляются, поскольку 
// итоговый результат уже не является удобочитаемым текстом.
//
// Этот скетч демонстрирует, как:
// - отправлять двоичные аргументы
// - получать двоичные аргументы


#include <CmdMessenger.h>  // CmdMessenger

// привязываем экземпляр класса CmdMessenger к последовательному порту:
CmdMessenger cmdMessenger = CmdMessenger(Serial);

// Это список распознаваемых команд, и эти команды могут быть 
// либо получены, либо отправлены. Чтобы получить команду, к этому 
// событию нужно привязать функцию внешнего вызова.
enum
{
    kRequestPlainTextFloatSeries , // команда, запрашивающая отправку порции обычного текста
    kReceivePlainTextFloatSeries , // команда, отправляющая фрагмент обычного текста
    kRequestBinaryFloatSeries    , // команда, запрашивающая отправку порции текста в двоичной форме
    kReceiveBinaryFloatSeries    , // команда, отправляющая фрагмент текста в двоичной форме
};

// функции внешнего вызова, определяющие, при получении каких команд нам нужно начинать действовать:
void attachCommandCallbacks()
{
  // подключаем функции внешнего вызова:
  cmdMessenger.attach(OnUnknownCommand);
  cmdMessenger.attach(kRequestPlainTextFloatSeries, OnRequestPlainTextFloatSeries);
  cmdMessenger.attach(kRequestBinaryFloatSeries,    OnRequestBinaryFloatSeries);
}

// ------------------  ФУНКЦИИ ВНЕШНЕГО ВЫЗОВА  -----------------------

// эта функция вызывается, когда к присланной команде не привязано никакой функции:
void OnUnknownCommand()
{
  cmdMessenger.sendCmd(0,"Command without attached callback");  //  "Команда без функции внешнего вызова"
}

// функция внешнего вызова, рассчитывающая сумму двух присланных float-значений:
void OnRequestPlainTextFloatSeries()
{
  // получаем длину порции из первого аргумента:
  int16_t seriesLength = cmdMessenger.readInt16Arg();
  float seriesBase     = cmdMessenger.readFloatArg();
 
  // отправляем обратно серию float-значений:
  for(int i=0;i< seriesLength;i++) {
     cmdMessenger.sendCmdStart (kReceivePlainTextFloatSeries);
     cmdMessenger.sendCmdArg<uint16_t>((uint16_t)i);
     cmdMessenger.sendCmdArg<float>(((float)i*(float)seriesBase),6);
     cmdMessenger.sendCmdEnd ();
  }
}

// функция внешнего вызова, рассчитывающая сумму двух присланных float-значений:
void OnRequestBinaryFloatSeries()
{
  // получаем длину порции из первого аргумента:
  int16_t seriesLength = cmdMessenger.readBinArg<uint16_t>();
  float seriesBase     = cmdMessenger.readBinArg<float>(); 

  // отключаем символы новой строки – это сэкономит нам по два символа в каждой команде:
  cmdMessenger.printLfCr(false); 
  // отправляем обратно серию float-значений:
  for(int i=0;i< seriesLength;i++) {
     cmdMessenger.sendCmdStart (kReceiveBinaryFloatSeries);
     cmdMessenger.sendCmdBinArg<uint16_t>((uint16_t)i);
     cmdMessenger.sendCmdBinArg<float>(((float)i*(float)seriesBase));
     cmdMessenger.sendCmdEnd ();
  }
  // снова включаем символы новой строки – для удобочитаемости:
  cmdMessenger.printLfCr(true); 
}

// ------------------ ГЛАВНАЯ ЧАСТЬ СКЕТЧА ----------------------

// блок исходных операций:
void setup() 
{
  // прослушиваем последовательное соединение на предмет сообщений от PC:
  Serial.begin(115200); 

  // добавляем к каждой команде символ новой строки:
  cmdMessenger.printLfCr();   

  // подключаем функции внешнего вызова, заданные пользователем:
  attachCommandCallbacks();
}

// возвращаем «true», если время превысило заданный интервал 
// (в миллисекундах); используется для периодических действий:
bool hasExpired(unsigned long &prevTime, unsigned long interval) {
  if (  millis() - prevTime > interval ) {
    prevTime = millis();
    return true;
  } else     
    return false;
}

// блок повторяющихся операций:
void loop() 
{
  // обрабатываем данные, пришедшие по последовательному соединению,
  // и выполняем функции внешнего вызова:
  cmdMessenger.feedinSerialData(); 
}

См.также

Внешние ссылки