Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/WebClientRepeating

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Веб-клиент на базе Arduino, делающий повторяющиеся запросы[1]

Этот пример демонстрирует, как при помощи Ethernet Shield делать повторяющиеся HTTP-запросы. Мы будем использовать DNS, присваивая Ethernet-клиенту MAC-, IP- и DNS-адрес. Скетч будет подключаться к странице http://www.arduino.cc/latest.txt, а ее содержание будет отображаться через Serial Monitor.

Необходимое оборудование

  • Сетевой модуль Arduino Ethernet Shield;
  • Плата Arduino, совместимая с Ethernet Shield;

Цепь

Ethernet Shield позволяет подключить плату Arduino к контроллеру WizNet Ethernet (через SPI-шину), и это подключение осуществляется через 10-ый, 11-ый, 12-ый и 13-ый контакты. У последних моделей Ethernet Shield имеется встроенный слот для SD-карты, а управление SS-контактом этой SD-карты осуществляется через 4-ый цифровой контакт.

Ethernet Shield должен подключен к сети при помощи Ethernet-кабеля. Кроме того, сетевые настройки скетча нужно будет поменять, чтобы они соответствовали настройкам вашей сети.

EthernetShield bb.png

Ethernet Shield устанавливается поверх платы Arduino.

Схема

EthernetShield sch.png

Код

  1. /*
  2. Веб-клиент на базе Arduino, делающий повторяющиеся запросы
  3.  
  4. Этот скетч подключается к веб-серверу, а затем при помощи
  5. Ethernet Shield делает HTTP-запрос.
  6. Для этого примера подойдет и Arduino Ethernet Shield,
  7. и Adafruit Ethernet Shield (если у него будет модуль WizNet Ethernet).
  8.  
  9. Кроме того, этот скетч использует DNS, присваивая Ethernet-клиенту
  10. MAC-адрес, IP-адрес и DNS-адрес.
  11.  
  12. Цепь:
  13. * Ethernet Shield, подключенный к 10-ому, 11-ому, 12-ому и 13-ому контактам
  14.  
  15. Создан 19 апреля 2012 Томом Иго (Tom Igoe)
  16.  
  17. http://arduino.cc/en/Tutorial/WebClientRepeating
  18.  
  19. Этот код не защищен авторским правом.
  20. */
  21.  
  22. #include <SPI.h>
  23. #include <Ethernet.h>
  24.  
  25. // Присваиваем Ethernet-контроллеру MAC-адрес.
  26. // Свой адрес вставьте здесь:
  27. byte mac[] = {
  28.   0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
  29. // Вписываем IP-адрес, доступный для вашей сети (для ручной настройки):
  30. IPAddress ip(10,0,0,20);
  31.  
  32. // Здесь вписываем ваш DNS-адрес:
  33. IPAddress myDns(1,1,1,1);
  34.  
  35. // Создаем экземпляр класса:
  36. EthernetClient client;
  37.  
  38. char server[] = "www.arduino.cc";
  39.  
  40. unsigned long lastConnectionTime = 0;          // время, когда вы в последний раз подключались к серверу (в миллисекундах)
  41. boolean lastConnected = false;                 // статус подключения при последнем проходе через главный цикл
  42. const unsigned long postingInterval = 60*1000;  // задержка между апдейтами (в миллисекундах)
  43.  
  44. void setup() {
  45.   // Запускаем последовательную передачу данных:
  46.   Serial.begin(9600);
  47.   // Даем Ethernet-модулю время для загрузки:
  48.   delay(1000);
  49.   // Запускаем Ethernet-соединение при помощи фиксированного IP-адреса и DNS-адреса:
  50.   Ethernet.begin(mac, ip, myDns);
  51.   // Выводим IP-адрес Ethernet Shield:
  52.   Serial.print("My IP address: ");  //  "Мой IP-адрес: "
  53.   Serial.println(Ethernet.localIP());
  54. }
  55.  
  56. void loop() {
  57.   // Если через интернет-соединение пришли какие-то данные,
  58.   // пересылаем их на последовательный порт.
  59.   // Это нужно только в отладочных целях:
  60.   if (client.available()) {
  61.     char c = client.read();
  62.     Serial.print(c);
  63.   }
  64.  
  65.   // Если интернет-соединения нет, но при последнем проходе через цикл оно было,
  66.   // то останавливаем работу клиента:
  67.   if (!client.connected() && lastConnected) {
  68.     Serial.println();
  69.     Serial.println("disconnecting.");  //  "Отключение..."
  70.     client.stop();
  71.   }
  72.  
  73.   // Если вы не подключены, а с момента последнего подключения прошло 10 секунд,
  74.   // подключаемся снова и отсылаем данные:
  75.   if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
  76.     httpRequest();
  77.   }
  78.   // Сохраняем статус соединения для следующего прохода через цикл:
  79.   lastConnected = client.connected();
  80. }
  81.  
  82. // Эта функция будет осуществлять HTTP-соединение к серверу:
  83. void httpRequest() {
  84.   // Если подключение прошло успешно:
  85.   if (client.connect(server, 80)) {
  86.     Serial.println("connecting...");  //  "Подключение..."
  87.     // Отсылаем HTTP PUT запрос:
  88.     client.println("GET /latest.txt HTTP/1.1");
  89.     client.println("Host: www.arduino.cc");
  90.     client.println("User-Agent: arduino-ethernet");
  91.     client.println("Connection: close");
  92.     client.println();
  93.  
  94.     // Отмечаем время, когда было сделано соединение:
  95.     lastConnectionTime = millis();
  96.   }
  97.   else {
  98.     // Если подключиться не удалось:
  99.     Serial.println("connection failed");  //  "Подключиться не удалось"
  100.     Serial.println("disconnecting.");  //  "Отключение."
  101.     client.stop();
  102.   }
  103. }

См.также

  1. Arduino Ethernet Shield
  2. Getting started with the ethernet shield
  3. Ethernet library
  4. ChatServer
  5. ChatClient
  6. WebClient
  7. WebServer
  8. PachubeClient?
  9. PachubeClientString?
  10. BarometricPressureWebServer
  11. UDPSendReceiveString
  12. UdpNtpClient

Внешние ссылки

  1. Arduino - Web Client Repeating