Электроника:Полупроводники/Диоды и выпрямители/Модели диодов в SPICE

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Макаров В. (valemak)
Проверка/Оформление/Редактирование: Мякишев Е.А.


Модели диодов в SPICE[1]

Программа SPICE позволяет создавать модели диодов, для дальнейшего использования в моделировании цепей. Модель диода основывается на задании отдельных характеристик устройств, которые описанны в технической документации прибора, а также на характеристиках производственного процесса, которая не указывается в этой техдокументации. В нашем моделировании мы воспользуемся некоторой информацией, взятой из таблицы характеристик для модели 1N4004:

Рис. 1. Выдержка из технического паспорта для 1N4004.
Рис. 1. Выдержка из технического паспорта для 1N4004.

Табличные данные из технического описания на диод 1N4004

Параметр Значение Параметр Значение
Максимальный средний выпрямленный ток ID (А) 1 Прямое падение напряжения VF (В) 1
Пиковое повторяющееся обратное напряжение VRRM (В) 400 Прямой ток IF (А) 1
Пиковый прямой импульсный ток IFSM (А) 30 Максимальный обратный ток IR (мкА) 5
Общая емкость CT (пФ) 15 Максимальное обратное напряжение VR (В) 400

Объявление диода начинается с названия диодного элемента, которое должно начинаться с буквы «d» и кроме этой первой буквы должен быть хоть один дополнительный символ. Примеры названий диодных компонентов: d1, d2, dtest, da, db, d101. Затем указываются два номера узла, определяющих соединение анода и катода соответственно с другими компонентами. За номерами узлов следует название модели, относящееся к последующему оператору «.model».

Строка оператора для модели начинается с команды «.model», за которым следует название модели, используемая при объявлении диодов. Далее следует буква «d», указывающая, что моделируется именно диод. Остальная часть – список дополнительных параметров диода в виде ИмяПараметра=ЗначениеПараметра. В моделировании ниже в первом примере параметры не используются, а вот во втором примере некоторые определены. Ниже в табличном виде есть список параметров для диодов.

Общий вид:
d[Название] [Анод] [Катод] [НазваниеМодели]
.model ([НазваниеМодели] d [Параметр1=Значение1] [Параметр2=Значение2]...)

Пример 1:
d1 1 2 mod1
.model mod1 d

Пример 2:
D2 1 2 Da1N4004
.model Da1N4004 D (IS = 18,8n RS = 0 BV = 400 IBV = 5,00u CJO = 30 M = 0,333 N = 2)

Модели SPICE для диодов

Самый простой подход к модели SPICE такой же, как и к техническому описанию: посетить веб-сайт производителя. В таблице ниже перечислены параметры модели для некоторых выборочных диодов. Альтернативной стратегией является построение модели SPICE на основе параметров, перечисленных в таблице ниже. Третья стратегия, не рассматриваемая здесь – измерение реального устройства (с последующим расчётом, сравнением и настройкой параметров для SPICE в соответствии с измерениями).

SPICE параметры диодов

Обозначение Название Параметр Единицы измерения Значение по умолчанию
IS IS Ток насыщения (диодное уравнение) А 1E-14
RS RS Паразитное сопротивление (последовательное сопротивление) Ом 0
n N Коэффициент эмиссии, от 1 до 2 1
tD TT Время переноса заряда с 0
CD(0) CJO Ёмкость перехода при нулевом смещении Ф 0
φ0 VJ Контактная разность потенциалов перехода В 1
m M Коэффициент плавности перехода 0,5
0,33 для линейно леггированнного перехода
0,5 для лавинного перехода
Eg EG Ширина запрещённой зоны эВ 1,11
Si (кремний) эВ 1,11
Ge (германий) эВ 0,67
Шоттки эВ 0,69
pi XTI Температурный экспоненциальный коэффициент тока насыщения 3,0
pin переход 3,0
Шоттки 2,0
kf KF Коэффициент фликер-шума 0
af AF Показатель степени в формуле фликер-шума 1
FC FC Коэффициент ёмкости обедненной области при прямом включении 0,5
BV BV Обратное напряжение пробоя В
IBV IBV Обратный ток пробоя А 1E-3

Если параметры диода не указаны, как в модели из примера 1 выше, параметры принимают значения по умолчанию, перечисленные в таблице выше и ниже. Эти значения по умолчанию моделируют диоды интегральной схемы. Их, само собой, достаточно для поверхностной работы с дискретными устройствами. Для более ответственных проектов используйте модели SPICE, поставляемые производителем, компаниями-интеграторами SPICE и другими источниками.

SPICE параметры некоторых диодов: sk = Шоттки, Ge = германий, остальные = кремний

Элемент IS RS N TT CJO M VJ EG XTI BV IBV
По умолчанию 1E-14 0 1 0 0 0.5 1 1.11 3 1m
1N5711 sk 315n 2.8 2.03 1.44n 2.00p 0.333 0.69 2 70 10u
1N5712 sk 680p 12 1.003 50p 1.0p 0.5 0.6 0.69 2 20
1N34 Ge 200p 84m 2.19 144n 4.82p 0.333 0.75 0.67 60 15u
1N4148 35p 64m 1.24 5.0n 4.0p 0.285 0.6 75
1N3891 63n 9.6m 2 110n 114p 0.255 0.6 250
10A04 10A 844n 2.06m 2.06 4.32u 277p 0.333 400 10u
1N4004 1A 76.9n 42.2m 1.45 4.32u 39.8p 0.333 400 5u
1N4004 тех.описание 18.8n 2 30p 0.333 400 5u

Или же введите некоторые параметры из технической документации, поставляемой вместе с прибором.

Создание моделей диодов в SPICE на основе технической документации

Сначала модели диода в SPICE для параметра N выберите значение (вещественное число с целой частью 1 или 2). Это требуется для диодного уравнения. Джузеппе Массобрио в своей книге «Моделирование полупроводниковых устройств с помощью SPICE» («Semiconductor Device Modeling With SPICE», 1988) на странице 9 рекомендует: «… n, коэффициент эмиссии, обычно составляет около 2». В таблице выше мы это и видим, что силовые выпрямители 1N3891 (12 A) и 10A04 (10 A) используют значения близкие к двум. Первые четыре строки в таблице не имеют особого значения, это 2 диода Шоттки, германиевый и кремниевый диоды соответственно. Ток насыщения, IS, выводится из уравнения диода, значения (VD, ID) показаны на графике (рисунок 1 выше), N = 2 (это n в уравнении диода).

ID = IS (eVD/nVT – 1) VT = 26 мВ (при температуре 25°C) n = 2,0 VD = 0,925 В (при 1 А на графике) 1 А = IS (e(0,925 В)/(2)(26 мВ) – 1) IS = 18,8E-9

В последней строке таблицы можно увидеть числовые значения IS = 18,8n и N = 2. Они введены для сравнения с моделью производителя для 1N4004, которая значительно отличается. На данный момент RS по умолчанию равен 0. Этот фактор мы оценим позже. Важными статическими параметрами постоянного тока являются N, IS и RS. Мухаммад Рашид в своей книге «SPICE для силовой электроники и электроэнергетики» («SPICE for Power Electronics and Electric Power», 2012) предлагает, чтобы TT (τD), время прохождения, можно приблизительно рассчитать из накопленного заряда обратного восстановления QRR, параметра из техдокументации (в нашем списке его нет) и IF, прямого тока:

ID = IS (eVD/nVT - 1) τD = QRR/IF

В нашем моделировании мы примем TT = 0 по умолчанию ввиду отсутствия QRR. Хотя имело смысл взять ТТ = 4.32u, как у аналогичного выпрямителя типа 10A04. TT для 1N3891 не подходит, потому что это выпрямитель с быстрым восстановлением. CJO, ёмкость перехода при нулевом смещении оценивается из графика зависимости VR от CJ на рисунке 1 выше. Ёмкость при напряжении, ближайшем к нулю на графике, составляет 30 пФ при 1 В. При моделировании высокоскоростной переходной характеристики, как в импульсных источниках питания для стабилизатора, необходимо указать параметры TT и CJO.

Коэффициент плавности перехода M связан с профилем легирования перехода. В приведённой выше техдокументации его тоже не найдёте. Значение по умолчанию -0,5 соответствует резкому переходу. Мы же возьмём M = 0,333, что соответствует линейно-плавному переходу. Мощные выпрямители в таблице выше используют более низкие значения M, чем 0,5. Мы берём значения по умолчанию для VJ и EG. Гораздо больше диодов используют VJ = 0,6, чем показано в таблице выше. Однако выпрямитель 10A04 использует значение по умолчанию, которое мы используем для нашей модели 1N4004 (Da1N4001 в моделировании выше). Для кремниевых диодов и выпрямителей используйте значение по умолчанию EG = 1,11. В таблице выше приведены значения для диодов Шоттки и германиевых диодов. Возьмите XTI = 3, температурный коэффициент для IS по умолчанию для кремниевых устройств. См. таблицу выше для XTI для диодов Шоттки.

В сокращённом техническом описании на рисунке выше указано IR = 5 мкА и VR = 400 В, что соответствует IBV = 5u и BV = 400 соответственно. Параметры 1n4004 для SPICE, полученные из таблицы данных, перечислены в последней строке таблицы выше для сравнения с моделью производителя, указанной над ней. BV необходим только в том случае, если в симуляции превышено напряжение обратного пробоя диода, как со стабилитроном. IBV, ток обратного пробоя, часто опускается, но может быть введён, если он указывается в связке с BV.

Сравнение моделей диодов, взятых из разных источников

На рисунке ниже показана схема для сравнения модели производителя, модели, параметры которой взяты из таблицы характеристик и модели по умолчанию с использованием параметров по умолчанию. Три фиктивных источника питания по 0 В нужны, чтобы измерить силу тока на диодах (особенности моделирования в SPICE). Источник питания 1 В изменяется от 0 до 1,4 В с шагом 0,2 мВ (см. оператор .DC в списке соединений SPICE ниже). DI1N4004 – это модель диода от производителя, Da1N4004 – производная от него модель, некоторые параметры которой зададим мы.

Рис. 2. Схема для программы SPICE, в которой сравним модель диода от производителя (D1), модели, параметры которой зададим исходя из таблиц выше (D2) и модели диода с характеристиками по умолчанию (D3).
Рис. 2. Схема для программы SPICE, в которой сравним модель диода от производителя (D1), модели, параметры которой зададим исходя из таблиц выше (D2) и модели диода с характеристиками по умолчанию (D3).

Параметры списка соединений SPICE: (D1) – модель диода DI1N4004 от производителя, (D2) – наша модель диода Da1N40004, с некоторыми параметрами, взятыми из таблиц выше, (D3) – модель диода по умолчанию.

*SPICE circuit <03468.eps> from XCircuit v3.20
D1 1 5 DI1N4004
V1 5 0 0
D2 1 3 Da1N4004
V2 3 0 0
D3 1 4 Default
V3 4 0 0
V4 1 0 1
.DC V4 0 1400mV 0.2m
.model Da1N4004 D (IS=18.8n RS=0 BV=400 IBV=5.00u CJO=30
+M=0.333 N=2.0 TT=0)
.MODEL DI1N4004 D (IS=76.9n RS=42.0m BV=400
IBV=5.00u CJO=39.8p
+M=0.333 N=1.45 TT=4.32u)
.MODEL Default D
.end

Итоги сравнения приведены ниже – на графике (рисунок 3) и в виде таблицы, в которую занесены выходные данные. VD – это зависимость напряжения диода от тока диода для модели производителя, нашей расчётной модели диода, созданной на основе табличных характеристик и модели диода по умолчанию. В последнем столбце «График 1N4004» в итоговой таблице отображена зависимость напряжения от тока на рисунке выше, которую мы пытаемся сопоставить. Сравнение токов для трёх моделей с последним столбцом показывает, что модель по умолчанию хороша для низких токов, модель от производителя хороша для высоких токов, а наша расчётная модель на основе табличных характеристик лучше всего подходит для токов до 1 А. Мы подобрали почти идеальные характеристики для 1 А, поскольку расчёт IS как раз и основан на напряжении на диоде при токе в 1 А. Наша модель сильно завышает значения, если ток выше 1 А.

Рис. 3. Первое испытание модели от производителя, расчётной модели на основе табличных характеристик и модели по умолчанию.
Рис. 3. Первое испытание модели от производителя, расчётной модели на основе табличных характеристик и модели по умолчанию.

Сравнение модели от производителя, расчётной модели на основе табличных характеристик и модели по умолчанию с вольт-амперными характеристиками 1N4004 – перевод графика в табличные данные:

Индекс VD Модель производителя Модель по тех. описанию Модель по умолчанию 1N4004 график
3500 7.000000e-01 1.612924e+00 1.416211e-02 5.674683e-03 0.01
4001 8.002000e-01 3.346832e+00 9.825960e-02 2.731709e-01 0.13
4500 9.000000e-01 5.310740e+00 6.764928e-01 1.294824e+01 0.7
4625 9.250000e-01 5.823654e+00 1.096870e+00 3.404037e+01 1.0
5000 1.000000e-00 7.395953e+00 4.675526e+00 6.185078e+02 2.0
5500 1.100000e+00 9.548779e+00 3.231452e+01 2.954471e+04 3.3
6000 1.200000e+00 1.174489e+01 2.233392e+02 1.411283e+06 5.3
6500 1.300000e+00 1.397087e+01 1.543591e+03 6.741379e+07 8.0
7000 1.400000e+00 1.621861e+01 1.066840e+04 3.220203e+09 12

Решение состоит в том, чтобы увеличить RS с нулевого значения по умолчанию. Изменение RS от 0 до 8 м в нашей модели по табличным характеристикам приводит к тому, что кривая пересекает 10 А (не показано на графике) в том же напряжении, что и для модели от производителя. Увеличение RS до 28,6 м смещает кривую ещё дальше вправо, как показано на рисунке 4 ниже. Это приводит к более точному сопоставлению нашей модели на основе табличных характеристик с графиком таблицы данных (рисунок 3 выше). В таблице ниже показано, что ток 1,224470e + 01 A при напряжении 1,4 В соответствует графику при 12 A. Однако ток при снижении до 0,925 В с 1,096870e + 00 повысился до 7,318536e-01.

Рис. 4. Вторая попытка улучшить расчётную модель на основе табличных характеристик по сравнению с моделью от производителя и моделью по умолчанию.
Рис. 4. Вторая попытка улучшить расчётную модель на основе табличных характеристик по сравнению с моделью от производителя и моделью по умолчанию.

Изменение модели Da1N4004 с RS = 0 на RS = 28,6 м снижает ток при VD = 1,4 В до 12,2 А:

.model Da1N4004 D (IS=18.8n RS=28.6m BV=400 IBV=5.00u CJO=30
+M=0.333 N=2.0 TT=0)
Индекс VD Модель производителя Модель по тех. описанию Модель по умолчанию
3505 7.010000e-01 1.628276e+00 1.432463e-02 0.01
4000 8.000000e-01 3.343072e+00 9.297594e-02 0.13
4500 9.000000e-01 5.310740e+00 5.102139e-01 0.7
4625 9.250000e-01 5.823654e+00 7.318536e-01 1.0
5000 1.000000e-00 7.395953e+00 1.763520e+00 2.0
5500 1.100000e+00 9.548779e+00 3.848553e+00 3.3
6000 1.200000e+00 1.174489e+01 6.419621e+00 5.3
6500 1.300000e+00 1.397087e+01 9.254581e+00 8.0
7000 1.400000e+00 1.621861e+01 1.224470e+01 12

Задание для читателя: уменьшите N так, чтобы ток при VD = 0,925 В восстановился до 1 A. Это может увеличить ток (12,2 A) при VD = 1,4 В, что требует увеличения RS для уменьшения тока до 12 A.

Моделирование стабилитрона

Существует два подхода к моделированию стабилитрона: установить параметр BV равным напряжению стабилитрона в описании модели или смоделировать стабилитрон с помощью подсхемы, содержащей фиксатор уровней диода, настроенного на напряжение стабилитрона. Пример первого подхода, в котором устанавливается напряжение пробоя BV равным 15 для модели стабилитрона 1n4469 15 В (опционально IBV):

.model D1N4469 D (BV = 15 IBV = 17 м) 

Второй подход моделирует стабилитрон с помощью подсхемы. Фиксаторы D1 и VZ на рисунке ниже моделируют напряжение обратного пробоя 15 В для стабилитрона 1N4477A. Диод DR отвечает за прямую проводимость стабилитрона в подсхеме.

Рис. 5. В подсхеме стабилитрона используется фиксатор (D1 и VZ) для моделирования стабилитрона.
Рис. 5. В подсхеме стабилитрона используется фиксатор (D1 и VZ) для моделирования стабилитрона.
.SUBCKT DI-1N4744A 1 2
* Terminals A K
D1 1 2 DF
DZ 3 1 DR
VZ 2 3 13.7
.MODEL DF D ( IS=27.5p RS=0.620 N=1.10
+ CJO=78.3p VJ=1.00
M=0.330 TT=50.1n )
.MODEL DR D ( IS=5.49f RS=0.804 N=1.77 )
.END

Моделирование туннельного диода

Туннельный диод может быть смоделирован парой полевых транзисторов (JFET) в подсхеме SPICE.

Моделирование диода Ганна

Диод Ганна также может быть смоделирован парой полевых транзисторов JFET.

Итог

  • Диоды в SPICE объявляются в качестве диодного компонента со ссылкой на оператор .model. Оператор .model содержит параметры, описывающие диод. Если параметры не указаны, модель принимает значения по умолчанию.
  • Статические параметры постоянного тока включают N, IS и RS. Параметры обратного пробоя: BV, IBV.
  • Для точной динамической синхронизации требуются параметры TT и CJO.
  • Настоятельно рекомендуется использовать модели, предоставленные производителями.

См.также

Внешние ссылки