Arduino:Примеры/RemoteAtCommand

Материал из Онлайн справочника
Версия от 23:56, 13 декабря 2016; Myagkij (обсуждение | вклад) (Замена текста — «<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">» на «<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS" enclose="div">»)
(разн.) ← Предыдущая версия | Текущая версия (разн.) | Следующая версия → (разн.)
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Отправка AT-команд на удаленный XBee-модуль[1]

Этот пример показывает, как при помощи библиотеки XBee управлять удаленным XBee-модулем. Скетч отправляет ему две AT-команды, настраивая на сбор данных с I/O линии.

Код

/**
 * Автор – Эндрю Рэпп (Andrew Rapp). 2009 год, все права защищены.
 *
 * Этот файл – часть библиотеки XBee-Arduino.
 *
 * Библиотека XBee для Arduino – это бесплатное ПО: его можно 
 * распространять и/или модифицировать согласно условиям Универсальной 
 * общественной лицензии GNU, изданной Фондом свободного ПО – будь то 
 * 3-тья или более поздняя версия этой лицензии (на ваш выбор).
 *
 * Библиотека XBee-Arduino распространяется бесплатно в надежде на то, 
 * что окажется полезной, но БЕЗО ВСЯКОЙ ГАРАНТИИ; включая даже 
 * обязательную гарантию на КОММЕРЧЕСКОЕ КАЧЕСТВО и ПРИГОДНОСТЬ 
 * КОНКРЕТНОЙ ЦЕЛИ. Более подробно читайте в Универсальной 
 * общественной лицензии GNU.
 *
 * Вы должны получить копию Универсальной общественной лицензии GNU 
 * вместе с библиотекой XBee-Arduino. Если не получили, ее можно найти 
 * на http://www.gnu.org/licenses/.
 */

#include <XBee.h>
#include <SoftwareSerial.h>

/*
Этот пример – для XBee-модуля Series 1 (с прошивкой 10C8 или новее) 
или Series 2. XBee-модуль отправляет две AT-команды на удаленный 
XBee-модуль, чтобы настроить его на сбор данных с I/O линии. 

Чтобы видеть информацию об XBee-коммуникации, этот пример использует 
библиотеку SoftSerial. Я использую плату Modern Device USB BUB
(http://moderndevice.com/connect) и просматриваю выдачу при помощи 
монитора порта в IDE Arduino.
*/

// Задаем TX и RX контакты для SoftSerial.
// Подключаем 8-ой контакт Arduino к TX-контакту конвертера USB-Serial:
uint8_t ssRX = 8; 
// Подключаем 9-ый контакт Arduino к RX-контакту конвертера USB-Serial:
uint8_t ssTX = 9;
// Не забудьте подключить все устройства к общей «земле»: XBee, Arduino и конвертер USB-Serial
SoftwareSerial nss(ssRX, ssTX);

XBee xbee = XBee();

// Включаем сбор порций данных на I/O линии:
uint8_t irCmd[] = {'I','R'};
// Задаем частоту сбора на 65 секунд (0xffff/1000)
uint8_t irValue[] = { 0xff, 0xff };

// Делаем DIO0 (20-ый контакт) входным аналоговым контактом:
uint8_t d0Cmd[] = { 'D', '0' };
uint8_t d0Value[] = { 0x2 };

// Адрес (SH + SL) удаленного XBee-модуля:
XBeeAddress64 remoteAddress = XBeeAddress64(0x0013a200, 0x400a3e02);
// Создаем удаленный AT-запрос с командой IR:
RemoteAtCommandRequest remoteAtRequest = RemoteAtCommandRequest(remoteAddress, irCmd, irValue, sizeof(irValue));
  
// Создаем объект для ответа на удаленную AT-команду:
RemoteAtCommandResponse remoteAtResponse = RemoteAtCommandResponse();

void setup() { 
  Serial.begin(9600);
  xbee.begin(Serial);
  // Запускаем коммуникацию SoftSerial:
  nss.begin(9600);
  
 // После включения питания XBee-модулям требуется несколько секунд, 
 // чтобы запуститься и подключиться к сети. Все пакеты, отправленные 
 // XBee-модулю в течение этого времени, будут проигнорированы. 
 // XBee-модули типа Series 2 при запуске отправляют модему пакет 
 // с информацией о статусе. 

 // Лично у меня на возвращение статусного пакета уходит около четырех 
 // секунд. Кроме того, по моему опыту, ассоциация модулей типа 
 // Series 1 выполняется чуть дольше. Разумеется, если XBee-модуль был 
 // запущен раньше скетча, то никакой задержки не требуется, но если 
 // обе команды не выполняются, попробуйте увеличить задержку.

 delay(5000);
}

void loop() {
  sendRemoteAtCommand();
  
  // Теперь снова используем тот же объект для команды DIO0:
  remoteAtRequest.setCommand(d0Cmd);
  remoteAtRequest.setCommandValue(d0Value);
  remoteAtRequest.setCommandValueLength(sizeof(d0Value));

  sendRemoteAtCommand();
  
  // Очищаем задающее значение, чтобы этот объект можно было снова 
  // использовать для запроса:
  remoteAtRequest.clearCommandValue();
  
  // Готово!
  while (1) {};
}

void sendRemoteAtCommand() {
  nss.println("Sending command to the XBee");  //  "Отправка команды XBee-модулю"

  // Отправляем команду: 
  xbee.send(remoteAtRequest);

  // Ждем 5 секунд ответа о статусе:
  if (xbee.readPacket(5000)) {
    // Получили ответ! 

    // Проверка на получение ответа: 
    if (xbee.getResponse().getApiId() == REMOTE_AT_COMMAND_RESPONSE) {
      xbee.getResponse().getRemoteAtCommandResponse(remoteAtResponse);

      if (remoteAtResponse.isOk()) {
        nss.print("Command [");  //  "Команда ["
        nss.print(remoteAtResponse.getCommand()[0]);
        nss.print(remoteAtResponse.getCommand()[1]);
        nss.println("] was successful!");  //  "] была выполнена успешно!"

        if (remoteAtResponse.getValueLength() > 0) {
          nss.print("Command value length is ");    //  "Размер значения, полученного командой - " 
          nss.println(remoteAtResponse.getValueLength(), DEC);

          nss.print("Command value: ");  //  "Значение, полученное командой: " 
          
          for (int i = 0; i < remoteAtResponse.getValueLength(); i++) {
            nss.print(remoteAtResponse.getValue()[i], HEX);
            nss.print(" ");
          }

          nss.println("");
        }
      } else {
        nss.print("Command returned error code: ");  //  "Код ошибки, возвращенный командой: "
        nss.println(remoteAtResponse.getStatus(), HEX);
      }
    } else {
      nss.print("Expected Remote AT response but got ");  //  "Ожидался AT-ответ, но получили "
      nss.print(xbee.getResponse().getApiId(), HEX);
    }    
  } else if (xbee.getResponse().isError()) {
    nss.print("Error reading packet.  Error code: ");     //  "Ошибка при чтении пакета. Код ошибки: " 
    nss.println(xbee.getResponse().getErrorCode());
  } else {
    nss.print("No response from radio");  //  "XBee-модуль не отвечает" 
  }
}

См.также

Внешние ссылки