Arduino:Примеры/RobotDiscoBot

Материал из Онлайн справочника
Версия от 08:03, 14 декабря 2016; Myagkij (обсуждение | вклад) (Замена текста — «<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">» на «<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS" enclose="div">»)
(разн.) ← Предыдущая версия | Текущая версия (разн.) | Следующая версия → (разн.)
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Диско-бот[1]

Этот скетч демонстрирует, как при помощи робота проигрывать мелодии, основанные на звуковых файлах.

При помощи кнопок, находящихся на верхней (контрольной) плате, вы сможете выбирать между тремя мелодиями, созданными специально для Arduino Robot. Выбрав понравившуюся мелодию, поставьте робота на пол, после чего он с удовольствием вам станцует.

Необходимое оборудование

  • Arduino Robot;
  • Ваш лучший танцевальный костюм;

Инструкция

  1. Загрузите скетч, отключите USB и включите питание
  2. Поставьте робота на пол
  3. Показав экран загрузки, робот начнет танцевать под музыку и мигать на дисплее разными цветами
  4. Переключать музыку можно при помощи кнопок «Влево» и «Вправо»
  5. Если танцевальные движения робота вас не устраивают, найдите в скетче строчку
    char danceScript[]="S4L1R1S2F1B1S1\0"
    
    и измените ее. Вся эта абракадабра расшифровывается следующим образом:
  • «S» – стоп,
  • «L» – поворот влево,
  • «R» – поворот вправо,
  • «F» – движение вперед,
  • «B» – движение назад.

Номер возле каждой команды означает то, сколько она будет длиться. То есть

  • «1» – это 500 миллисекунд,
  • «2» – 1000 миллисекунд,
  • «3» – 1500 миллисекунд и т.д.

Пробуем

Выбираем мелодию

Код

/* Диско-бот

Этот скетч демонстрирует, как у Arduino Robot работает функция
проигрывания мелодий – у робота припасены для вас пара треков
зажигательной 8-битной музыки. Музыка будет проигрываться, когда
робот будет во включенном состоянии. Кроме того, он покажет вам пару
интересных танцевальных движений. 

Цепь:
* Arduino Robot

Создан 1 мая 2013 Х. Янгом (X. Yang),
модифицирован 12 мая 2013 Д. Куартиллье (D. Cuartielles).

Этот код не защищен авторским правом.
 */

#include <ArduinoRobot.h> // подключаем библиотеку робота
#include <Wire.h>
#include <SPI.h>

/* 
Танцевальные «движения»:
S: стоп
L: поворот влево
R: поворот вправо
F: движение вперед
B: движение назад

Цифра после каждой команды означает то, как долго будет длиться то или иное «движение». «1» – это полсекунды, «2» – секунда и т.д.

«\0» означает конец строки.
*/

char danceScript[] = "S4L1R1S2F1B1S1\0";

int currentScript = 0; // то, на каком шаге мы находимся

int currentSong = 0; // отслеживаем текущую песню
static const int SONGS_COUNT = 3; // количество песен

// массив, в котором будут храниться песни:
char musics[][11] = {
  "melody.sqm",
  "menu.sqm",
  "chase.sqm",
};

// Переменные для неблокирующей задержки:
long waitFrom;
long waitTime = 0;

void setup() {
  // Инициализируем робота, SD-карту, дисплей и динамик:
  Robot.begin();
  Robot.beginSpeaker();
  Robot.beginSD();
  Robot.beginTFT();

  // Рисуем на экране картинки «lg0.bmp» и «lg1.bmp»:
  Robot.displayLogos();

  // Печатаем на экране инструкции:
  Robot.text("1. Use left and\n right key to switch\n song", 5, 5);  //  "Для переключения\n песни используем\n кнопки «Влево» \n и «Вправо»"
  Robot.text("2. Put robot on the\n ground to dance", 5, 33);  //  "Чтобы робот начал\n танцевать, поставьте\n его на землю"

  // Ждем несколько секунд:
  delay(3000);

  setInterface(); // показываем текущую песню
  play(0);  // проигрываем первую песню в массиве

  resetWait();  // инициализируем неблокирующую задержку
}

void loop() {
  // Считываем состояния кнопок робота:
  int key = Robot.keyboardRead();

  // Кнопки «Вправо» и «Влево» переключают на следующую песню:
  switch (key) {
    case BUTTON_UP:
    case BUTTON_LEFT:
      play(-1);  // проигрываем предыдущую песню
      break;
    case BUTTON_DOWN:
    case BUTTON_RIGHT:
      play(1);  // проигрываем следующую песню
      break;
  }

  // Танцуем!
  runScript();
}

// «Танцевальная» функция:
void runScript() {
  if (!waiting()) { // если робот выполнил предыдущую последовательность действий
    // Берем следующие две команды: 
    parseCommand(danceScript[currentScript], danceScript[currentScript + 1]);
    currentScript += 2;
    if (danceScript[currentScript] == '\0') { // если добрались до конца массива
      currentScript = 0;  // начинаем еще раз с самого начала
    }
  }
}

// Используем этот таймер вместо стандартной задержки:
boolean waiting() {
  if (millis() - waitFrom >= waitTime) {
    return false;
  } else {
    return true;
  }
}

// Как долго будем ждать:
void wait(long t) {
  resetWait();
  waitTime = t;
}

// Сбрасываем таймер:
void resetWait() {
  waitFrom = millis();
}

// Считываем информацию о направлении и продолжительности «движений»:
void parseCommand(char dir, char duration) {
  // Трансформируем скрипт в действие:
  switch (dir) {
    case 'L':
      Robot.motorsWrite(-255, 255);
      break;
    case 'R':
      Robot.motorsWrite(255, -255);
      break;
    case 'F':
      Robot.motorsWrite(255, 255);
      break;
    case 'B':
      Robot.motorsWrite(-255, -255);
      break;
    case 'S':
      Robot.motorsStop();
      break;
  }
  // Если хотите поменять ритм танца, поменяйте цифру «500» на какую-нибудь еще:
  wait(500 * (duration - '0'));
}

// Отображаем на дисплее название песни:
void setInterface() {
  Robot.clearScreen();
  Robot.stroke(0, 0, 0);
  Robot.text(musics[0], 0, 0);
}

// Отображаем следующую песню:
void select(int seq, boolean onOff) {
  if (onOff) { // выбираем
    Robot.stroke(0, 0, 0);
    Robot.text(musics[seq], 0, 0);
  } else { // отменяем выбор
    Robot.stroke(255, 255, 255);
    Robot.text(musics[seq], 0, 0);
  }
}

// Проигрываем выбранную песню:
void play(int seq) {
  select(currentSong, false);
  if (currentSong <= 0 && seq == -1) {
    currentSong = SONGS_COUNT - 1; // переходим к последней песне
  } else if (currentSong >= SONGS_COUNT - 1 && seq == 1) { 
    currentSong = 0;  // переходим к первой песне
  } else {
    currentSong += seq;  // следующая песня
  }
  Robot.stopPlayFile();
  Robot.playFile(musics[currentSong]);
  select(currentSong, true);  // отображаем на экране название текущей песни
}

Изучаем дальше

Мелодии создаются при помощи трекера и хранятся на SD-карте. О том, как написать свой собственный трек, можно прочесть тут.

См.также

  1. begin()
  2. beginTFT()
  3. beginSD()
  4. beginSpeaker()
  5. playFile()
  6. motorsWrite()
  7. turn()

Внешние ссылки