Arduino:Примеры/wifi101WiFiWebClientRepeating

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Повторяющийся запрос с помощью WiFi Shield 101[1]

Этот пример демонстрирует, как при помощи WiFi Shield 101 или платы MKR1000 делать повторяющийся HTTP-запрос. В процессе будет создан клиент, который каждые 10 секунд будет подключаться к странице https://www.arduino.cc/latest.txt, а ее содержание будет отображаться в мониторе порта IDE Arduino.

По умолчанию скетч написан таким образом, чтобы работать через WPA-зашифрованную сеть. Впрочем, его можно переписать, чтобы он вместо WPA работал с WEP – для этого поменяйте соответствующим образом функцию WiFi.begin().

Необходимое оборудование

  • Модуль Arduino WiFi Shield 101
  • Плата Arduino или Genuino Zero (или MKR1000)

Цепь

7-ой цифровой контакт используется в качестве контакта для «рукопожатия» между WiFi Shield 101 и платой, т.е. ни для каких других целей его использовать не следует.

Также для этого примера понадобится доступ к 802.11b/g сети, подключенной к интернету. Кроме того, в скетче надо будет поменять сетевые настройки, чтобы они соответствовали сети, к которой вы собираетесь подключиться.

Для сетей, использующих шифрование через WPA и WPA Personal, понадобятся SSID и пароль. К сети, использующей шифрование через WPA Enterprise, Shield подключиться не сможет.

Пароли к сетям с WEP-шифрованием – это шестнадцатеричные строки, называемые «ключами». Причем WEP-сеть может иметь 4 разных ключа, каждому из которых будет присвоен свой собственный «индекс». Таким образом, для WEP-зашифрованных сетей вам понадобятся SSID, ключ и индекс ключа.

ArduinoWiFi101.png

На картинке выше модуль WiFi Shield 101 установлен поверх платы Arduino/Genuino Zero.

Код

/*
Веб-клиент, делающий повторяющиеся HTTP-запросы 

Этот скетч подключается к веб-серверу, а затем при помощи WiFi Shield
делает запросы. 

Цепь:
* WiFi Shield, подключенный к SPI-контактам и 7-ому контакту Arduino

Создан 23 апреля 2012,
модифицирован 31 мая 2012 Томом Иго (Tom Igoe),
еще раз модифицирован 13 января 2014 Федерико Ванзати (Federico Vanzati).

http://www.arduino.cc/en/Tutorial/WifiWebClientRepeating

Этот код не защищен авторским правом.
*/

#include <SPI.h>
#include <WiFi101.h>

char ssid[] = "yourNetwork";      //  SSID (имя) вашей сети
char pass[] = "secretPassword";   //  пароль к вашей сети
int keyIndex = 0;                 //  индекс ключа для вашей сети (нужно только для WEP)

int status = WL_IDLE_STATUS;

// Инициализируем клиентскую библиотеку WiFi:
WiFiClient client;

// Адрес сервера::
char server[] = "www.arduino.cc";
//IPAddress server(64,131,82,241);

unsigned long lastConnectionTime = 0;            // время, когда вы в последний раз подключались к серверу (в миллисекундах)
const unsigned long postingInterval = 10L * 1000L; // задержка между обновлениями (в миллисекундах)

void setup() {
  // Инициализируем последовательную передачу данных и ждем открытия порта:
  Serial.begin(9600);
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для плат со штатным USB-портом)
  }

  // проверяем наличие Shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");  //  "WiFi Shield не подключен"
    // Дальше не продолжаем:
    while (true);
  }

  // пытаемся подключиться к WiFi-сети:
  while ( status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");  //  "Пытаемся подключиться к SSID: "
    Serial.println(ssid);
    // Подключаемся к WPA/WPA2 сети (если у вас открытая сеть или WEP-сеть, эту строчку нужно поменять):
    status = WiFi.begin(ssid, pass);

    // 10 секунд ждем подключения:
    delay(10000);
  }
  // мы подключились, значит, печатаем статус:
  printWifiStatus();
}

void loop() {
  // Если через сетевое подключение пришли какие-нибудь данные, 
  // выводим их на Serial Monitor. Это нужно только в отладочных целях:
  while (client.available()) {
    char c = client.read();
    Serial.write(c);
  }

  // Если с момента последнего подключения прошло 10 секунд,
  // подключаемся снова, а затем отправляем новый запрос:
  if (millis() - lastConnectionTime > postingInterval) {
    httpRequest();
  }

}

// Эта пользовательская функция осуществляет HTTP-подключение к серверу:
void httpRequest() {
  // Перед отправкой нового запроса отключаем все соединения.
  // Это освободит сокет на WiFi Shield:
  client.stop();

  // Если подключение прошло успешно:
  if (client.connect(server, 80)) {
    Serial.println("connecting...");  //  "Подключение..."
    // Отправляем HTTP-Запрос типа PUT:
    client.println("GET /latest.txt HTTP/1.1");
    client.println("Host: www.arduino.cc");
    client.println("User-Agent: ArduinoWiFi/1.1");
    client.println("Connection: close");
    client.println();

    // Отмечаем время, было установлено когда подключение:
    lastConnectionTime = millis();
  } else {
    // Если подключиться не удалось, сообщаем об это на Serial Monitor:
    Serial.println("connection failed");  //  "Подключиться не удалось"
  }
}

//  Пользовательская функция для отображения информации о сети и сетевом оборудовании: 
void printWifiStatus() {
  // Показываем на Serial Monitor название (SSID) сети, к которой подключились:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // Показываем IP-адрес WiFi Shield:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");  //  "IP-адрес: "
  Serial.println(ip);

  // Показываем мощность приемного сигнала:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");  //  "Мощность сигнала: (RSSI):"
  Serial.print(rssi);
  Serial.println(" dBm");
}

См.также

  1. WiFi library – Your reference for the WiFi101 Library.
  2. WiFi Shield – Product details for the WiFi 101 Shield.
  3. MKR1000 – Product details for the MKR1000 board.
  4. Connect No Encryption - Demonstrates how to connect to an open network.
  5. Connect With WEP - Demonstrates how to connect to a network that is encrypted with WEP.
  6. Connect With WPA - Demonstrates how to connect to a network that is encrypted with WPA2 Personal.
  7. Scan Networks - Displays all WiFi networks in range.
  8. Simple Web Server WiFi – Turn on and off an LED accessing this simple Web Server.
  9. UDP NTP Client - Query a Network Time Protocol (NTP) server using UDP.
  10. WiFi Chat Server - Set up a simple chat server.
  11. WiFi Web Client - Connect to a remote webserver.
  12. WiFi Web Server - Serve a webpage from the WiFi shield with Analog Input values.
  13. WiFi Send Receive UDP String - Send and receive a UDP string.

Внешние ссылки