Arduino:Примеры/Блокировка ПК на основе показаний фоторезистора

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Проверка/Оформление/Редактирование: Мякишев Е.А.

Черновик

Блокировка ПК на основе показаний фоторезистора

Данный пример демонстрирует блокировку ПК на основе показаний фоторезистора с использованием Arduino Leonardo. Arduino Leonardo обладает возможностью эмулировать работу USB-устройств(например, клавиатуры или мыши), в результате мы можем эмулировать нажатия комбинация клавиш.

В этом примере при достижении показаний фоторезистора ниже пороговых мы будем блокировать компьютер комбинацией клавиш  Win  +  L .

Необходимые компоненты

• Arduino Leonardo;
• Резистор 150 Ом, 1 шт.;
• Резистор 10 кОм, 1 шт.;
• Светодиод, 1 шт.;
• Фоторезистор, 1 шт.;
• Кнопка, , 1 шт.;
• Макетная плата;
• Провода перемычки;

Монтажная схема

Соберите схему согласно монтажной схеме.

Код

Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Он специально устроен таким образом, что работает только при нажатии кнопки.

#include <Keyboard.h>                                  

#define LIGHT      0                                   // фоторезистор подключаем к 0-му аналоговому выводу
#define LED        3                                   // светодиод подключаем к 3-му выводу
#define BUTTON     2                                   // кнопку подключаем к 2-му выводу

#define THRESHOLD 50                                   // пороговое значение для блокировки компьютера
                                                       // ВНИМАНИЕ! Здесь вы должны подставить свое вычисленное значение
                                                       // для своего фоторезистора.

boolean lastButton = LOW;                              // последнее состояние кнопки
boolean currentButton = LOW;                           // текущее состояние кнопки
boolean lock = false;                                  // по умолчанию блокировка компьютера запрещена

void setup()
{
  pinMode (LED, OUTPUT);                               // устанавливаем вывод LED(т.е. 3-ий) как выход
  Keyboard.begin();                                    // запускаем эмуляцию клавиатуры
}

void loop()
{
  currentButton = debounce(lastButton);                // считываем состояние кнопки с использованием функции "антидребезга"
 
  if (lastButton == LOW && currentButton == HIGH)      // если кнопку нажали, то
    lock = !lock;                                      // инвертируем переменную lock для разрешения/запрета блокировки компьютера
  
  lastButton = currentButton;                          // сохраняем текущее состояние кнопки как последнее состояние
 
  if (lock)                                            // если блокировка компьютера разрешена
  {
    digitalWrite(LED, HIGH);                           // включаем светодиод
        
    if (millis() % 1000 == 0)                          // если время кратно 1000
    {
      int brightness = analogRead(LIGHT);              // считываем значение с фоторезистора
      if (brightness < THRESHOLD)                      // если значение ниже порогового
        {
          Keyboard.press(KEY_LEFT_GUI);                // нажимаем и удерживаем нажатой клавишу Win
          Keyboard.press('l');                         // нажимаем и удерживаем нажатой клавишу L
          delay(100);                                  // задержка 100 мс.
          Keyboard.releaseAll();                       // отпускаем все клавиши
         }
     }          
  }
  else                                                 // иначе, блокировка компьютера запрещена
  {
    digitalWrite(LED, LOW);                            // отключаем светодиод
  }
}

/*
* Функция для предотвращения дребезга контакта
* last    - последнее состояние кнопки
* current - текущее состояние кнопки
*/
boolean debounce(boolean last)
{
  boolean current = digitalRead(BUTTON);              // считываем состояние кнопки
  if (last != current)                                // если предыдущее и текущее состояние кнопки отлючаются
  {
    delay(5);                                         // ждем 5мс
    current = digitalRead(BUTTON);                    // считываем заново
  }
  return current;                                     // возвращаем текущее состояние кнопки
}