Просмотр кода страницы ESP8266:Прошивки/Arduino/Библиотеки/Библиотека ESP8266WiFi/Класс UDP/UDP-коммуникация между ESP8266 и внешней программой

{{ESP8266 панель перехода}}
{{Перевод от Сubewriter}}
{{Myagkij-редактор}}



=UDP-коммуникация между ESP8266 и внешней программой<ref>[http://arduino-esp8266.readthedocs.io/en/latest/esp8266wifi/udp-examples.html arduino-esp8266.readthedocs.io - UDP]</ref>=

Цель этого скетча – продемонстрировать, как настроить [[UDP]]-коммуникацию между [[ESP8266]] и внешним клиентом. Внутри блока loop() скетч (выполняющий роль [[сервер]]а) будет проверять, пришел ли [[UDP-пакет]]. Если пришел, и если это корректный пакет, [[скетч]] отправит клиенту подтверждающий пакет – на тот же порт, с которого пакет был прислан.

== Объявление библиотек, констант и переменных ==

Вначале скетча подключаем две библиотеки:

<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">
#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
</syntaxhighlight>

Первая библиотека ('''ESP8266WiFi.h''') нужна в любом случае, т.к. мы используем [[ESP8266]] и передачу данных по [[WiFi]]. Вторая ('''WiFiUdp.h''') будет использоваться для программирования [[UDP]]-функционала.

Подключив библиотеки, создаем экземпляр класса WiFiUDP. Затем указываем порт для прослушки входящих пакетов. Стандартные номера портов для [[TCP]] и [[UDP]] можно посмотреть по [https://ru.wikipedia.org/wiki/Список_портов_TCP_и_UDP этой ссылке]. Наконец, создаем буфер для входящих пакетов и задаем ответное сообщение.

<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">
WiFiUDP Udp;
unsigned int localUdpPort = 4210;
char incomingPacket[255];
char  replyPacekt[] = "Hi there! Got the message :-)";
                  //  "Привет! Сообщение получено :-)"
</syntaxhighlight>

== Подключение к WiFi ==

В начале блока setup() пишем стандартный код для подключения к точке доступа. Его можно найти, к примеру, в заглавной статье в [[ESP8266:Прошивки/Arduino/Библиотеки/Библиотека_ESP8266WiFi#.D0.91.D1.8B.D1.81.D1.82.D1.80.D1.8B.D0.B9_.D1.81.D1.82.D0.B0.D1.80.D1.82|разделе «Быстрый старт»]].

== Настройка UDP ==

Установив соединение, начинаем прослушивать входящие пакеты.

<syntaxhighlight lang="c">
Udp.begin(localUdpPort);
</syntaxhighlight>

В принципе, все. Теперь переходим к блоку loop(), в котором будет обрабатываться [[UDP]]-коммуникация.

== Получение UDP-пакета ==

Для ожидания входящего [[UDP-пакет]]а требуется вот такой код:

<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">
int packetSize = Udp.parsePacket();
if (packetSize)
{
  Serial.printf("Received %d bytes from %s, port %d\n", packetSize, Udp.remoteIP().toString().c_str(), Udp.remotePort());
            //  "Получено %d байт от %s, порт %d%"
  int len = Udp.read(incomingPacket, 255);
  if (len > 0)
  {
    incomingPacket[len] = 0;
  }
  Serial.printf("UDP packet contents: %s\n", incomingPacket);
            //  "Содержимое UDP-пакета: %s"
  (...)
}
</syntaxhighlight>

После получения пакета [[скетч]] напечатает в мониторе порта [[IP-адрес]], порт отправителя и размер присланного пакета. Если пакет не пуст, будет напечатано и его содержимое.

== Отправка подтверждения ==

После получения каждого пакета [[скетч]] будет отправлять обратно подтверждающий пакет.

<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">
Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
Udp.write(replyPacekt);
Udp.endPacket();
</syntaxhighlight>

Обратите внимание, что отправка ответа на [[IP-адрес]] и порт отправителя выполняется при помощи функций Udp.remoteIP() и Udp.remotePort().

== Скетч целиком ==

Полная версия [[скетч]]а показана ниже:

<syntaxhighlight lang="c" line="GESHI_NORMAL_LINE_NUMBERS|GESHI_FANCY_LINE_NUMBERS">
#include <ESP8266WiFi.h>
#include <WiFiUdp.h>

const char* ssid = "********";
const char* password = "********";

WiFiUDP Udp;
unsigned int localUdpPort = 4210;  // локальный порт для прослушки 
char incomingPacket[255];          // буфер для входящих пакетов
char  replyPacekt[] = "Hi there! Got the message :-)";  // ответ
                  //  "Привет! Сообщение получено :-)"

void setup()
{
  Serial.begin(115200);
  Serial.println();

  Serial.printf("Connecting to %s ", ssid);
            //  "Подключение к %s "
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected");
             //  " подключено "

  Udp.begin(localUdpPort);
  Serial.printf("Now listening at IP %s, UDP port %d\n", WiFi.localIP().toString().c_str(), localUdpPort);
            //  "Теперь прослушиваем IP-адрес %s, UDP-порт %d"
}

void loop()
{
  int packetSize = Udp.parsePacket();
  if (packetSize)
  {
    // получаем входящие UDP-пакеты:
    Serial.printf("Received %d bytes from %s, port %d\n", packetSize, Udp.remoteIP().toString().c_str(), Udp.remotePort());
              //  "Получено %d байт от %s, порт %d%"
    int len = Udp.read(incomingPacket, 255);
    if (len > 0)
    {
      incomingPacket[len] = 0;
    }
    Serial.printf("UDP packet contents: %s\n", incomingPacket);
              //  "Содержимое UDP-пакета: %s"

    // отправляем ответ на IP-адрес и порт, с которых пришел пакет: 
    Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
    Udp.write(replyPacekt);
    Udp.endPacket();
  }
}
</syntaxhighlight>

== Как проверить? ==

Загрузите [[скетч]] на модуль и откройте монитор порта. В нем должно появиться подтверждение, что [[ESP8266]] подключился к [[WiFi]] и начал прослушивать [[UDP-пакет]]ы:

<syntaxhighlight lang="html5">
Connecting to twc-net-3 ........ connected
Now listening at IP 192.168.1.104, UDP port 4210
</syntaxhighlight>

Теперь нам понадобится еще одна программа для отправки пакетов на [[IP-адрес]] и порт, показанные выше.

Здесь можно обойтись без дополнительного [[ESP8266]], вместо нее воспользовавшись специальной программой. К примеру, [https://packetsender.com/download Packet Sender], доступной в версиях для [[Windows]], [[Mac]] и [[Linux]]. Загрузите ее, установите и запустите.

Открыв Packet Sender, введите следующую информацию: 
* Название пакета (поле '''«Name»''')
* Текст, который будет внутри пакета (поле '''«ASCII»''')
* [[IP-адрес]], показанный в мониторе порта (поле '''«IP-address»''')
* Порт, показанный в мониторе порта (поле '''«Port»''')

Затем в выпадающем меню справа выберите пункт '''«UDP»'''.

В результате программа должна выглядеть следующим образом:

[[File:udp-packet-sender.jpg|center]]

Теперь нажмите на кнопку '''«Send»'''. Сразу после этого в мониторе порта должно появиться следующее:

<syntaxhighlight lang="html5">
Received 12 bytes from 192.168.1.106, port 55056
UDP packet contents: Hello World!
</syntaxhighlight>

Текст '''192.168.1.106, port 55056''' указывает на [[ПК]], с которого были присланы пакеты. У вас, скорее всего, будут другие значения.
После этого [[ESP8266]] отошлет обратно пакет с подтверждающим сообщением, которое вы должны увидеть в логах в нижней части [[Packet Sender]].

== Итого ==

Этот простой [[скетч]] демонстрирует, как отправлять и получать [[UDP-пакет]]ы между [[ESP8266]] и внешней программой. Это минимум для [[UDP]]-коммуникации, но, разобравшись в нем, вы поймете, как запрограммировать [[ESP8266]] на '''«общение»''' с любым другим [[UDP]]-устройством. Если у вас не получается установить соединение с новым устройством, для отладки можно воспользоваться программой [[Packet Sender]], о которой рассказывалось выше.

Список функций для работы с классом WiFiUDP смотрите по [ссылка этой ссылке]. 

=См.также=

=Внешние ссылки=

<references />

[[Категория:ESP8266]]