Электроника:Переменный ток/Трансформаторы/Взаимная индуктивность и основные операции

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Макаров В. (valemak)
Проверка/Оформление/Редактирование: Мякишев Е.А.


Взаимная индуктивность и основные операции[1]

Поведение катушек индуктивности, намотанных на проводящий сердечник

Представим, что катушка изолированного провода намотана вокруг замкнутого контура из ферромагнетика и эта катушка запитывается от источника переменного напряжения (часть (а) рисунка 1):

Рис. 1. Изолированная обмотка ферромагнитного контура имеет индуктивное сопротивление, ограничивающее переменный ток (а).
Рис. 1. Изолированная обмотка ферромагнитного контура имеет индуктивное сопротивление, ограничивающее переменный ток (а).

От индуктора мы ожидаем, что катушка с железным сердечником будет противодействовать приложенному напряжению за счёт своего индуктивного реактивного сопротивления, ограничивая ток, проходящий через катушку. Есть даже уравнения, которые предсказывают такое поведение:

XL = 2πfL и I = E/X (или I = E/Z)

Однако мы сейчас тщательнее рассмотрим, как в этом устройстве напряжение, ток и магнитный поток взаимодействуют между собой.

Правило Кирхгофа для напряжения гласит, что алгебраическая сумма всех напряжений в контуре должна равняться нулю. В этом примере мы могли бы применить этот фундаментальный закон для электричества при описании соответствующих напряжений источника и катушки индуктивности.

Здесь, как и в любой схеме с одним источником и одной нагрузкой, падение напряжения на нагрузке должно равняться напряжению, подаваемому источником, при условии, что нулевое напряжение падает вместе с сопротивлением любых соединительных проводов.

Другими словами, нагрузка (в роли которой в данном случае выступает катушка индуктивности) должна создавать противодействующее напряжение, равное по величине напряжению источника. В этом случаи оба напряжения уравновешивают друг друга и производят нулевую алгебраическую сумму напряжений в контуре.

Откуда вообще берётся это противодействующее напряжение? Если бы в качестве нагрузки выступал резистор (часть (б) рисунка 1), падение напряжения происходило из-за потери электрической энергии, «трения» переносчиков заряда, преодолевающих сопротивление.

В идеальном индукторе (без сопротивления в проволоке катушки) иной механизм противодействующего напряжения, которое суть реакция на изменение магнитного потока в железном сердечнике. При изменении переменного тока изменяется магнитный поток Φ. Изменение магнитного потока порождает встречную ЭДС.

Связь между напряжением, током и магнитным потоком

Майкл Фарадей вывел математическую связь между магнитным потоком (Φ) и наведённым напряжением:

Рис. 2. Соотношение между напряжением тока и магнитным потоком.
Рис. 2. Соотношение между напряжением тока и магнитным потоком.

Мгновенное напряжение (напряжение, падающее в любой момент времени) на проволочной катушке равно количеству витков (N) этой катушки на сердечнике, умноженному на мгновенную скорость изменения магнитного потока (dΦ/dt), сопряжённого с катушкой.

На графике (на рисунке ниже) это проявляется в виде набора синусоидальных волн (при условии, что источник генерирует синусоидальное напряжение), где волна потока на 90° отстаёт от волны напряжения:

Рис. 3. Магнитный поток, как и ток, отстаёт от приложенного напряжения на 90°.
Рис. 3. Магнитный поток, как и ток, отстаёт от приложенного напряжения на 90°.

Вот почему волна переменного тока, проходящего через катушку индуктивности, отстаёт от волны приложенного напряжения на 90°: потому что это требуется для создания изменяющегося магнитного потока, скорость изменения которого создаёт противоположное напряжение, синфазное с приложенным напряжением.

Этот ток также называют током намагничивания, поскольку он обеспечивает магнитодвижущую силу (МДС) для сердечника.

Следует отметить, что ток, проходящий через индуктор с железным сердечником, не будет идеально синусоидальным из-за нелинейного характера B/H-кривой намагничивания для железа.

Фактически, если катушка индуктивности в целях экономии изготовлена с минимальным содержанием железа, то плотность магнитного потока может достигать высоких уровней (приближаясь к насыщению), в результате чего волна тока намагничивания выглядит примерно так, как показано на этом рисунке (красная линия):

Рис. 4. Когда плотность магнитного потока (зелёная синусоида) приближается к насыщению, форма волны тока намагничивания искажается (красная кривая имеет вид, только похожий на синусоиду).
Рис. 4. Когда плотность магнитного потока (зелёная синусоида) приближается к насыщению, форма волны тока намагничивания искажается (красная кривая имеет вид, только похожий на синусоиду).

Когда ферромагнитный материал приближается к насыщению магнитного потока, для обеспечения равномерного увеличения потока магнитного поля (Φ) требуется непропорционально всё больше и больше магнитодвижущей силы (МДС).

Поскольку магнитодвижущая сила прямо пропорциональна количеству тока, проходящего через намагниченную катушку (МДС = N×I, где «N» - количество проволочных витков в катушке, а «I» – сила тока, проходящего через неё), то требуется значительное увеличение МДС для необходимого увеличения магнитного потока, что приводит к значительному увеличению силы тока в катушке.

Таким образом, сила тока в катушке резко увеличивается на пиках своей волны, чтобы в эти моменты поддерживать правильную синусоидальную форму волны для потока Ф. Поэтому на графике волна для тока имеет такой «колоколообразный» полупериод.

Ток возбуждения и его эффекты

Ситуация также осложняется потерями энергии в железном сердечнике. Эффекты гистерезиса и вихревых токов приводят к дальнейшему искажению и усложнению формы волны тока, делая её ещё менее синусоидальной и изменяя фазу, из-за чего волна тока отстаёт чуть менее чем на 90° от волны приложенного напряжения.

Этот ток в катушке, возникающий в результате суммы всех магнитных эффектов в сердечнике (намагниченность dΦ/dt плюс гистерезисные потери, потери на вихревые токи и т.д.), называется током возбуждения.

Искажения тока возбуждения, которые он вносит в работу катушки с железным сердечником, можно минимизировать, если индуктор спроектирован для работы при очень низких плотностях магнитного потока. Вообще говоря, для этого требуется сердечник с большой площадью поперечного сечения, что делает индуктивный элемент громоздким и дорогим.

Чтобы сейчас не усложнять, пока предположим, что сердечник в нашем примере далёк от насыщения и не имеет потерь, в результате чего ток возбуждения идеально синусоидален.

Как мы уже выяснили в главе 3 «Реактанс и импеданс - Индуктивность», если волна тока на 90° не совпадает по фазе с волной напряжения, это приводит к тому, что мощность попеременно поглощается и возвращается в цепь индуктором.

Если катушка индуктивности идеальна (т.е. отсутствуют сопротивления проволоки, нет потерь в магнитном сердечнике и т.д.), то она будет рассеивать нулевую мощность. Давайте теперь рассмотрим то же индуктивное устройство, только добавим в него вторую катушку (рисунок ниже), обмотанную вокруг того же железного сердечника. Будем считать, что первая катушка – первичная, а вторая – вторичная:

Рис.5. Ферромагнитный сердечник с первичной обмоткой (на которую подаётся переменный ток) и вторичной обмоткой. Вторичная обмотка здесь при этом представляет собой разомкнутую цепь.
Рис.5. Ферромагнитный сердечник с первичной обмоткой (на которую подаётся переменный ток) и вторичной обмоткой. Вторичная обмотка здесь при этом представляет собой разомкнутую цепь.

Взаимная индукция

Если эта вторичная катушка (в которой такое же количество витков, что и на первой) испытывает такое же изменение магнитного потока, что и первичная (по идее так и должно быть, при условии идеального удержания магнитного потока в общем сердечнике), то индуцированное напряжение по всей её длине будет равно по величине и фазе приложенному напряжению.

На следующем графике (рисунок ниже) волна индуцированного напряжения (фиолетовая линия) несколько меньше, чем волна напряжения источника (синяя линия). Это сделано только для того, чтобы отличить одну волну от другой:

Рис. 6. Хотя вторичная обмотка представляет собой разомкнутую цепь, на неё воздействует такой же магнитный поток Φ, что и на первичную. Это значит, что индуцированное вторичное напряжение eS имеет ту же величину и фазу, что и первичное напряжение eP.
Рис. 6. Хотя вторичная обмотка представляет собой разомкнутую цепь, на неё воздействует такой же магнитный поток Φ, что и на первичную. Это значит, что индуцированное вторичное напряжение eS имеет ту же величину и фазу, что и первичное напряжение eP.

Это и есть взаимная индукция: напряжение индуцируется в одной катушке в ответ на изменение тока в другой катушке. Как и обычная (само)индукция, она измеряется в единицах «генри», но при этом обозначается заглавной буквой «M», а не буквой «L»:

Рис. 7. Формула для индуцированного напряжения при взаимной индукции.
Рис. 7. Формула для индуцированного напряжения при взаимной индукции.

Во вторичной катушке не будет тока, поскольку она разомкнута. Однако, если мы подключим к ней нагрузочный резистор, переменный ток начнёт проходить через вторичную катушку синфазно с индуцированным напряжением (ибо напряжение на резисторе и ток через него всегда синфазны друг с другом).

Рис. 8. Резистивная нагрузка на вторичной обмотке имеет синфазные напряжение и ток.
Рис. 8. Резистивная нагрузка на вторичной обмотке имеет синфазные напряжение и ток.

Вроде как этот ток во вторичной катушке должен вызвать дополнительный магнитный поток в сердечнике. На самом деле нет. Если бы в сердечнике был индуцирован больший поток, это привело бы к увеличению напряжения в первичной катушке (вы же помните, что e = dΦ/dt).

Но такого не может быть, потому что индуцированное напряжение первичной катушки должно сохранять свой уровень и фазу, чтобы уравновешивать приложенное напряжение, в соответствии с правилом Кирхгофа для напряжения. Следовательно, ток вторичной обмотки никак не может повлиять на магнитный поток в сердечнике.

Однако, что действительно меняется, так это МДС в магнитной цепи.

Магнитодвижущая сила

Магнитодвижущая сила возникает каждый раз, когда по проводам течёт ток. Обычно МДС сопровождается магнитным потоком в соответствии с уравнением «магнитного закона Ома» МДС = ΦR.

Однако в данном случае, дополнительный магнитный поток не допустим, поэтому МДС вторичной катушки может возникнуть только как противодействие МДС первичной катушки, причём обе МДС равны по величине и противоположны по фазе.

Вот что происходит на самом деле: в первичной обмотке формируется переменный ток на -180° не совпадающий по фазе с током вторичной обмотки – это необходимо для создания этого противодействующего МДС и предотвращения дополнительного потока в сердечнике.

На нашей схеме разметим полярность и обозначим стрелки направления тока, чтобы показать, где какая фаза:

Рис. 9. Поток остаётся постоянным при приложении нагрузки. Тем не менее, в нагруженной вторичной обмотке создаётся противодействующая МДС.
Рис. 9. Поток остаётся постоянным при приложении нагрузки. Тем не менее, в нагруженной вторичной обмотке создаётся противодействующая МДС.

Совсем запутались? Ладно, не унывайте. Трансформаторная динамика – это не для слабонервных. Важно понимать следующее: когда напряжение переменного тока подаётся на первичную катушку, оно создаёт магнитный поток в сердечнике, который индуцирует переменное напряжение во вторичной катушке синфазно с напряжением источника.

Любой ток, протекающий через вторичную катушку для питания нагрузки, индуцирует соответствующий ток в первичной катушке, потребляющей ток от источника.

Взаимная индукция и трансформаторы

Обратите внимание, что первичная катушка ведёт себя как нагрузка по отношению к источнику переменного напряжения, а вторичная катушка ведёт себя как источник питания по отношению к резистору.

Раньше в цепи первичной обмотки катушка поочерёдно забирала энергию и возвращала обратно в цепь. После добавления вторичной обмотки энергия попадает на другую катушку, откуда подаётся на диссипативную (энергоёмкую) нагрузку. Теперь источник переменного тока также напрямую питает резистор.

Конечно, существует ещё дополнительный ток первичной обмотки, отстающий от приложенного напряжения на 90°, которого достаточно для намагничивания сердечника и создания необходимого напряжения для балансировки с источником (от тока возбуждения).

Такой тип устройства и есть трансформатор, потому что он преобразует (трансформирует) электрическую энергию в магнитную, а затем магнитную снова в электрическую. Поскольку его работа зависит от электромагнитной индукции между двумя неподвижными катушками и магнитного потока изменяющейся величины и «полярности», трансформаторы всегда являются устройствами переменного тока.

Схематическое отображение трансформатора – две катушки индуктивности с одним и тем же магнитным сердечником:

Рис. 10. Схематическое отображение трансформера трансформатора состоит из двух символов индуктивности, разделённых линиями, обозначающими ферромагнитный сердечник.
Рис. 10. Схематическое отображение трансформера трансформатора состоит из двух символов индуктивности, разделённых линиями, обозначающими ферромагнитный сердечник.

Две катушки индуктивности легко различить по вышеуказанному символу. Пара вертикальных линий представляет собой железный сердечник, общий для обоих катушек индуктивности. В большинстве трансформаторов сердечники сделаны из ферромагнитных материалов. Но не во всех – иногда индукторы магнитно связаны друг с другом через воздух.

На этой фотографии показан силовой трансформатор того типа, который используется в газоразрядном освещении. Здесь отчетливо видны две катушки индуктивности, намотанные на железный сердечник. Как правило в конструкциях трансформаторов катушки и сердечник спрятаны в металлический защитный кожух. Но этот конкретный трансформатор выполнен в открытом виде, поэтому он идеален для иллюстрации:

Рис. 11. Пример трансформатора для газоразрядного освещения.
Рис. 11. Пример трансформатора для газоразрядного освещения.

Первичная и вторичная обмотки

На предыдущем рисунке видим обе проволочные катушки с изоляцией из лака медного цвета. Верхняя обмотка больше нижней обмотки и имеет большее количество витков вокруг сердечника. В трансформаторах катушки индуктивности часто называют именно обмотками, так как провод намотан на материал сердечника.

Как показано в нашем первоначальном примере, активная катушка индуктивности трансформатора называется первичной обмоткой, а катушка без питания называется вторичной обмоткой.

На следующей фотографии (рисунок ниже) трансформатор разрезан пополам, чтобы показать поперечное сечение железного сердечника, а также обеих обмоток. Как и в показанном ранее трансформаторе, в этом устройстве также используются первичная и вторичная обмотки с разным числом витков.

Также хорошо видно, что калибры проводов различаются между первичной и вторичной обмотками. Зачем в обеих обмотках разные калибры проволоки – это разберём в следующем разделе этой главы.

Кроме того, на этой фотографии видно, что железный сердечник состоит из множества тонких листов (пластин), а не из цельного куска. Про это тоже расскажу позднее.

Рис. 12. На разрезе трансформатора показаны сердечник и обмотки.
Рис. 12. На разрезе трансформатора показаны сердечник и обмотки.

SPICE-анализ для простого трансформатора

С помощью SPICE легко показать, как работает трансформатор, задав в программе первичную и вторичную обмотки моделируемого трансформатора как пару «взаимосвязанных» индукторов (схема ниже).

Коэффициент «связи» (коэффициент взаимной индукции) указан на строке с «k» в описании схемы SPICE, значение этой переменной установлено почти как идеальное (0.999). Этот коэффициент описывает, насколько «связаны» обе катушки индуктивности через магнитное поле. Чем лучше две катушки индуктивности «связаны» магнитным полем, тем эффективнее должна быть передача энергии между ними (и соответственно, коэффициент тем ближе должен быть к единице).

Рис. 13. Две последовательные схемы объединены в общую цепь за счёт того, что индукторы «спарены» в единый трансформатор. Для учёта некоторых особенностей SPICE добавлены фиктивные резисторы.
Рис. 13. Две последовательные схемы объединены в общую цепь за счёт того, что индукторы «спарены» в единый трансформатор. Для учёта некоторых особенностей SPICE добавлены фиктивные резисторы.
transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
l1 2 0 100
l2 3 5 100
** На этой строке сообщается для SPICE, что
** индукторы l1 и l2 магнитно “связаны” друг с другом
k l1 l2 0.999
vi1 3 4 ac 0
rload 4 5 1k
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end

Примечание. «Виртуальные» резисторы RФиктивн. необходимы, чтобы учесть особенности самой SPICE. Первый резистор размыкает цепь, так как непрерывный контур между источником напряжения и L1 в SPICE недопустим. Второй выполняет роль заземлителя (узел 0) для вторичной цепи, что необходимо, ибо SPICE не может работать с любыми незаземлёнными цепями.

freq v(2) i(v1)
6.000E+01 1.000E+01 9.975E-03 Первичная обмотка
freq v(3,5) i(vi1)
6.000E+01 9.962E+00 9.962E-03 Вторичная обмотка

Обратите внимание, что при одинаковой индуктивностях обеих обмоток (100 генри каждая), напряжения и токи переменного тока для них почти равны. Разница между первичным и вторичным токами – это ток намагничивания, о котором упоминалось ранее: этот ток запаздывает по фазе на 90°, он необходим для намагничивания сердечника.

Как видим, данный ток обычно очень мал по сравнению с первичным током, индуцированным нагрузкой, поэтому первичный и вторичный токи почти равны. Это довольно-таки типично для КПД трансформатора.

Эффективность менее 95% считается плохой для современных конструкций силовых трансформаторов, при этом такая передача мощности происходит без использования движущихся частей или каких-то других компонентов, которые могли бы изнашиваться.

Если мы уменьшим сопротивление нагрузки, чтобы потреблять больше тока при том же напряжении, то увидим, что в ответ на это ток через первичную обмотку возрастёт. Несмотря на то, что источник питания переменного тока не подключён напрямую к сопротивлению нагрузки (скорее, они электромагнитно «связаны» друг с другом), величина тока, потребляемого от источника, будет почти такой же, как величина тока, потребляемого, если бы нагрузка была напрямую связана с источником.

Внимательно ознакомьтесь со следующими двумя моделированиями SPICE, показывающими, что происходит, если варьировать сопротивления нагрузочных резисторов:

transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
l1 2 0 100
l2 3 5 100
k l1 l2 0.999
vi1 3 4 ac 0
** Обратите внимание на значение сопротивления нагрузки 200 Ом
rload 4 5 200
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end
freq v(2) i(v1)
6.000E+01 1.000E+01 4.679E-02
freq v(3.5) i(vi1)
6.000E+01 9.348E+00 4.674E-02

Обратите внимание, как на выходе первичный ток близок по величине к вторичному току. В нашем первом моделировании оба тока составляли примерно 10 мА, но теперь они оба составляют примерно 47 мА. В этом втором моделировании два тока относительно ближе друг к другу, потому что ток намагничивания остаётся таким же, как и раньше, в то время как сама сила тока на нагрузке увеличилась.

Также обратите внимание на то, как вторичное напряжение немного снизилось с более тяжёлой (большей по току) нагрузкой. Давайте запустим другое моделирование с ещё меньшим значением сопротивления нагрузки (15 Ом):

transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
l1 2 0 100
l2 3 5 100
k l1 l2 0.999
vi1 3 4 ac 0
rload 4 5 15
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end
freq v(2) i(v1)
6.000E+01 1.000E+01 1.301E-01
freq v(3,5) i(vi1)
6.000E+01 1.950E+00 1.300E-01

Ток на нагрузке теперь составляет 0,13 ампера, или 130 мА, это гораздо выше, чем в прошлый раз. Первичный ток очень близок к тому же, но обратите внимание, как вторичное напряжение упало намного ниже первичного напряжения (1,95 вольт против 10 вольт на первичной обмотке).

Причина тому – несовершенный конструктив нашего трансформатора: поскольку первичная и вторичная индуктивности не связаны идеально (коэффициент k = 0,999 вместо 1.000), возникает «паразитная» индуктивность, она же – индуктивность «рассеяния». Другими словами, часть магнитного поля не связана с вторичной катушкой и, следовательно, не может передавать ей энергию:

Рис. 14. Утечка индуктивности возникает из-за того, что магнитный поток не охватывает обе обмотки.
Рис. 14. Утечка индуктивности возникает из-за того, что магнитный поток не охватывает обе обмотки.

Следовательно, этот поток «утечки» просто сохраняет и возвращает энергию в цепь источника через самоиндукцию, эффективно действуя как последовательный импеданс как в первичной, так и во вторичной цепях. Напряжение падает на этом последовательном импедансе, что приводит к снижению напряжения нагрузки: напряжение на нагрузке «проседает» по мере увеличения тока нагрузки.

Рис. 15. На эквивалентной схеме смоделирована индуктивность рассеяния в виде последовательных индукторов, не являющихся частью «идеального трансформатора».
Рис. 15. На эквивалентной схеме смоделирована индуктивность рассеяния в виде последовательных индукторов, не являющихся частью «идеального трансформатора».

Если мы изменим конструкцию трансформатора, чтобы обеспечить лучшую магнитную связь между первичной и вторичной обмотками (для k вместо 0,999 поставим 0,99999), значения напряжений между первичной и вторичной обмотками снова будут почти равны друг другу:

transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
l1 2 0 100
l2 3 5 100
** Коэффициент «связи» = 0.99999 вместо 0.999
k l1 l2 0.99999
vi1 3 4 ac 0
rload 4 5 15
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end
freq v(2) i(v1)
6.000E+01 1.000E+01 6.658E-01
freq v(3,5) i(vi1)
6.000E+01 9.987E+00 6.658E-01

Видим, что вторичное напряжение снова почти равно первичному, вторичный ток также равен первичному току. В качестве модели это смотрится круто, но увы, построить реальный трансформатор с такой связкой очень проблематично.

Компромиссным решением является разработка первичной и вторичной катушек с меньшей индуктивностью. Стратегия заключается в том, что меньшая общая индуктивность приводит к меньшей индуктивности «утечки», вызывающей проблемы, для любой заданной степени неэффективности магнитной связи. В результате напряжение нагрузки близко к идеальному при той же (сильноточной, большой) нагрузке и одинаковом коэффициенте связи:

transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
** Индуктивность = 1 генри вместо 100 генри
l1 2 0 1
l2 3 5 1
k l1 l2 0.999
vi1 3 4 ac 0
rload 4 5 15
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end
freq v(2) i(v1)
6.000E+01 1.000E+01 6.664E-01
freq v(3,5) i(vi1)
6.000E+01 9.977E+00 6.652E-01

Просто за счёт использования первичной и вторичной катушек с меньшей индуктивностью, напряжение нагрузки для этой тяжёлой нагрузки (большой ток) было возвращено почти до идеального уровня (9,977 В). Здесь возникает резонный вопрос: «Если меньшая индуктивность – это всё, что нужно для достижения почти идеальных характеристик при большой нагрузке, тогда зачем вообще беспокоиться об эффективности «связи»?

Если невозможно построить трансформатор с идеальной «связью», но легко сконструировать катушки с низкой индуктивностью, то почему бы просто во всех трансформаторах не использовать катушки с низкой индуктивностью. Ведь тогда будет отличный КПД даже при плохой магнитной связи?» Ответом будет ещё одно моделирование: возьмём тот же трансформатор с низкой индуктивностью, но на этот раз с меньшей нагрузкой (меньшим током) 1 кОм вместо 15 Ом:

transformer
v1 1 0 ac 10 sin
rbogus1 1 2 1e-12
rbogus2 5 0 9e12
l1 2 0 1
l2 3 5 1
k l1 l2 0.999
vi1 3 4 ac 0
rload 4 5 1k
.ac lin 1 60 60
.print ac v(2,0) i(v1)
.print ac v(3,5) i(vi1)
.end
freq v(2) i(v1)
6.000E+01 1.000E+01 2.835E-02
freq v(3,5) i(vi1)
6.000E+01 9.990E+00 9.990E-03

При более низкой индуктивности обмотки первичное и вторичное напряжения почти равны, а вот примерного равенства между первичным и вторичным токами нет и в помине. В этом конкретном случае первичный ток составляет 28,35 мА, а вторичный ток составляет всего 9,990 мА: почти в три раза больше тока в первичной обмотке, чем во вторичной.

Почему так? Чем меньше индуктивность первичной обмотки, тем меньше индуктивное сопротивление и, как следствие, гораздо больший ток намагничивания. Значительная часть тока, проходящего через первичную обмотку, просто намагничивает сердечник, а не передаёт полезную энергию вторичной обмотке и нагрузке.

Идеальный трансформатор с идентичными первичной и вторичной обмотками будет демонстрировать одинаковое напряжение и ток в обоих наборах обмоток для любых условий нагрузки. В этом прекрасном идеальном мире трансформаторы передавали бы электроэнергию от первичной обмотки к вторичной так же плавно, как если бы нагрузка была напрямую подключена к первичному источнику питания, а трансформатора как будто там нет вообще.

Однако несложно увидеть, что это совершенство достижимо исключительно при идеальном взаимодействии магнитного потока между первичной и вторичной обмотками. Поскольку этого достичь невозможно, трансформаторы нужно проектировать для работы в определённых ожидаемых диапазонах напряжений и нагрузок, тогда их рабочие характеристики будут близки к идеальным.

А пока самое главное, что вы должны вынести из сегодняшнего урока – это основной принцип работы трансформатора: передача мощности от первичной цепи ко вторичной происходит за счёт электромагнитной связи.

Итог

  • Взаимная индукция – это когда магнитный поток двух или более катушек индуктивности «связан», так что напряжение индуцируется в одной катушке пропорционально скорости изменения тока в другой.
  • Трансформатор представляет собой устройство из двух или более дросселей, один из которых питается от сети переменного тока, вызывая переменное напряжение во втором дросселе. Если вторая катушка индуктивности подключена к нагрузке, мощность будет электромагнитно передаваться от источника питания первой катушки индуктивности к этой нагрузке.
  • Катушка индуктивности трансформатора называется первичной обмоткой. Второй индуктор без запитки в трансформаторе называется вторичной обмоткой.
  • Магнитный поток в сердечнике (Φ) отстаёт на 90° от волны напряжения источника питания. Ток, потребляемый первичной обмоткой от источника питания для создания этого потока, называется током намагничивания, и он также отстаёт от волны напряжения источника питания на 90°.
  • Полный первичный ток ненагруженного трансформатора называется током возбуждения и состоит из тока намагничивания и любого дополнительного тока, необходимого для преодоления потерь в сердечнике. Он никогда не бывает идеально синусоидальным в реальном трансформаторе, но может быть приближен к синусоидальной форме, если трансформатор правильно спроектирован и эксплуатируется так, чтобы плотность магнитного потока была минимальной.
  • Поток сердечника индуцирует напряжение в любой катушке, намотанной вокруг сердечника. Индуцированные напряжения идеально синфазны с напряжением первичной обмотки источника питания и имеют одинаковую форму волны.
  • Любой ток, протекающий через вторичную обмотку с нагрузкой, через электромагнитную связь будет «отражаться» в первичную обмотку и потребляться от источника напряжения, как если бы источник питания напрямую подпитывал аналогичную нагрузку.

См.также

Внешние ссылки