ESP32:Примеры/Машинка-робот с дистанционным WiFi-управлением
|
Черновик |
Содержание
Машинка-робот с дистанционным WiFi-управлением
В этом руководстве мы пошагово расскажем, как при помощи ESP32 создать машинку-робота, управляемую через WiFi.
В этом проекте затрагивается несколько тем, о которых уже рассказывалось в других руководствах по ESP32 на нашем сайте. Поэтому для лучшего понимания того, что будет написано ниже, советуем с ними ознакомиться (если еще не ознакомились). Вот они:
- Изменение яркости светодиода при помощи ШИМ
- Веб-сервер на базе ESP32: управление выходными контактами
- Веб-сервер на базе ESP32: удаленное управление сервоприводом
Обзор проекта
Перед тем, как начать, давайте рассмотрим главные функции и компоненты, при помощи которых этот проект будет воплощен в жизнь.
WiFi
Робот будет управляться через WiFi при помощи ESP32. Мы создадим веб-интерфейс, с помощью которого можно будет управлять роботом, и доступ к этому интерфейсу можно будет получить с любого устройства (ПК, ноутбука, планшета и т.д.), подключенного к вашей локальной сети.
Веб-интерфейс для управления роботом
Веб-интерфейс будет состоять из 6 компонентов: 5 кнопок вверху (вперед, назад, влево, вправо и стоп) и одного ползунка внизу (для изменения скорости движения, на нем можно выбрать скорость 0%, 25%, 50%, 75% и 100%).
Примечание: О том, как создавать кнопки, читайте в руководстве «Веб-сервер на базе ESP32: управление выходными контактами», а о создании ползунка – в руководстве «Веб-сервер на базе ESP32: удаленное управление сервоприводом».
Шасси
Мы будем использовать набор, показанный на картинке ниже. Он называется Smart Robot Chassis Kit. Его можно купить в большинстве онлайн-магазинов. Он стоит около 10 долларов и очень легко собирается. Подойдет и любой другой набор, но в нем также должны быть два DC-мотора.
Драйвер моторов L298N
Есть много разных способов для управления DC-моторами (электромоторами постоянного тока). Мы же воспользуемся драйвером моторов L298N, т.к. он позволяет значительно облегчить управление скоростью и направлением двух DC-моторов.
Питание
Моторам требуется много электроэнергии, поэтому нам также понадобится внешний источник питания. Это значит, что нам будут нужны два разных источника питания – один для DC-моторов, и один для ESP32. Плату ESP32 мы будем питать от пауэрбанка (вроде тех, что используются для зарядки смартфонов).
Моторы будут питаться от четырех 1.5-вольтовых АА-батареек. Подойдут, впрочем, и перезаряжаемые батарейки, и любой другой подходящий источник питания.
Справочная информация
Краткое введение в драйвер моторов L298N
Как уже говорилось выше, есть много разных способов для управления DC-моторами. Наш метод подходит для большинства моторов, используемых в любительских проектах и требующих 6-12 вольт. Мы воспользуемся драйвером моторов L298N, который может управлять нагрузкой до 3 ампер при 35 вольтах, что как раз подходит для нашего проекта. Он также позволяет одновременно управлять двумя DC-моторами, что идеально для создания робота на колесах.
Распиновка драйвера моторов L298N
Давайте взглянем на контакты драйвера моторов L298N и разберемся, как он работает.
Драйвер моторов L298N оснащен двумя клеммниками, которые находятся по разные стороны платы. Левый клеммник состоит из портов OUT1 и OUT2, а правый – из портов OUT3 и OUT4.
- OUT1 – плюсовой порт для DC-мотора А;
- OUT2 – минусовой порт для DC-мотора А;
- OUT3 – плюсовой порт для DC-мотора B;
- OUT4 – минусовой порт для DC-мотора B;
Внизу находится еще один клеммник, но уже на 3 порта: +12V, GND и +5V. Порт +12V используется для питания моторов. Порт +5V используется для питания чипа L298N. Но если поставить перемычку (на изображении выше она помечена оранжевым цветом), чип будет питаться от питания для DC-моторов. В этом случае подавать 5-вольтовое питание на порт +5V не нужно.
Примечание: Если напряжение питания превышает 12 вольт, перемычку нужно снять и подать 5-вольтовое питание на порт +5V.
Важно отметить, что хотя порт называется +12V, для нашего проекта (и с поставленной перемычкой) подойдет напряжение в диапазоне между 6 и 12 вольтами. Мы будем питать проект от четырех 1.5-вольтовых АА-батареек общим напряжением примерно 6 вольт.
Итого:
- +12V: Это порт, к которому нужно подключить питание;
- GND: Это порт для заземления;
- +5V: Если перемычка снята, на этот порт нужно подать 5-вольтовое питание. Если перемычка стоит, этот порт будет источником 5-вольтового питания;
- Перемычка: Если перемычка на месте, чип питается от питания моторов. Если перемычка снята, на порт +5V нужно подать 5-вольтовое питание. Если напряжение питания превышает 12 вольт, перемычку нужно снять.
В правом нижнем углу платы располагается 4 входных контакта, а по бокам от них – еще 2 контакта. 4 входных контакта предназначены для управления направлением вращения DC-моторов, а 2 контакта по бокам – для управления скоростью каждого мотора.
- IN1 – входной контакт 1 для мотора А;
- IN2 – входной контакт 2 для мотора А;
- IN3 – входной контакт 1 для мотора B;
- IN4 – входной контакт 2 для мотора B;
- ENA – контакт для управления скоростью мотора A;
- ENB – контакт для управления скоростью мотора B;
Рядом с контактами ENA и ENB находится по одному контакту +5V, и по умолчанию на них стоят перемычки. Чтобы управлять скоростью моторов, эти перемычки нужно снять.
Управление DC-моторами с помощью L298N
Теперь, когда мы познакомились с драйвером моторов L298N, давайте разберемся, как использовать его для управления DC-моторами.
Контакты ENA и ENB
Контакты ENA и ENB (для управления скоростью моторов) используются как переключатели между режимами «вкл» и «выкл», но также могут принимать более вариативные ШИМ-значения.
Например:
- Если подать на контакт ENA значение «HIGH», это разрешит управление мотором А на максимальной скорости;
- Если подать на контакт ENA значение «LOW», это выключит мотор А;
- Если подать ШИМ-сигнал на контакт ENA, это позволит управлять скоростью мотора. Скорость мотора пропорциональна коэффициенту заполнения ШИМ. Но помните, что если задать маленький коэффициент заполнения, моторы, возможно, просто не будут вращаться, а лишь постоянно жужжать.
| Сигнал, подаваемый на ENA или ENB | Как ведет себя мотор |
|---|---|
| HIGH | Мотор работает на максимальной скорости |
| LOW | Мотор не работает |
| ШИМ | Мотор работает (скорость пропорциональна коэффициенту заполнения) |
Входные контакты
Входные контакты предназначены для управления направлением вращения моторов. Контакты IN1 и IN2 управляют мотором А, а контакты IN3 и IN4 – мотором B.
Если подать на контакт IN1 значение LOW, а на IN2 – значение HIGH, мотор A будет крутиться вперед. Если инвертировать значения (на IN1 подать HIGH, а на IN2 – LOW), мотор A будет крутиться назад. Мотор B управляется аналогичным образом.
Таким образом, если вы хотите, чтобы робот ехал вперед, оба мотора должны крутиться вперед, а чтобы он ехал назад – оба мотора должны крутиться назад.
Чтобы робот повернулся, один из моторов должен крутиться быстрее другого. Например, чтобы робот повернул вправо, нам нужно включить левый мотор и выключить правый мотор.
| НАПРАВЛЕНИЕ | INPUT 1 | INPUT 2 | INPUT 3 | INPUT 4 |
|---|---|---|---|---|
| Вперед | 0 | 1 | 0 | 1 |
| Назад | 1 | 0 | 1 | 0 |
| Вправо | 0 | 1 | 0 | 0 |
| Влево | 0 | 0 | 0 | 1 |
| Стоп | 0 | 0 | 0 | 0 |
Как работает этот код
Мы подробно рассказывали о коде для создания веб-сервера на базе ESP32 в других руководствах. Поэтому здесь мы затронем лишь те фрагменты, что касаются нашего проекта.
Задаем настройки для подключения к WiFi
Начинаем с того, что задаем в двух переменных ниже SSID и пароль для локальной WiFi-сети, к которой нужно подключить ESP32.
1 const char* ssid = "REPLACE_WITH_YOUR_SSID";
2 const char* password = "REPLACE_WITH_YOUR_PASSWORD";
Создаем переменные для контактов драйвера моторов L298N
Далее создаем переменные для входных контактов (IN1, IN2, IN3, IN4), а также для контактов управления скоростью вращения моторов (ENA и ENB) драйвера моторов L298N.
1 // мотор 1:
2 int motor1Pin1 = 27;
3 int motor1Pin2 = 26;
4 int enable1Pin = 14;
5
6 // мотор 2:
7 int motor2Pin1 = 33;
8 int motor2Pin2 = 25;
9 int enable2Pin = 32;
Задаем свойства ШИМ
Если мы хотим управлять скоростью вращения моторов, нам нужно будет отправлять ШИМ-сигнал на контакты ENA и ENB. Следовательно, нам нужно создать переменные для свойств ШИМ-сигнала вроде частоты, канала ШИМ, разрешения и коэффициента заполнения.
1 // переменные для свойств широтно-импульсной модуляции (ШИМ):
2 const int freq = 30000;
3 const int pwmChannel = 0;
4 const int resolution = 8;
5 int dutyCycle = 0;
Примечание: Более подробно об использовании ШИМ вместе с ESP32 читайте в руководстве«Изменение яркости светодиода при помощи ШИМ».
setup()
В блоке setup() делаем выходными контакты для моторов.
1 // переключаем контакты моторов в режим «OUTPUT»:
2 pinMode(motor1Pin1, OUTPUT);
3 pinMode(motor1Pin2, OUTPUT);
4 pinMode(motor2Pin1, OUTPUT);
5 pinMode(motor2Pin2, OUTPUT);
Затем настраиваем ШИМ-канал при помощи заданных ранее свойств.
ledcSetup(pwmChannel, freq, resolution);
В следующих двух строчках подключаем этот ШИМ-канал к контактам ENA и ENB. Таким образом, на контакты ENA и ENB будет идти один и тот же ШИМ-сигнал.
1 ledcAttachPin(enable1Pin, pwmChannel);
2 ledcAttachPin(enable2Pin, pwmChannel);
Наконец, при помощи функции ledcWrite() генерируем ШИМ-сигнал с заранее заданным коэффициентом заполнения.
ledcWrite(pwmChannel, dutyCycle);
Код ниже подключает ESP32 к локальной WiFi-сети и печатает в монитор порта ее IP-адрес.
1 // подключаемся к WiFi-сети при помощи заданных выше SSID и пароля:
2 Serial.print("Connecting to "); // "Подключаемся к "
3 Serial.println(ssid);
4 WiFi.begin(ssid, password);
5 while (WiFi.status() != WL_CONNECTED) {
6 delay(500);
7 Serial.print(".");
8 }
9 // печатаем в мониторе порта
10 // локальный IP-адрес и запускаем веб-сервер:
11 Serial.println("");
12 Serial.println("WiFi connected."); // "Подключились к WiFi-сети."
13 Serial.println("IP address: "); // "IP-адрес: "
14 Serial.println(WiFi.localIP());
15 server.begin();
loop()
В блоке loop() ESP32 всегда будет прослушивать входящих клиентов и при получении запроса сохранять входящие данные.
1 WiFiClient client = server.available(); // Запускаем прослушку
2 // входящих клиентов.
3 if (client) { // Если подключился
4 // новый клиент,
5 Serial.println("New Client."); // печатаем в монитор порта
6 // сообщение об этом.
7 String currentLine = ""; // Создаем строку
8 // для хранения данных,
9 // пришедших от клиента.
10 while (client.connected()) { // Запускаем цикл while(),
11 // который будет работать,
12 // пока клиент подключен.
13 if (client.available()) { // Если у клиента
14 // есть байты, которые
15 // можно прочесть,
16 char c = client.read(); // считываем байт
17 Serial.write(c); // и печатаем его
18 // в мониторе порта.
19 header += c;
20 if (c == '\n') { // Если полученный байт –
21 // это символ новой строки.
22 // Если мы получили два символа новой строки подряд,
23 // то это значит, что текущая строка пуста.
24 // Это конец HTTP-запроса клиента, поэтому отправляем ответ:
25 if (currentLine.length() == 0) {
26 // HTTP-заголовки всегда начинаются с кода ответа
27 // (например, с «HTTP/1.1 200 OK»),
28 // а также с информации о типе контента,
29 // чтобы клиент знал, что получает.
30 // После этого пишем пустую строчку:
31 client.println("HTTP/1.1 200 OK");
32 client.println("Content-type:text/html");
33 client.println("Connection: close");
34 // "Соединение: отключено"
35 client.println();
Управляем роботом
В следующем фрагменте задано несколько операторов if() и else(), с помощью которых проверяется, какая команда отправляется роботу – «вперед», «назад», «влево», «вправо» или «стоп». Затем контактам моторов отправляются значения, соответствующие выбранной команде.
Например, чтобы повернуть робота влево, всем контактам нужно отправить значение «LOW» (кроме «motor2Pin2», которому нужно отправить «HIGH»).
1 // Этот код отвечает за управление контактами моторов
2 // согласно тому, какие нажаты кнопки на веб-странице:
3 if (header.indexOf("GET /forward") >= 0) {
4 Serial.println("Forward"); // "Вперед"
5 digitalWrite(motor1Pin1, LOW);
6 digitalWrite(motor1Pin2, HIGH);
7 digitalWrite(motor2Pin1, LOW);
8 digitalWrite(motor2Pin2, HIGH);
9 } else if (header.indexOf("GET /left") >= 0) {
10 Serial.println("Left"); // "Влево"
11 digitalWrite(motor1Pin1, LOW);
12 digitalWrite(motor1Pin2, LOW);
13 digitalWrite(motor2Pin1, LOW);
14 digitalWrite(motor2Pin2, HIGH);
15 } else if (header.indexOf("GET /stop") >= 0) {
16 Serial.println("Stop"); // "Стоп"
17 digitalWrite(motor1Pin1, LOW);
18 digitalWrite(motor1Pin2, LOW);
19 digitalWrite(motor2Pin1, LOW);
20 digitalWrite(motor2Pin2, LOW);
21 } else if (header.indexOf("GET /right") >= 0) {
22 Serial.println("Right"); // "Вправо"
23 digitalWrite(motor1Pin1, LOW);
24 digitalWrite(motor1Pin2, HIGH);
25 digitalWrite(motor2Pin1, LOW);
26 digitalWrite(motor2Pin2, LOW);
27 } else if (header.indexOf("GET /reverse") >= 0) {
28 Serial.println("Reverse"); // "Назад"
29 digitalWrite(motor1Pin1, HIGH);
30 digitalWrite(motor1Pin2, LOW);
31 digitalWrite(motor2Pin1, HIGH);
32 digitalWrite(motor2Pin2, LOW);
33 }
Как видите, каждая команда – предназначенная для того, чтобы переместить робота в каком-либо направлении или остановить его – представляет собой уникальную комбинацию сигналов «HIGH» и «LOW». Более подробно об этом рассказывалось выше, в разделе «Входные контакты».
Показываем веб-страницу
Фрагмент кода ниже показывает в вашем браузере веб-страницу с интерфейсом для управления роботом. Он состоит из 5 кнопок (вперед, назад, влево, вправо, стоп) и ползунка для управления скоростью.
1 // Показываем веб-страницу:
2 client.println("<!DOCTYPE HTML><html>");
3 client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
4 client.println("<link rel=\"icon\" href=\"data:,\">");
5 // При помощи CSS задаем стиль кнопок.
6 // Попробуйте поэкспериментировать
7 // с атрибутами «background-color» и «font-size»,
8 // чтобы стилизовать кнопки согласно своим предпочтениям:
9 client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
10 client.println(".button { -webkit-user-select: none; -moz-user-select: none; -ms-user-select: none; user-select: none; background-color: #4CAF50;");
11 client.println("border: none; color: white; padding: 12px 28px; text-decoration: none; font-size: 26px; margin: 1px; cursor: pointer;}");
12 client.println(".button2 {background-color: #555555;}</style>");
13 client.println("<script src=\"https://ajax.googleapis.com/ajax/libs/jquery/3.3.1/jquery.min.js\"></script></head>");
14
15 // веб-страница:
16 client.println("<p><button class=\"button\" onclick=\"moveForward()\">FORWARD</button></p>");
17 client.println("<div style=\"clear: both;\"><p><button class=\"button\" onclick=\"moveLeft()\">LEFT </button>");
18 client.println("<button class=\"button button2\" onclick=\"stopRobot()\">STOP</button>");
19 client.println("<button class=\"button\" onclick=\"moveRight()\">RIGHT</button></p></div>");
20 client.println("<p><button class=\"button\" onclick=\"moveReverse()\">REVERSE</button></p>");
21 client.println("<p>Motor Speed: <span id=\"motorSpeed\"></span></p>");
22 client.println("<input type=\"range\" min=\"0\" max=\"100\" step=\"25\" id=\"motorSlider\" onchange=\"motorSpeed(this.value)\" value=\"" + valueString + "\"/>");
23
24 client.println("<script>$.ajaxSetup({timeout:1000});");
25 client.println("function moveForward() { $.get(\"/forward\"); {Connection: close};}");
26 client.println("function moveLeft() { $.get(\"/left\"); {Connection: close};}");
27 client.println("function stopRobot() {$.get(\"/stop\"); {Connection: close};}");
28 client.println("function moveRight() { $.get(\"/right\"); {Connection: close};}");
29 client.println("function moveReverse() { $.get(\"/reverse\"); {Connection: close};}");
30 client.println("var slider = document.getElementById(\"motorSlider\");");
31 client.println("var motorP = document.getElementById(\"motorSpeed\"); motorP.innerHTML = slider.value;");
32 client.println("slider.oninput = function() { slider.value = this.value; motorP.innerHTML = this.value; }");
33 client.println("function motorSpeed(pos) { $.get(\"/?value=\" + pos + \"&\"); {Connection: close};}</script>");
34 client.println("</html>");
Примечание: О создании веб-страниц для веб-сервера подробно рассказывается в руководстве «Веб-сервер на базе ESP32: управление выходными контактами».
Управляем скоростью мотора
Во фрагменте кода ниже мы считываем значение ползунка и, исходя из него, меняем скорость мотора. Такой же метод используется в руководстве «Веб-сервер на базе ESP32: удаленное управление сервоприводом».
1 // Пример HTTP-запроса: «GET /?value=100& HTTP/1.1»;
2 // Он задает коэффициент заполнения ШИМ на 100% (255):
3 if(header.indexOf("GET /?value=")>=0) {
4 pos1 = header.indexOf('=');
5 pos2 = header.indexOf('&');
6 valueString = header.substring(pos1+1, pos2);
7 // Задаем скорость мотора:
8 if (valueString == "0") {
9 ledcWrite(pwmChannel, 0);
10 digitalWrite(motor1Pin1, LOW);
11 digitalWrite(motor1Pin2, LOW);
12 digitalWrite(motor2Pin1, LOW);
13 digitalWrite(motor2Pin2, LOW);
14 }
15 else {
16 dutyCycle = map(valueString.toInt(), 25, 100, 200, 255);
17 ledcWrite(pwmChannel, dutyCycle);
18 Serial.println(valueString);
19 }
20 }
В переменную «valueString» сохраняется текущее значение ползунка.
Если ползунок стоит на значении «0», моторы не будут работать. То есть мы задаем ШИМ-каналу коэффициент заполнения «0» и отправляем всем контактам моторов значения «LOW».
1 if (valueString == "0") {
2 ledcWrite(pwmChannel, 0);
3 digitalWrite(motor1Pin1, LOW);
4 digitalWrite(motor1Pin2, LOW);
5 digitalWrite(motor2Pin1, LOW);
6 digitalWrite(motor2Pin2, LOW);
7 }
Если на ползунке стоит ненулевое значение, то моторы начнут вращаться. Расчет коэффициента заполнения на основе значения ползунка осуществляется при помощи Arduino-функции map(). В ней начальным значением коэффициента заполнения задано «200», т.к. если задать меньше, робот просто не будет двигаться (моторы лишь будут издавать странное жужжание).
1 else {
2 dutyCycle = map(valueString.toInt(), 25, 100, 200, 255);
3 ledcWrite(pwmChannel, dutyCycle);
4 Serial.println(valueString);
5 }
После этого мы задаем коэффициент заполнения для ШИМ-канала, с его помощью и управляя скоростью моторов.
Тестируем веб-сервер
Теперь давайте протестируем веб-сервер. Убедитесь, что вставили в код SSID и пароль для своей WiFi-сети. Также проверьте, правильные ли в IDE Arduino выбраны COM-порт и плата. После этого жмите на кнопку «Загрузка». Когда загрузка завершится, откройте монитор порта на скорости 115200 бод.
Чтобы узнать IP-адрес ESP32, нажмите на ней на кнопку EN.
Отключите ESP32 от компьютера и запитайте от пауэрбанка.
Убедитесь, что все четыре АА-батарейки стоят на месте, а движковый переключатель стоит в положении «вкл».
Откройте браузер и впишите в адресную строку IP-адрес ESP32, чтобы получить доступ к веб-серверу. Этот веб-сервер можно открыть на любом устройстве (ПК, ноутбуке, смартфоне и т.д.), подключенном к вашей локальной сети, и с его помощью управлять роботом.
Теперь, если все настроено правильно, в браузере должен появиться веб-интерфейс с кнопками и ползунком, с помощью которого можно будет управлять машинкой-роботом.
Важное примечание: Если моторы крутятся в неправильном направлении, нужно просто поменять местами провода, подключенные к моторам. Например, провода, подключенные к контактам OUT1 и OUT2 или OUT3 и OUT4. Это должно решить проблему.
Поздравляем! Вы своими руками сделали робота с дистанционным WiFi-управлением! Он может перемещаться вперед, назад, влево и вправо. Вы также можете остановить его, нажав на кнопку «STOP». Более того, вы даже можете менять скорость движения робота при помощи ползунка.
Робот работает превосходно и мгновенно отвечает на команды.
Итого
Ну что, нравится робот? Советуем не останавливаться на достигнутом и попробовать оснастить машинку новыми фичами – например, так:
- Подключите к ней RGB-светодиод и запрограммируйте ESP32 так, чтобы его цвет менялся в зависимости от направления, в котором едет машинка;
- Подключите к ней ультразвуковой датчик, чтобы она останавливалась, увидев препятствие.
На наш взгляд, это хороший проект для того, чтобы практиковать на нем концепты, о которых рассказывалось в других руководствах по ESP32 на нашем сайте.
Необходимое оборудование
- Плата ESP32 – 1 шт.
- Набор для шасси (можно сделать своими руками + два DC-мотора) – 1 шт.
- Драйвер моторов L298N – 1 шт.
- Пауэрбанк (портативный зарядник) – 1 шт.
- AA-батарейки (1.5 вольт) – 4 шт.
- Керамические конденсаторы на 100 нФ – 2 шт.
- Движковый переключатель типа SPDT (один полюс, два направления) – 1 шт.
- Провода-перемычки ;
- Контактная или печатная макетная плата – 1 шт.
- Лента-липучка («репейник») – 1 шт.
Схема
|
|
На этой схеме изображена 36-контактная версия платы ESP32 DEVKIT DOIT V1, поэтому если у вас какая-то другая модель, обязательно сверьтесь с ее распиновкой. |
Начинаем с подключения ESP32 к драйверу моторов. Для размещения ESP32 и построения цепи можно воспользоваться либо небольшой контактной, либо печатной макетной платой. В таблице ниже показано, с помощью каких контактов ESP32 и драйвер моторов L298N необходимо подключить друг к другу.
| Драйвер моторов L298N | ESP32 |
|---|---|
| IN1 | GPIO27 |
| IN2 | GPIO26 |
| ENA | GPIO14 |
| IN3 | GPIO33 |
| IN4 | GPIO25 |
| ENB | GPIO32 |
После этого подключите оба мотора к клеммникам драйвера моторов L298N. В целях ослабления скачков напряжения мы рекомендуем припаять к плюсовому и минусовому контактам каждого мотора керамический конденсатор на 100 нФ (как показано на схеме выше).
Кроме того, можно припаять движковый переключатель к красному проводу, идущему от батареек. Благодаря ему вы сможете включать/отключать питание, идущее к моторам и драйверу моторов.
Наконец, запитайте моторы при помощи четырех АА-батареек, подключив их к портам питания драйвера моторов. Так как наш робот должен быть портативным, ESP32 будет питаться от пауэрбанка. Прикрепите его к шасси, например, при помощи ленты-липучки.
Код
1 /*********
2 Руи Сантос
3 Более подробно о проекте на: http://randomnerdtutorials.com
4 *********/
5
6 // загружаем библиотеку для WiFi:
7 #include <WiFi.h>
8
9 // вставляем ниже SSID и пароль для своей WiFi-сети:
10 const char* ssid = "REPLACE_WITH_YOUR_SSID";
11 const char* password = "REPLACE_WITH_YOUR_PASSWORD";
12
13 // создаем объект сервера и задаем ему порт «80»:
14 WiFiServer server(80);
15
16 // переменная для хранения HTTP-запроса:
17 String header;
18
19 // мотор 1:
20 int motor1Pin1 = 27;
21 int motor1Pin2 = 26;
22 int enable1Pin = 14;
23
24 // мотор 2:
25 int motor2Pin1 = 33;
26 int motor2Pin2 = 25;
27 int enable2Pin = 32;
28
29 // переменные для свойств широтно-импульсной модуляции (ШИМ):
30 const int freq = 30000;
31 const int pwmChannel = 0;
32 const int resolution = 8;
33 int dutyCycle = 0;
34
35 // переменные для расшифровки HTTP-запроса GET:
36 String valueString = String(5);
37 int pos1 = 0;
38 int pos2 = 0;
39
40 void setup() {
41 Serial.begin(115200);
42
43 // переключаем контакты моторов в режим «OUTPUT»:
44 pinMode(motor1Pin1, OUTPUT);
45 pinMode(motor1Pin2, OUTPUT);
46 pinMode(motor2Pin1, OUTPUT);
47 pinMode(motor2Pin2, OUTPUT);
48
49 // задаем настройки ШИМ-канала:
50 ledcSetup(pwmChannel, freq, resolution);
51
52 // подключаем ШИМ-канал 0 к контактам ENA и ENB,
53 // т.е. к GPIO-контактам для управления скоростью вращения моторов:
54 ledcAttachPin(enable1Pin, pwmChannel);
55 ledcAttachPin(enable2Pin, pwmChannel);
56
57 // подаем на контакты ENA и ENB
58 // ШИМ-сигнал с коэффициентом заполнения «0»:
59 ledcWrite(pwmChannel, dutyCycle);
60
61 // подключаемся к WiFi-сети при помощи заданных выше SSID и пароля:
62 Serial.print("Connecting to "); // "Подключаемся к "
63 Serial.println(ssid);
64 WiFi.begin(ssid, password);
65 while (WiFi.status() != WL_CONNECTED) {
66 delay(500);
67 Serial.print(".");
68 }
69 // печатаем в мониторе порта
70 // локальный IP-адрес и запускаем веб-сервер:
71 Serial.println("");
72 Serial.println("WiFi connected."); // "Подключились к WiFi-сети."
73 Serial.println("IP address: "); // "IP-адрес: "
74 Serial.println(WiFi.localIP());
75 server.begin();
76 }
77
78 void loop(){
79 WiFiClient client = server.available(); // Запускаем прослушку
80 // входящих клиентов.
81
82 if (client) { // Если подключился
83 // новый клиент,
84 Serial.println("New Client."); // печатаем в монитор порта
85 // сообщение об этом.
86 String currentLine = ""; // Создаем строку
87 // для хранения данных,
88 // пришедших от клиента.
89 while (client.connected()) { // Запускаем цикл while(),
90 // который будет работать,
91 // пока клиент подключен.
92 if (client.available()) { // Если у клиента
93 // есть байты, которые
94 // можно прочесть,
95 char c = client.read(); // считываем байт
96 Serial.write(c); // и печатаем его
97 // в мониторе порта.
98 header += c;
99 if (c == '\n') { // Если полученный байт –
100 // это символ новой строки.
101 // Если мы получили два символа новой строки подряд,
102 // то это значит, что текущая строка пуста.
103 // Это конец HTTP-запроса клиента, поэтому отправляем ответ:
104 if (currentLine.length() == 0) {
105 // HTTP-заголовки всегда начинаются с кода ответа
106 // (например, с «HTTP/1.1 200 OK»),
107 // а также с информации о типе контента,
108 // чтобы клиент знал, что получает.
109 // После этого пишем пустую строчку:
110 client.println("HTTP/1.1 200 OK");
111 client.println("Content-type:text/html");
112 client.println("Connection: close");
113 // "Соединение: отключено"
114 client.println();
115
116 // Этот код отвечает за управление контактами моторов
117 // согласно тому, какие нажаты кнопки на веб-странице:
118 if (header.indexOf("GET /forward") >= 0) {
119 Serial.println("Forward"); // "Вперед"
120 digitalWrite(motor1Pin1, LOW);
121 digitalWrite(motor1Pin2, HIGH);
122 digitalWrite(motor2Pin1, LOW);
123 digitalWrite(motor2Pin2, HIGH);
124 } else if (header.indexOf("GET /left") >= 0) {
125 Serial.println("Left"); // "Влево"
126 digitalWrite(motor1Pin1, LOW);
127 digitalWrite(motor1Pin2, LOW);
128 digitalWrite(motor2Pin1, LOW);
129 digitalWrite(motor2Pin2, HIGH);
130 } else if (header.indexOf("GET /stop") >= 0) {
131 Serial.println("Stop"); // "Стоп"
132 digitalWrite(motor1Pin1, LOW);
133 digitalWrite(motor1Pin2, LOW);
134 digitalWrite(motor2Pin1, LOW);
135 digitalWrite(motor2Pin2, LOW);
136 } else if (header.indexOf("GET /right") >= 0) {
137 Serial.println("Right"); // "Вправо"
138 digitalWrite(motor1Pin1, LOW);
139 digitalWrite(motor1Pin2, HIGH);
140 digitalWrite(motor2Pin1, LOW);
141 digitalWrite(motor2Pin2, LOW);
142 } else if (header.indexOf("GET /reverse") >= 0) {
143 Serial.println("Reverse"); // "Назад"
144 digitalWrite(motor1Pin1, HIGH);
145 digitalWrite(motor1Pin2, LOW);
146 digitalWrite(motor2Pin1, HIGH);
147 digitalWrite(motor2Pin2, LOW);
148 }
149 // Показываем веб-страницу:
150 client.println("<!DOCTYPE HTML><html>");
151 client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
152 client.println("<link rel=\"icon\" href=\"data:,\">");
153 // При помощи CSS задаем стиль кнопок.
154 // Попробуйте поэкспериментировать
155 // с атрибутами «background-color» и «font-size»,
156 // чтобы стилизовать кнопки согласно своим предпочтениям:
157 client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
158 client.println(".button { -webkit-user-select: none; -moz-user-select: none; -ms-user-select: none; user-select: none; background-color: #4CAF50;");
159 client.println("border: none; color: white; padding: 12px 28px; text-decoration: none; font-size: 26px; margin: 1px; cursor: pointer;}");
160 client.println(".button2 {background-color: #555555;}</style>");
161 client.println("<script src=\"https://ajax.googleapis.com/ajax/libs/jquery/3.3.1/jquery.min.js\"></script></head>");
162
163 // веб-страница:
164 client.println("<p><button class=\"button\" onclick=\"moveForward()\">FORWARD</button></p>");
165 client.println("<div style=\"clear: both;\"><p><button class=\"button\" onclick=\"moveLeft()\">LEFT </button>");
166 client.println("<button class=\"button button2\" onclick=\"stopRobot()\">STOP</button>");
167 client.println("<button class=\"button\" onclick=\"moveRight()\">RIGHT</button></p></div>");
168 client.println("<p><button class=\"button\" onclick=\"moveReverse()\">REVERSE</button></p>");
169 client.println("<p>Motor Speed: <span id=\"motorSpeed\"></span></p>");
170 client.println("<input type=\"range\" min=\"0\" max=\"100\" step=\"25\" id=\"motorSlider\" onchange=\"motorSpeed(this.value)\" value=\"" + valueString + "\"/>");
171
172 client.println("<script>$.ajaxSetup({timeout:1000});");
173 client.println("function moveForward() { $.get(\"/forward\"); {Connection: close};}");
174 client.println("function moveLeft() { $.get(\"/left\"); {Connection: close};}");
175 client.println("function stopRobot() {$.get(\"/stop\"); {Connection: close};}");
176 client.println("function moveRight() { $.get(\"/right\"); {Connection: close};}");
177 client.println("function moveReverse() { $.get(\"/reverse\"); {Connection: close};}");
178 client.println("var slider = document.getElementById(\"motorSlider\");");
179 client.println("var motorP = document.getElementById(\"motorSpeed\"); motorP.innerHTML = slider.value;");
180 client.println("slider.oninput = function() { slider.value = this.value; motorP.innerHTML = this.value; }");
181 client.println("function motorSpeed(pos) { $.get(\"/?value=\" + pos + \"&\"); {Connection: close};}</script>");
182
183 client.println("</html>");
184
185 // Пример HTTP-запроса: «GET /?value=100& HTTP/1.1»;
186 // Он задает коэффициент заполнения ШИМ на 100% (255):
187 if(header.indexOf("GET /?value=")>=0) {
188 pos1 = header.indexOf('=');
189 pos2 = header.indexOf('&');
190 valueString = header.substring(pos1+1, pos2);
191 // Задаем скорость мотора:
192 if (valueString == "0") {
193 ledcWrite(pwmChannel, 0);
194 digitalWrite(motor1Pin1, LOW);
195 digitalWrite(motor1Pin2, LOW);
196 digitalWrite(motor2Pin1, LOW);
197 digitalWrite(motor2Pin2, LOW);
198 }
199 else {
200 dutyCycle = map(valueString.toInt(), 25, 100, 200, 255);
201 ledcWrite(pwmChannel, dutyCycle);
202 Serial.println(valueString);
203 }
204 }
205 // HTTP-ответ заканчивается еще одной пустой строкой:
206 client.println();
207 // Выходим из цикла while():
208 break;
209 } else { // Если получили символ новой строки,
210 // то очищаем переменную «currentLine»:
211 currentLine = "";
212 }
213 } else if (c != '\r') { // Если получили что-либо,
214 // кроме символа возврата каретки...
215 currentLine += c; // ...добавляем эти данные
216 // в конец переменной «currentLine»
217 }
218 }
219 }
220 // Очищаем переменную «header»:
221 header = "";
222 // Отключаем соединение:
223 client.stop();
224 Serial.println("Client disconnected."); // "Клиент отключен."
225 Serial.println("");
226 }
227 }
См.также
Внешние ссылки
