Arduino:Примеры/Чтение и запись произвольных данных на SD карту с использованием часов реального времени
Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску
Содержание | Знакомство с Arduino | Продукты | Основы | Справочник языка Arduino | Примеры | Библиотеки | Хакинг | Изменения | Сравнение языков Arduino и Processing |
Проверка/Оформление/Редактирование: Мякишев Е.А.
Чтение и запись произвольных данных на SD карту с использованием часов реального времени
Данный пример демонстрирует чтение и запись произвольных данных на SD-карту с использованием платы Arduino Uno, любой платы расширения(шилд), работающей с SD-картами или MicroSD-картами(Cooking HAcks Micro SD shiled, Arduino Wireless SD shiled, Arduino Ethernet SD shiled, Arduino Wi-Fi SD shield, Adafruit data logging shield, SparkFun MicroSD shield) и любой платы расширения(шилд) RTC.
Необходимые компоненты
- Плата Arduino Uno, 1 шт.;
- Любая плата расширения(шилд), работающая с SD-картами или MicroSD-картами(Cooking HAcks Micro SD shiled, Arduino Wireless SD shiled, Arduino Ethernet SD shiled, Arduino Wi-Fi SD shield, Adafruit data logging shield, SparkFun MicroSD shield), 1 шт.;
- Любая плата расширения(шилд) RTC, 1 шт.;
- Макетная плата;
- Провода перемычки;
Монтажная схема
Соедините выбранную вами плату расширения работающую с SD-картами или MicroSD-картами, плату расширения часов реального времени и плату Arduino Uno.
Для примеры мы взяли Arduino Ethernet SD shiled + Arduino Uno + Плата расширения RTC.
Код
#include <SD.h> // Подключаем библиотеку SD для работы с платой расширения, оснащенной SD-слотом
#include <Wire.h> // Подключаем библиотеку Wire для работы с I2C устройствами, в данном случае с платой расширения RTC
#include "RTClib.h" // Подключаем библиотеку RTClib
/*
Используемые по умолчанию контакты для библиотеки SD.
Если вы используете Arduino Ethernet SD shiled или любую
другую плату расширения использующую эти контакты,
то ничего менять не надо
MOSI = 11 контакт
MISO = 12 контакт
SCLK = 13 контакт
*/
#define CS_PIN 10 // Контакт выбора
// Примечание: если вы используете Arduino Ethernet SD shiled
// необходимо изменить номер контакта на 4.
// Если ваша плата расширения использует другой контакт
// вам необходимо его изменить на правильный.
int refresh_rate = 5000; // Скорость опроса по умолчанию 5 сек.
RTC_DS1307 RTC; // Объявляем RTC объект
String year, month, day, hour, minute, second, time, date; // Объявляем строковые переменный для хранения даты и времени
void setup()
{
Serial.begin(9600); // Инициализация последовательного соединения на скорости 9600 бод
Serial.println(F("Initializing Card")); // Распечатываем в мониторе последовательного порта "Initializing Card"("Инициализация карты")
pinMode(CS_PIN, OUTPUT); // Определяем CS(контакт выбора) контакт как выход
Wire.begin(); // Инициализация шины I2C
RTC.begin(); // Инициализация библиотеки RTC
// Если микросхема RTC не запущена, то записываем данные часов компьютера при компиляции в RTC
if (! RTC.isrunning())
{
Serial.println(F("RTC is NOT running!")); // Распечатываем в мониторе последовательного порта "RTC is NOT running!"("Микросхема RTC не запущена!")
RTC.adjust(DateTime(__DATE__, __TIME__));
}
// Инициализация SD-карты
if (!SD.begin(CS_PIN))
{
Serial.println(F("Card Failure")); // Распечатываем в мониторе последовательного порта "Card Failure"("Сбой подключения к SD-карте")
return; // Останавливаем выполнение программы
}
Serial.println(F("Card Ready")); // Распечатываем в мониторе последовательного порта "Card Ready"("Карта готова к работе")
File commandFile = SD.open("speed.txt");
if (commandFile)
{
Serial.println(F("Reading Command File")); // Распечатываем в мониторе последовательного порта "Reading Command File"("Чтение конфигурационного файла")
while(commandFile.available())
{
refresh_rate = commandFile.parseInt();
}
Serial.print(F("Refresh Rate = ")); // Распечатываем в мониторе последовательного порта "Refresh Rate = " ("Частота обновления = ")
Serial.print(F(refresh_rate)); // Распечатываем в мониторе последовательного порта значение переменной refresh_rate
Serial.println(F("ms")); // Распечатываем в мониторе последовательного порта "ms"("мс.")
commandFile.close(); // Закрываем файл
}
else
{
Serial.println(F("Could not read command file.")); // Распечатываем в мониторе последовательного порта "Could not read command file."("Не удалось прочитать конфигурационный файл")
return; // Останавливаем выполнение программы
}
// Открываем файл и создаем заголовки
File dataFile = SD.open("log.csv", FILE_WRITE);
if (dataFile)
{
dataFile.println(F("\nNew Log Started!"));
dataFile.println(F("Date,Time,Phrase"));
dataFile.close(); // Внимание! Данные не будут записаны, пока вы не закроете соединение!
// Распечатываем в мониторе последовательного порта те же данные для отладки
Serial.println(F("\nNew Log Started!")); // Распечатываем в мониторе последовательного порта "\nNew Log Started!"("Новый лог начат")
Serial.println(F("Date,Time,Phrase")); // Распечатываем в мониторе последовательного порта "Date,Time,Phrase"
}
else
{
Serial.println(F("Couldn't open log file")); // Распечатываем в мониторе последовательного порта "Couldn't open log file"("Не удалось открыть файл журнала")
}
}
void loop()
{
// Получаем текущую дату и время и сохраняем в строковых переменных
DateTime datetime = RTC.now();
year = String(datetime.year(), DEC);
month = String(datetime.month(), DEC);
day = String(datetime.day(), DEC);
hour = String(datetime.hour(), DEC);
minute = String(datetime.minute(), DEC);
second = String(datetime.second(), DEC);
// Объединяем строки для получения полной даты и времени
date = year + "/" + month + "/" + day;
time = hour + ":" + minute + ":" + second;
String dataString = "Hello World!";
// Открываем файл и записываем в него данные
File dataFile = SD.open("log.csv", FILE_WRITE);
if (dataFile)
{
dataFile.print(date);
dataFile.print(F(","));
dataFile.print(time);
dataFile.print(F(","));
dataFile.println(dataString);
dataFile.close(); // Внимание! Данные не будут записаны, пока вы не закроете соединение!
// Распечатываем в мониторе последовательного порта те же данные для отладки
Serial.print(date);
Serial.print(F(","));
Serial.print(time);
Serial.print(F(","));
Serial.println(dataString);
}
else
{
Serial.println(F("Couldn't open log file")); // Распечатываем в мониторе последовательного порта "Couldn't open log file"("Не удалось открыть файл журнала")
}
delay(refresh_rate); // Задержка длительностью refresh_rate
}