Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

ESP32:Примеры/Использование ESP32 вместе с PIR-датчиком движения

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2753 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Использование ESP32 вместе с PIR-датчиком движения

В этом примере мы научимся обнаруживать движения при помощи PIR-датчика движения. В нашем проекте-примере плата ESP32, обнаружив движение, запустит таймер, а затем включит светодиод на предварительно заданное количество секунд. Когда отсчет таймера завершится, светодиод автоматически выключится.

В этом примере мы представим два новых концепта: прерывания и таймеры.

Чтобы запустить событие при помощи PIR-датчика движения, вам понадобятся прерывания. Они используются для автоматического выполнения задач в микроконтроллерных программах и хороши при решении проблем, завязанных на время.

Благодаря прерываниям вам не нужно постоянно проверять текущее значение контакта. Потому что, когда значение изменится, это событие запустится само (с помощью вызова функции). В IDE Arduino для того, чтобы задать прерывание, используется функция attachInterrupt(). Она принимает три параметра: GPIO-контакт, название выполняемой функции и режим работы:

attachInterrupt(digitalPinToInterrupt(GPIO), funcion, mode);

Теперь о каждом из этих параметров более подробно.

Первый параметр – это номер GPIO-контакта, на котором выполняется прерывание. Как правило, чтобы на каком-либо GPIO-контакте можно было использовать прерывания, для него необходимо вызвать функцию digitalPinToInterrupt(GPIO). К примеру, чтобы использовать для прерываний контакт GPIO27, в коде нужно написать следующее:

digitalPinToInterrupt(27)

На схеме ниже GPIO-контакты, которые можно использовать для прерываний, помечены красной рамкой. В нашем проекте для прерываний, вызванных данными от PIR-датчика движения, будет использоваться контакт GPIO27.

Esp32 board esp-wroom-32 1.PNG

Второй параметр функции attachInterrupt() – это «function», т.е. функция, запускаемая при каждом прерывании.

Третий параметр – это «mode», т.е. режим активации прерывания. Всего их 5:

  • LOW – прерывание будет запущено, если на контакте будет значение «LOW»
  • HIGH – прерывание будет запущено, если на контакте будет значение «HIGH»
  • CHANGE – прерывание будет запущено, если значение на контакте изменится (например, с «LOW» на «HIGH» или с «HIGH» на «LOW»)
  • FALLING – прерывание будет запущено, если значение на контакте изменится с «HIGH» на «LOW»
  • RISING – прерывание будет запущено, если значение на контакте изменится с «LOW» на «HIGH»

В этом примере мы воспользуемся режимом «RISING», т.к. когда PIR-датчик движения определяет движение, GPIO-контакт, к которому он подключен, переключается с «LOW» на «HIGH».

В этом проекте-примере мы также впервые воспользуемся таймером. Нам нужно, чтобы светодиод после обнаружения движения оставался включенным определенное количество секунд. Вместо функции delay(), которая просто блокирует код и не дает ему ничего делать в течение заданного количества секунд, мы воспользуемся таймером.

Ранее мы использовали функцию delay(), которая работала очень просто. Ее единственным параметром служит целочисленное значение (int) – в нем задается количество миллисекунд, которые программа будет ждать до перехода к следующей строчке кода.

delay(время_в_миллисекундах)

Например, если вписать в код delay(1000), программа затормозит на этой строчке на 1 секунду.

То есть функция delay() – это блокирующая функция. Блокирующие функции не дают программе делать что-либо до того, пока не будет выполнена некоторая задача. Если вы хотите, чтобы ваш код одновременно выполнял несколько задач, функцию delay() использовать нельзя.

В большинстве проектов нужно избегать функции delay(), используя вместо нее таймер.

Функция millis() возвращает количество миллисекунд, прошедших с момента запуска программы.

millis()

Что делает эту функцию полезной? Проделав некоторые несложные расчеты, вы можете легко проверить, сколько времени прошло, не блокируя при этом весь код.

Загрузите этот код на ESP32. Перед этим убедитесь, что в IDE Arduino выбраны правильная плата и COM-порт. Откройте монитор порта на скорости 115200 бод.

Поместите руку перед PIR-датчиком движения. Светодиод должен включиться, а в мониторе порта должно появиться сообщение «MOTION DETECTED!!!» Спустя 10 секунд светодиод должен выключиться.

Давайте рассмотрим этот код более подробно.

В начале задаем номера GPIO-контактов для светодиода и PIR-датчика движения в переменных «led» и «motionSensor».

  1. const int led = 26;
  2. const int motionSensor = 27;

Затем создаем переменные, позволяющие задать таймер для выключения светодиода после обнаружения движения.

  1. unsigned long now = millis();
  2. unsigned long lastTrigger = 0;
  3. boolean startTimer = false;

Переменная «now» служит для хранения текущего времени. В переменной «lastTrigger» хранится время, когда PIR-датчик определил движение. Переменная «startTimer» – это булева переменная, которая запускает таймер после обнаружения движения.

В блоке setup() сначала инициализируем последовательную коммуникацию на 115200 бод.

Serial.begin(115200);

Выставляем контакт PIR-датчика движения в режим «INPUT_PULLUP».

pinMode(motionSensor, INPUT_PULLUP);

Далее используем описанную выше функцию attachInterrupt(), чтобы сделать контакт PIR-датчика контактом для прерываний.

  1. attachInterrupt(digitalPinToInterrupt(motionSensor), detectsMovement, RISING);

Таким образом, благодаря этой функции мы задаем, что если на контакте GPIO27 будет вызвано прерывание типа «RISING», это запустит функцию detectsMovement().

Делаем контакт «led» выходным (OUTPUT) контактом, а его начальным значением делаем «LOW».

  1. pinMode(led, OUTPUT);
  2. digitalWrite(led, LOW);

Код в блоке loop() будет повторяться снова и снова. Таким образом, при каждом проходе через loop() в переменную «now» будет записываться текущее время.

now = millis();

Больше никаких задач в блоке loop() не выполняется. Но при обнаружении движения вызывается функция detectsMovement(), т.к. ранее мы задали ее в блоке setup() как функцию, запускаемую при прерывании.

Эта функция печатает в мониторе порта сообщение «MOTION DETECTED!!!» («ОБНАРУЖЕНО ДВИЖЕНИЕ!!!»), включает светодиод, записывает в булеву переменную «startTimer» значение «true» и записывает в переменную «lastTrigger» текущее время.

  1. void IRAM_ATTR detectsMovement() {
  2.  Serial.println("MOTION DETECTED!!!");
  3.             //  "ОБНАРУЖЕНО ДВИЖЕНИЕ!!!"
  4.  digitalWrite(led, HIGH);
  5.  startTimer = true;
  6.  lastTrigger = millis();
  7. }

Примечание: Конструкция «IRAM_ATTR» используется для того, чтобы запустить код прерывания в памяти RAM. В противном случае код будет сохранен на flash-память, из-за чего программа будет работать медленнее.

После этого код снова возвращается в блок loop().

Сейчас в переменной «startTimer» хранится значение «true». Таким образом, при прошествии заданного количества секунд после обнаружения движения результатом if() будет «true».

  1. if(startTimer && (now - lastTrigger > (timeSeconds*1000))) {
  2.  Serial.println("Motion stopped...");
  3.             //  "Движение прекратилось..."
  4.  digitalWrite(led, LOW);
  5.  startTimer = false;
  6. }

В результате в мониторе порта будет напечатано сообщение «Motion stopped...» («Движение прекратилось...»), светодиод будет выключен, а в переменную «startTimer» будет записано значение «false».

Итак, если вкратце, прерывания используются для обнаружения изменений состояния GPIO-контакта, чтобы вам не приходилось постоянно считывать текущее состояние GPIO-контакта. Благодаря прерываниям при обнаружении такого изменения запускается заданная заранее функция.

В этом примере мы также научились настраивать простой таймер, позволяющий проверить, прошло ли заданное количество секунд, не прибегая при этом к блокировке остального кода.

Прерывания и таймеры – это два очень важных концепта, которые пригодятся нам для работы над дальнейшими проектами.

Необходимое оборудование

Схема

Ambox content.png На этой схеме показана 30-контактная версия ESP32 DEVKIT V1 DOIT. Если вы используете другую модель, обязательно сверьтесь с ее распиновкой


Эта цепь собирается довольно просто. Нам понадобятся, во-первых, светодиод и резистор. Светодиод нужно подключить к контакту GPIO26. Во-вторых, нам будет нужен PIR-датчик движения, работающий на 3.3 вольтах, который нужно будет подключить к контакту GPIO27. При сборке следуйте схеме ниже.

Esp32 pir sensor led millis 1.png

Код

  1. const int timeSeconds = 10; // количество секунд, в течение которых светодиод будет оставаться включенным после обнаружения движения.
  2.  
  3. // задаем GPIO-контакты для светодиода и PIR-датчика движения:
  4. const int led = 26;
  5. const int motionSensor = 27;
  6.  
  7. // вспомогательные переменные для таймера:
  8. unsigned long now = millis();
  9. unsigned long lastTrigger = 0;
  10. boolean startTimer = false;
  11.  
  12. // проверяем, обнаружено ли движение,
  13. // и если обнаружено, переключаем контакт «led» на «HIGH»
  14. // и запускаем таймер:
  15. void IRAM_ATTR detectsMovement() {
  16.   Serial.println("MOTION DETECTED!!!");
  17.              //  "ОБНАРУЖЕНО ДВИЖЕНИЕ!!!"
  18.   digitalWrite(led, HIGH);
  19.   startTimer = true;
  20.   lastTrigger = millis();
  21. }
  22.  
  23. void setup() {
  24.   // запускаем последовательную коммуникацию (в целях отладки):
  25.   Serial.begin(115200);
  26.  
  27.   // выставляем контакт датчика движения в режим «INPUT_PULLUP»:
  28.   pinMode(motionSensor, INPUT_PULLUP);
  29.   // делаем контакт «motionSensor» контактом для прерываний,
  30.   // задаем функцию, которая будет запущена при прерывании,
  31.   // а также выставляем режим активации прерывания на «RISING»:
  32.   attachInterrupt(digitalPinToInterrupt(motionSensor), detectsMovement, RISING);
  33.  
  34.   // переключаем контакт светодиода («led») на «LOW»:
  35.   pinMode(led, OUTPUT);
  36.   digitalWrite(led, LOW);
  37. }
  38.  
  39. void loop() {
  40.   // текущее время:
  41.   now = millis();
  42.   // выключаем светодиод спустя определенное количество секунд,
  43.   // заданное в параметре «timeSeconds»:
  44.   if(startTimer && (now - lastTrigger > (timeSeconds*1000))) {
  45.     Serial.println("Motion stopped...");
  46.                //  "Движение прекратилось..."
  47.     digitalWrite(led, LOW);
  48.     startTimer = false;
  49.   }
  50. }

См.также

Внешние ссылки