Arduino:Примеры/wifi101ScanNetworks

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Сканирование WiFi-сетей (WiFi Shield 101)

Это скетч при помощи модуля Arduino WiFi Shield 101 или платы MKR1000 сканирует близлежащие 802.11b/g сети. Затем, проведя сканирование, через монитор порта показывает информацию о себе и найденных сетях.

На подключение к сети этот пример не запрограммирован.

Необходимое оборудование

• Модуль Arduino WiFi Shield 101
• Плата Arduino или Genuino Zero (или MKR1000)

Цепь

7-ой цифровой контакт используется в качестве контакта для «рукопожатия» между WiFi Shield 101 и платой, т.е. ни для каких других целей его использовать не следует.

Откройте монитор порта, чтобы видеть сети, найденные WiFi Shield 101. Впрочем, количество сетей, которые он может найти, будет не таким большим, как если бы их искал компьютер.

На картинке выше модуль WiFi Shield 101 установлен поверх платы Arduino/Genuino Zero.

Код

/*
Этот скетч печатает на Serial Monitor MAC-адрес WiFi Shield, 
а затем с его помощью сканирует доступные WiFi-сети. 
При этом сканирование происходит каждые 10 секунд, но самого
подключения, собственно, не происходит. 

Цепь:
* WiFi Shield, подключенный к Arduino

Создан 13 июля 2010 пользователем dlf (Metodo2 srl),
модифицирован 21 июня 2012 
Томом Иго (Tom Igoe) и Джеймсом Деком (Jaymes Dec).
*/

#include <SPI.h>
#include <WiFi101.h>


void setup() {
  // Инициализируем последовательную передачу данных и ждем открытия порта:
  Serial.begin(9600); 
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для Leonardo)
  }

  // Проверяем наличие WiFi Shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");  //  "WiFi Shield не подключен"
    // Дальше не продолжаем:
    while(true);
 }

  // показываем MAC-адрес:
  printMacAddress();

  // сканируем доступные сети:
  Serial.println("Scanning available networks...");   //  "Сканирование доступных сетей..."
  listNetworks();
}

void loop() {
  delay(10000);
  // сканируем доступные сети:
  Serial.println("Scanning available networks...");   //  "Сканирование доступных сетей..."
  listNetworks();
}

//  Пользовательская функция, с помощью которой мы будем выводить MAC-адрес на Serial Monitor:
void printMacAddress() {
  // MAC-адрес вашего WiFi Shield:
  byte mac[6];                     

  // Поэтапная печать MAC-адреса:
  WiFi.macAddress(mac);
  Serial.print("MAC: ");  //  "MAC-адрес: "
  Serial.print(mac[5],HEX);
  Serial.print(":");
  Serial.print(mac[4],HEX);
  Serial.print(":");
  Serial.print(mac[3],HEX);
  Serial.print(":");
  Serial.print(mac[2],HEX);
  Serial.print(":");
  Serial.print(mac[1],HEX);
  Serial.print(":");
  Serial.println(mac[0],HEX);
}

// Пользовательская функция, с помощью которой мы будем сканировать доступные сети:
void listNetworks() {
  // Сканируем сети:
  Serial.println("** Scan Networks **");  //  "** Сканирование сетей **"

  int numSsid = WiFi.scanNetworks();
  if (numSsid == -1)
  { 
    Serial.println("Couldn't get a wifi connection");   //  "Доступных сетей нет"

    while(true);
  } 

  // Показываем количество доступных сетей:
  Serial.print("number of available networks:");  //  "Число доступных сетей: "

  Serial.println(numSsid);

  // Показываем номер и название каждой обнаруженной сети:
  for (int thisNet = 0; thisNet<numSsid; thisNet++) {
    Serial.print(thisNet);
    Serial.print(") ");
    Serial.print(WiFi.SSID(thisNet));
    Serial.print("\tSignal: ");  //  "\tСигнал: "
    Serial.print(WiFi.RSSI(thisNet));
    Serial.print(" dBm");
    Serial.print("\tEncryption: ");  //  "\tШифрование: "
    printEncryptionType(WiFi.encryptionType(thisNet));
  }
}

//  Пользовательская функция для считывания и отображения типа шифрования:
void printEncryptionType(int thisType) {
  switch (thisType) {
  case ENC_TYPE_WEP:
    Serial.println("WEP");
    break;
  case ENC_TYPE_TKIP:
    Serial.println("WPA");
    break;
  case ENC_TYPE_CCMP:
    Serial.println("WPA2");
    break;
  case ENC_TYPE_NONE:
    Serial.println("None");  //  "Без шифрования"
    break;
  case ENC_TYPE_AUTO:
    Serial.println("Auto");  //  "Автоматически"
    break;
  } 
}

См.также

1. WiFi library – Your reference for the WiFi101 Library.
2. WiFi Shield – Product details for the WiFi 101 Shield.
3. MKR1000 – Product details for the MKR1000 board.
4. Connect No Encryption - Demonstrates how to connect to an open network.
5. Connect With WEP - Demonstrates how to connect to a network that is encrypted with WEP.
6. Connect With WPA - Demonstrates how to connect to a network that is encrypted with WPA2 Personal.
7. Simple Web Server WiFi – Turn on and off an LED accessing this simple Web Server.
8. UDP NTP Client - Query a Network Time Protocol (NTP) server using UDP.
9. WiFi Chat Server - Set up a simple chat server.
10. WiFi Web Client - Connect to a remote webserver.
11. WiFi Web Client Repeating - Repeatedly make HTTP calls to a server.
12. WiFi Web Server - Serve a webpage from the WiFi shield with Analog Input values.
13. WiFi Send Receive UDP String - Send and receive a UDP string.