ESP32:Примеры/Статический/фиксированный IP-адрес для ESP32

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 25257 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Pixel Art Mini Meow Animated.gif Черновик


Статический/фиксированный IP-адрес для ESP32

Если Вы сделали из своей ESP32 веб-сервер или WiFi-клиент, и она каждый раз при перезапуске платы получает новый IP-адрес, то здесь мы расскажем о том, как задать статический/фиксированный IP-адрес для своей ESP32.

Необходимое оборудование

  • Плата ESP32 – 1 шт.

Скетч «Фиксированный/статический IP-адрес для ESP32»

Чтобы показать, как сделать IP-адрес ESP32 статическим, мы возьмем в качестве примера код из руководства «Веб-сервер на базе ESP32: управление выходными контактами». В результате вы сможете сделать свой IP-адрес статическим для проекта и с веб-сервером, и с WiFi-клиентом.

Скопируйте код ниже в IDE Arduino, но пока не загружайте. Сначала вы должны будете внести в него некоторые изменения, чтобы он заработал конкретно в вашей ситуации.

Примечание: Если вы загрузите этот скетч на ESP32, она автоматически получит статический IP-адрес «192.168.1.184».

  1. /*********
  2.   Руи Сантос
  3.   Более подробно о проекте на https://randomnerdtutorials.com  
  4. *********/
  5.  
  6. // Загружаем библиотеку WiFi:
  7. #include <WiFi.h>
  8.  
  9. // Вставьте в строчках ниже SSID и пароль для своей WiFi-сети:
  10. const char* ssid     = "REPLACE_WITH_YOUR_SSID";
  11. const char* password = "REPLACE_WITH_YOUR_PASSWORD";
  12.  
  13. // Создаем объект для веб-сервера и задаем ему номер порта «80»:
  14. WiFiServer server(80);
  15.  
  16. // Переменная для хранения HTTP-запроса:
  17. String header;
  18.  
  19. // Вспомогательные переменные
  20. // для хранения текущего состояния выходных GPIO-контактов:
  21. String output26State = "off";
  22. String output27State = "off";
  23.  
  24. // Задаем номера для выходных GPIO-контактов:
  25. const int output26 = 26;
  26. const int output27 = 27;
  27.  
  28. // Задаем статический IP-адрес:
  29. IPAddress local_IP(192, 168, 1, 184);
  30. // Задаем IP-адрес сетевого шлюза:
  31. IPAddress gateway(192, 168, 1, 1);
  32.  
  33. IPAddress subnet(255, 255, 0, 0);
  34. IPAddress primaryDNS(8, 8, 8, 8);   // опционально
  35. IPAddress secondaryDNS(8, 8, 4, 4); // опционально
  36.  
  37. void setup() {
  38.   Serial.begin(115200);
  39.   // Переключаем выходные GPIO-контакты в режим «OUTPUT»:
  40.   pinMode(output26, OUTPUT);
  41.   pinMode(output27, OUTPUT);
  42.   // Задаем для выходных GPIO-контактов состояние «LOW»:
  43.   digitalWrite(output26, LOW);
  44.   digitalWrite(output27, LOW);
  45.  
  46.   // Настраиваем статический IP-адрес:
  47.   if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
  48.     Serial.println("STA Failed to configure");
  49.                //  "Не удалось задать статический IP-адрес"
  50.   }
  51.  
  52.   // Подключаемся к WiFi-сети с помощью заданных выше SSID и пароля:
  53.   Serial.print("Connecting to ");  //  "Подключаемся к "
  54.   Serial.println(ssid);
  55.   WiFi.begin(ssid, password);
  56.   while (WiFi.status() != WL_CONNECTED) {
  57.     delay(500);
  58.     Serial.print(".");
  59.   }
  60.   // Печатаем локальный IP-адрес и запускаем веб-сервер:
  61.   Serial.println("");
  62.   Serial.println("WiFi connected.");  //  "Подключились к WiFi."
  63.   Serial.println("IP address: ");  //  "IP-адрес: "
  64.   Serial.println(WiFi.localIP());
  65.   server.begin();
  66. }
  67.  
  68. void loop(){
  69.   WiFiClient client = server.available();  // Запускаем прослушку
  70.                                            // входящих клиентов.
  71.  
  72.   if (client) {                            // Если подключился
  73.                                            // новый клиент,
  74.     Serial.println("New Client.");         // пишем в монитор порта
  75.                                            // сообщение об этом.
  76.     String currentLine = "";               // Создаем строку
  77.                                            // для хранения данных,
  78.                                            // пришедших от клиента.
  79.     while (client.connected()) {           // Цикл while()
  80.                                            // будет работать,
  81.                                            // пока клиент подключен.
  82.       if (client.available()) {            // Если у клиента
  83.                                            // есть байты для чтения,
  84.         char c = client.read();            // считываем байт
  85.         Serial.write(c);                   // и пишем его
  86.                                            // в мониторе порта.
  87.         header += c;
  88.         if (c == '\n') {                   // если считанный байт –
  89.                                            // это символ новой строки,
  90.           // и если получили два символа новой строки подряд,
  91.           // то это значит, что текущая строка пуста.
  92.           // Это конец HTTP-запроса клиента, поэтому шлем ответ:
  93.           if (currentLine.length() == 0) {
  94.             // HTTP-заголовки всегда начинаются с кода ответа
  95.             // (например, с «HTTP/1.1 200 OK») и типа контента,
  96.             // чтобы клиент знал, что получает.
  97.             // Затем пишем пустую строку.
  98.             client.println("HTTP/1.1 200 OK");
  99.             client.println("Content-type:text/html");
  100.             client.println("Connection: close");
  101.                        //  "Соединение: отключено"
  102.             client.println();
  103.            
  104.             // Включаем и выключаем GPIO-контакты:
  105.             if (header.indexOf("GET /26/on") >= 0) {
  106.               Serial.println("GPIO 26 on");  //  "GPIO26 включен"
  107.               output26State = "on";
  108.               digitalWrite(output26, HIGH);
  109.             } else if (header.indexOf("GET /26/off") >= 0) {
  110.               Serial.println("GPIO 26 off");  //  "GPIO26 выключен"
  111.               output26State = "off";
  112.               digitalWrite(output26, LOW);
  113.             } else if (header.indexOf("GET /27/on") >= 0) {
  114.               Serial.println("GPIO 27 on");  //  "GPIO27 включен"
  115.               output27State = "on";
  116.               digitalWrite(output27, HIGH);
  117.             } else if (header.indexOf("GET /27/off") >= 0) {
  118.               Serial.println("GPIO 27 off");  //  "GPIO27 выключен"
  119.               output27State = "off";
  120.               digitalWrite(output27, LOW);
  121.             }
  122.            
  123.             // Показываем HTML-страницу:
  124.             client.println("<!DOCTYPE html><html>");
  125.             client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
  126.             client.println("<link rel=\"icon\" href=\"data:,\">");
  127.             // При помощи CSS задаем стили для кнопок «ON» и «OFF».
  128.             // Не бойтесь экспериментировать, поиграйтесь
  129.             // с атрибутами «background-color» и «font-size»,
  130.             // чтобы настроить дизайн кнопок по своему вкусу.
  131.             client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
  132.             client.println(".button { background-color: #4CAF50; border: none; color: white; padding: 16px 40px;");
  133.             client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
  134.             client.println(".button2 {background-color: #555555;}</style></head>");
  135.            
  136.             // Заголовок веб-страницы:
  137.             client.println("<body><h1>ESP32 Web Server</h1>");
  138.            
  139.             // Показываем текущее состояние
  140.             // и кнопку «ON»/«OFF» для контакта GPIO26:
  141.             client.println("<p>GPIO 26 - State " + output26State + "</p>");
  142.             // Если значением в «output26State» является «off»,
  143.             // то показываем кнопку «ON»:
  144.             if (output26State=="off") {
  145.               client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
  146.             } else {
  147.               client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
  148.             }
  149.                
  150.             // Показываем текущее состояние
  151.             // и кнопку «ON»/«OFF» для контакта GPIO27:
  152.             client.println("<p>GPIO 27 - State " + output27State + "</p>");
  153.             // Если значением в «output27State» является «off»,
  154.             // то показываем кнопку «ON»:
  155.             if (output27State=="off") {
  156.               client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
  157.             } else {
  158.               client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
  159.             }
  160.             client.println("</body></html>");
  161.            
  162.             // HTTP-ответ заканчивается еще одной пустой строкой:
  163.             client.println();
  164.             // выходим из цикла while():
  165.             break;
  166.           } else {  // Если получили символ новой строки,
  167.                     // то очищаем переменную «currentLine»
  168.             currentLine = "";
  169.           }
  170.         } else if (c != '\r') {  // если получили что-либо,
  171.                                  // кроме символа возврата каретки,
  172.           currentLine += c;      // добавляем это что-то
  173.                                  // в конец переменной «currentLine»
  174.         }
  175.       }
  176.     }
  177.     // Очищаем переменную «header»:
  178.     header = "";
  179.     // Отключаем соединение:
  180.     client.stop();
  181.     Serial.println("Client disconnected.");
  182.                //  "Клиент отключился."
  183.     Serial.println("");
  184.   }
  185. }

Что нужно сделать перед загрузкой кода

Задаем учетные данные для WiFi-сети

Вам нужно отредактировать две строчки ниже, вставив в них SSID и пароль для своей WiFi-сети:

  1. // Вставьте в строчках ниже SSID и пароль для своей WiFi-сети:
  2. const char* ssid     = "REPLACE_WITH_YOUR_SSID";
  3. const char* password = "REPLACE_WITH_YOUR_PASSWORD";

Задаем статический IP-адрес

Затем, все еще находясь вне блоков setup() и loop(), задаем переменные для хранения статического IP-адреса и IP-адреса сетевого шлюза. Также задаем маску подсети и – опционально – главный и вспомогательный DNS-серверы.

По умолчанию строчки кода ниже присвоят IP-адрес «192.168.1.184», который будет работать в сетевом шлюзе «192.168.1.1».

  1. // Задаем статический IP-адрес:
  2. IPAddress local_IP(192, 168, 1, 184);
  3. // Задаем IP-адрес сетевого шлюза:
  4. IPAddress gateway(192, 168, 1, 1);
  5.  
  6. IPAddress subnet(255, 255, 0, 0);
  7. IPAddress primaryDNS(8, 8, 8, 8);   // опционально
  8. IPAddress secondaryDNS(8, 8, 4, 4); // опционально

Если вы хотите задать для ESP32 собственный IP-адрес, то вам нужно отредактировать значения, выделенные во фрагменте выше красным цветом.

Важно: Задаваемый IP-адрес должен быть свободен и быть в пределах вашей локальной сети.

setup()

В блоке setup() нужно вызвать метод WiFi.config(), с помощью которого задаются сетевые настройки для ESP32.

  1. if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
  2.  Serial.println("STA Failed to configure");
  3.             //  "Не удалось задать статический IP-адрес"
  4. }

Примечание: Параметры «primaryDNS» и «secondaryDNS» – опциональные, и их можно удалить.

Тестирование

Загрузив код на плату, откройте монитор порта IDE Arduino на скорости 115200 бод и перезапустите ESP32. В результате в мониторе порта IDE Arduino должен появиться IP-адрес, ранее присвоенный вашей плате.

Esp32 static ip serial monitor 1.PNG

Как видите, в моем случае она напечатала IP-адрес «192.168.1.184».

В общем, этот код можно использовать, если вам нужно добавить в WiFi-скетч присвоение статического IP-адреса для ESP32.

Присвоение IP-адреса через MAC-адрес

Если вы попытались присвоить ESP32 статический IP-адрес при помощи скетча выше, и это не сработало, советуем присвоить IP-адрес напрямую в настройках роутера через MAC-адрес ESP32. Это можно сделать с помощью скетча ниже, который также можно найти по этой ссылке.

Впишите в него SSID и пароль для своей WiFi-сети, а затем загрузите на ESP32.

  1. /*********
  2.   Руи Сантос
  3.   Более подробно о проекте на: https://randomnerdtutorials.com  
  4. *********/
  5.  
  6. // Загружаем библиотеку для WiFi:
  7. #include <WiFi.h>
  8.  
  9. // Вставляем SSID и пароль для своей WiFi-сети:
  10. const char* ssid     = "REPLACE_WITH_YOUR_SSID";
  11. const char* password = "REPLACE_WITH_YOUR_PASSWORD";
  12.  
  13. // создаем объект для веб-сервера и задаем ему номер порта «80»:
  14. WiFiServer server(80);
  15.  
  16. void setup() {
  17.   Serial.begin(115200);
  18.  
  19.   // Подключаемся к WiFi-сети при помощи SSID и пароля:
  20.   Serial.print("Connecting to ");  //  "Подключаемся к "
  21.   Serial.println(ssid);
  22.   WiFi.begin(ssid, password);
  23.   while (WiFi.status() != WL_CONNECTED) {
  24.     delay(500);
  25.     Serial.print(".");
  26.   }
  27.  
  28.   // Печатаем локальный IP-адрес и запускаем веб-сервер:
  29.   Serial.println("");
  30.   Serial.println("WiFi connected.");  //  "Подключились к WiFi."
  31.   Serial.println("IP address: ");  //  "IP-адрес: "
  32.   Serial.println(WiFi.localIP());
  33.   server.begin();
  34.  
  35.   // Печатаем MAC-адрес ESP32:
  36.   Serial.println("MAC address: ");  //  "MAC-адрес: "
  37.   Serial.println(WiFi.macAddress());
  38. }
  39.  
  40. void loop() {
  41.   // Здесь поместите свой главный код,
  42.   // который будет постоянно повторяться:
  43. }

В результате ESP32, подключившись к WiFi-сети, при помощи функции Serial.println() в блоке setup() напечатает в мониторе порта свой MAC-адрес:

  1. // Печатаем MAC-адрес ESP32:
  2. Serial.println("MAC address: ");
  3. Serial.println(WiFi.macAddress());
Esp32 get ip get macserial monitor 1.PNG

В моем случае MAC-адрес ESP32 – это «B4:E6:2D:8F:C1:65». Скопируйте его, потому что он вам понадобится уже совсем скоро.

Настраиваем роутер

После того, как вы залогинитесь в админской странице роутера, там должна быть страница/меню для присвоения IP-адресов сетевым устройствам. У разных роутеров – разные меню и настройки. Поэтому нам трудно пошагово объяснить, что нужно сделать, чтобы задать нужные параметры – мы попросту не сможем предоставить инструкции для всех роутеров, т.к. им несть числа.

Поэтому рекомендуем погуглить что-то вроде «присвоение IP-адреса через MAC-адрес» вместе с названием своего роутера.

Но все эти инструкции, как правило, сводятся к тому, что где-то меню настроек роутера должно быть еще одно меню для присвоения IP-адреса по MAC-адресу (например, «B4:E6:2D:8F:C1:65»).

Esp32 static ip mac 1.PNG

См.также

Внешние ссылки