Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/WebServer

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Веб-сервер на базе Arduino[1]

В этом примере мы воспользуемся платой Arduino, модулем Ethernet Shield и библиотекой Ethernet для создания простого веб-сервера, который сможет отвечать на HTTP-запросы. Для того, чтобы воспользоваться этим веб-сервером, вам надо будет открыть браузер и вписать IP-адрес Ethernet Shield, после чего Arduino сгенерирует достаточно HTML-кода, чтобы отобразить в браузере входные данные ото всех шести аналоговых контактов.

Необходимое оборудование

  • Сетевой модуль Arduino Ethernet Shield;
  • Плата Arduino, совместимая с Ethernet Shield;

Цепь

Ethernet Shield позволяет подключить Arduino к Ethernet-контроллеру WizNet (через SPI-шину), и это подключение осуществляется через 10-ый, 11-ый, 12-ый и 13-ый контакты. У последних моделей Ethernet Shield имеется встроенный слот для SD-карты, а для управления SS-контактом этой SD-карты используется 4-ый цифровой контакт.

Ethernet Shield должен быть подключен к сети при помощи Ethernet-кабеля. Кроме того, в скетче нужно будет поменять сетевые настройки, чтобы они соответствовали настройкам вашей сети.

EthernetShield bb.png

Ethernet Shield устанавливается поверх платы Arduino.

Схема

EthernetShield sch.png

Внимание! SD-карта для этого скетча не нужна. Однако в случае, если SD-карта все же будет вставлена, но использоваться не будет, то скетч может зависнуть, потому что 4-ый контакт используется как SS-контакт SD-карты, а будучи неиспользованным он по умолчанию воспринимается как входной контакт. Вот два возможных решения:

  • Выньте SD-карту;
  • Добавьте в секции setup() вот эти строчки кода:
  1. pinMode(4, OUTPUT);
  2. digitalWrite(4, HIGH);

Код

  1. /*
  2. Веб-сервер на базе Arduino
  3.  
  4. Простой веб-сервер, который показывает значения от входных аналоговых контактов
  5. при помощи Arduino Ethernet Shield на базе WizNet.
  6.  
  7. Цепь:
  8. * Ethernet Shield подключен к 10-ому, 11-ому, 12-ому и 13-ому контактам
  9. * Аналоговые устройства, подключенные к шести входным аналоговым контактам (с 0-ого по 5-ый)
  10.  
  11. Создан 18 декабря 2009 Дэвидом А. Меллисом (David A. Mellis),
  12. модифицирован 9 апреля 2012 Томом Иго (Tom Igoe).
  13. */
  14.  
  15. #include <SPI.h>
  16. #include <Ethernet.h>
  17.  
  18. // Ниже вводим MAC-адрес и IP-адрес контроллера.
  19. // IP-адрес будет зависеть от вашей локальной сети:
  20. byte mac[] = {
  21.   0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
  22. };
  23. IPAddress ip(192, 168, 1, 177);
  24.  
  25. // Инициализируем библиотеку Ethernet Server
  26. // с необходимыми вам IP-адресом и портом
  27. // (порт 80 используется для HTTP по умолчанию):
  28. EthernetServer server(80);
  29.  
  30. void setup() {
  31.   // Открываем последовательную передачу данных и ждем открытия порта:
  32.   Serial.begin(9600);
  33.   while (!Serial) {
  34.     ; // ждем подключения последовательного порта (нужно только для Leonardo)
  35.   }
  36.  
  37.   // Запускаем Ethernet-соединение и работу сервера:
  38.   Ethernet.begin(mac, ip);
  39.   server.begin();
  40.   Serial.print("server is at ");  //  "Сервер по адресу "
  41.   Serial.println(Ethernet.localIP());
  42. }
  43.  
  44.  
  45. void loop() {
  46.   // Слушаем подключающихся клиентов:
  47.   EthernetClient client = server.available();
  48.   if (client) {
  49.     Serial.println("new client");  //  "Новый клиент"
  50.     // HTTP-запрос заканчивается пустой линией:
  51.     boolean currentLineIsBlank = true;
  52.     while (client.connected()) {
  53.       if (client.available()) {
  54.         char c = client.read();
  55.         Serial.write(c);
  56.         // Если добрались до конца строки (т.е. получили символ новой строки),
  57.         // и эта строка – пустая, это значит, что это конец HTTP-запроса.
  58.         // То есть, можно приступать к отправке ответа:
  59.         if (c == '\n' && currentLineIsBlank) {
  60.           // Отсылаем стандартный заголовок для HTTP-ответа:
  61.           client.println("HTTP/1.1 200 OK");
  62.           client.println("Content-Type: text/html");
  63.           client.println("Connection: close");  // после выполнения ответа соединение будет разорвано
  64.           client.println("Refresh: 5");  // автоматически обновляем страницу каждые 5 секунд
  65.           client.println();
  66.           client.println("<!DOCTYPE HTML>");
  67.           client.println("<html>");
  68.           // Выводим значения ото всех входных аналоговых контактов:
  69.           for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
  70.             int sensorReading = analogRead(analogChannel);
  71.             client.print("analog input ");
  72.             client.print(analogChannel);
  73.             client.print(" is ");
  74.             client.print(sensorReading);
  75.             client.println("<br />");
  76.           }
  77.           client.println("</html>");
  78.           break;
  79. }
  80.         if (c == '\n') {
  81.           // Начинаем новую строку:
  82.           currentLineIsBlank = true;
  83.         }
  84.         else if (c != '\r') {
  85.           // В текущей строке есть символ:
  86.           currentLineIsBlank = false;
  87.         }
  88.       }
  89.     }
  90.     // Даем браузеру время, чтобы получить данные:
  91.     delay(1);
  92.     // Закрываем соединение:
  93.     client.stop();
  94.     Serial.println("client disconnected");  //  "Клиент отключился"
  95.  
  96.   }
  97. }

См.также

  1. Arduino Ethernet Shield
  2. Getting started with the ethernet shield
  3. Ethernet library
  4. ChatServer
  5. ChatClient
  6. WebClient
  7. WebServer
  8. PachubeClient?
  9. PachubeClientString?
  10. BarometricPressureWebServer
  11. UDPSendReceiveString
  12. UdpNtpClient

Внешние ссылки

  1. Arduino - Web Server