Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Processing:Примеры/2D-анимация на основе уравнения

Материал из Онлайн справочника
Перейти к: навигация, поиск


Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Описание[1]

Этот скетч-пример выполняет интерактивную 2D-визуализацию уравнения sin(n*cos(r) + 5*theta), где n – это значение, отвечающее за горизонтальное расположение мыши.

Пример

  1. void setup() {
  2.   size(640, 360);
  3. }
  4.  
  5. void draw() {
  6.   loadPixels();
  7.   float n = (mouseX * 10.0) / width;
  8.   float w = 16.0;         // ширина в 2D-пространстве
  9.   float h = 16.0;         // высота в 2D-пространстве
  10.   float dx = w / width;    // с каждым пикселем увеличиваем «x»
  11.                            // на это значение
  12.   float dy = h / height;   // с каждым пикселем увеличиваем «y»
  13.                            // на это значение
  14.   float x = -w/2;          // начинаем с «x» на «-1 * width / 2»
  15.   for (int i = 0; i < width; i++) {
  16.     float y = -h/2;        // начинаем с «y» на «-1 * height / 2»
  17.     for (int j = 0; j < height; j++) {
  18.       float r = sqrt((x*x) + (y*y));    // конвертируем декартовы
  19.                                         // координаты в полярные  
  20.       float theta = atan2(y,x);         // конвертируем декартовы
  21.                                         // координаты в полярные  
  22.       // рассчитываем функцию для двумерных полярных координат:
  23.       float val = sin(n*cos(r) + 5 * theta);  // в результате должно
  24.                                               // получиться значение
  25.                                               // от «-1» до «1»
  26.       //float val = cos(r);       // еще одна простая функция
  27.       //float val = sin(theta);   // еще одна простая функция
  28.       // подгоняем диапазон значений «val»
  29.       // к диапазону монохромных значений (0-255):
  30.       pixels[i+j*width] = color((val + 1.0) * 255.0/2.0);
  31.       y += dy;                // увеличиваем «y»
  32.     }
  33.     x += dx;                  // увеличиваем «x»
  34.   }
  35.   updatePixels();
  36. }

См.также

Внешние ссылки

  1. processing.org - Graphing 2D Equations by Daniel Shiffman