Электроника:Полупроводники/Диоды и выпрямители/Умножители напряжения (удвоители, утроители, учетверители и т.д.)

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Макаров В. (valemak)
Проверка/Оформление/Редактирование: Мякишев Е.А.


Умножители напряжения (удвоители, утроители, учетверители и т.д.)[1]

Умножитель напряжения – это специализированный выпрямитель цепи, выходной сигнал которого теоретически кратен пику входного сигнала переменного тока, например, больше в 2, 3 или 4 раза, чем пик переменного тока входного сигнала. Таким образом, можно получить 200 В постоянного тока от источника переменного тока с пиковым напряжением 100 В, используя удвоитель, а 400 В постоянного тока от того же источника на 100 В – от учетверителя. Любая нагрузка в практической цепи снизит эти напряжения.

Мы рассмотрим несколько типов умножителей напряжения – удвоитель напряжения (полуволновой и двухполупериодный), утроитель напряжения и учетверитель напряжения – а затем сделаем некоторые общие замечания о вопросах безопасности для умножителя напряжения и напоследок рассмотрим умножитель Кокрофта-Уолтона.

Удвоитель напряжения

Весьма распространённое применение удвоителя напряжения – это источник питания постоянного тока, способный использовать источник переменного тока на 240 В или 120 В. В источнике питания можно переключиться на двухполупериодный мост, для выработки около 300 В постоянного тока от источника 240 В переменного тока. Можно переключиться на 120 В, тогда мост как работает как удвоитель, вырабатывая около 300 В постоянного тока из 120 В переменного тока. В обоих случаях вырабатывается 300 В постоянного тока. Это в дальнейшем может использоваться как входное напряжение для импульсного регулятора, вырабатывающего более низкие напряжения для питания, скажем, персонального компьютера.

Полуволновой удвоитель напряжения

Полуволновой удвоитель напряжения на рисунке 1.а ниже состоит из двух цепей: фиксатора уровня (рисунок 1.б) и пикового детектора (полуволнового выпрямителя), который показан в изменённой форме на рисунке 1.в ниже. К пиковому детектору добавлен конденсатор C2, что и делает схему полуволновым выпрямителем.

Рис. 1. Полупериодный удвоитель напряжения (а) состоит из (б) фиксатора и (в) полуволнового выпрямителя.

Анализ рабочих схем полуволнового удвоителя напряжения

На рисунке 1.б выше, C2 заряжается до 5 В (если точнее, то до 4,3 В с учётом падения напряжения на диоде) на отрицательном полупериоде входного переменного тока. Правый вывод заземлён проводом D2. Левый вывод заряжается на отрицательном пике входа переменного тока. Так работает фиксатор уровня.

Во время положительного полупериода полуволновой выпрямитель вступает в игру, как показано на рисунке 1.в выше. Диод D2 не в цепи, так как он включён в обратном направлении. C2 теперь включён последовательно с источником напряжения. Обратите внимание на полярность батареи и C2, последовательного вспомогательного устройства. Таким образом, выпрямитель D1 получает всего 10 В на пике синусоиды, 5 В от батареи и 5 В от C2. D1 проводит сигнал V(1) (рисунок 2 ниже ), заряжая C1 до пика синусоидальной волны до 5 В постоянного тока (кривая V(2) на рисунке 2 ниже). Волна V(2) – это выходной сигнал удвоителя, который стабилизируется на уровне 10 В (точнее 8,6 В с учётом падения напряжения на диодах) после нескольких циклов входного синусоидального сигнала.

Рис. 2. Удвоитель напряжения: V(4) – это вход, V(1) –фиксатор уровня, V(2) – выход однополупериодного выпрямителя, который также является и выходом удвоителя.
*SPICE 03255.eps
C1 2 0 1000p
D1 1 2 diode
C2 4 1 1000p
D2 0 1 diode
V1 4 0 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Двухполупериодный удвоитель напряжения

Двухполупериодный удвоитель напряжения состоит из пары последовательно включённых полуволновых выпрямителей (рисунок 3 ниже). Также рядом приведён соответствующий список соединений SPICE для этой схемы.

Анализ работы полноволнового удвоителя напряжения

Нижний выпрямитель заряжает C1 за отрицательный полупериод входного сигнала. Верхний выпрямитель заряжает C2 в положительном полупериоде. Каждый конденсатор получает заряд 5 В (4,3 В с учётом падения напряжения на диоде). Выход в узле 5 представляет собой последовательную сумму C1 + C2 или 10 В (8,6 В, если с падениями напряжения на диодах).

Рис. 3. Двухполупериодный удвоитель напряжения состоит из двух полуволновых выпрямителей, работающих на чередующихся полярностях.
*SPICE 03273.eps
*R1 3 0 100k
*R2 5 3 100k
D1 0 2 diode
D2 2 5 diode
C1 3 0 1000p
C2 5 3 1000p
V1 2 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Обратите внимание, что выход V(5) достигает полного значения в течение одного цикла изменения входа V(2):

Рис. 4. Двухполупериодный удвоитель напряжения: V(2) – это вход, V(3) – напряжение в средней точке, V(5) – напряжение на выходе.

Получение двухполупериодных удвоителей из однополупериодных выпрямителей

На рисунке 5.а ниже показано, как получить двухполупериодный удвоитель, имея пару полуволновых выпрямителей противоположной полярности. Отрицательный выпрямитель пары для наглядности перерисован на рисунке 5.б. Оба они объединены на рисунке 5.в при помощи общего провода. На рисунке 5.г отрицательный выпрямитель переподключён для совместного использования с положительным выпрямителем общего источника напряжения. В этом случае получаем источник питания ± 5 В (4,3 В с падением напряжения на диоде); тем не менее, между двумя выводами замер показывает 10 В. Контрольная точка заземления перемещена так, чтобы напряжение +10 В было доступно по отношению к «земле».

Рис. 5. Двухполупериодный удвоитель: (а) пара удвоителей, (б) перерисовка одного из удвоителей для наглядности, (в) общее заземление, (г) общий источник напряжения, (e) перемещение точки заземления.

Утроитель напряжения

Утроитель напряжения (рисунок 6 ниже) скомбинирован из удвоителя и полуволнового выпрямителя (C3 + D3). Однополупериодный выпрямитель выдаёт 5 В (4,3 В) в узле 3. Удвоитель обеспечивает еще 10 В (8,4 В) между узлами 2 и 3. Суммарно получается 15 В (12,9 В) на выходном узле 2 относительно заземления. Список соединений SPICE также прилагается (рисунок 7 ниже):

Рис. 6. Утроитель напряжения, состоящий из удвоителя, помещённого поверх одного из звеньев выпрямителя.

Обратите внимание, что V(3) на рисунке 7 ниже возрастает до 5 В (4,3 В) в первом отрицательном полупериоде. График входа V(4) сдвигается вверх на 5 В (4,3 В) за счёт 5 В от однополупериодного выпрямителя. И плюс ещё 5 В на V(1) из-за фиксатора уровня (C2, D2). D1 заряжает C1 (волна V(2)) до пикового значения V(1).

Рис. 7. Утроитель напряжения: V(3) – однополупериодный выпрямитель, V(4) – входной сигнал на + 5 В, V(1) – фиксатор уровня, V(2) – конечный выход.
*SPICE 03283.eps
C3 3 0 1000p
D3 0 4 diode
C1 2 3 1000p
D1 1 2 diode
C2 4 1 1000p
D2 3 1 diode
V1 4 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Учетверитель напряжения

Учетверитель напряжения представляет собой комбинацию сложения двух удвоителей, показанных на рисунке 8 ниже. Каждый удвоитель по отдельности обеспечивает 10 В (8,6 В) для последовательной суммы на узле 2 по отношению к «земле» – итого 20 В (17,2 В).

Список соединений SPICE представлен на рисунке 9 ниже.

Рис. 8. Учетверитель напряжения, состоящий из двух последовательно соединенных удвоителей, с выходом в узле 2.

Волновые сигналы учетверителя показаны на рисунке ниже. Доступны два выхода постоянного тока: V(3) – это выход удвоителя, и V(2) – это выход учетверителя. На фиксаторах уровня некоторые из промежуточных напряжений показывают, что входная синусоида (не показана на графике), колеблющаяся на 5 В, последовательно фиксируется на более высоких уровнях: на V(5), V(4) и V(1). Строго говоря, V(4) не является выходом фиксатора уровня. Это просто источник переменного напряжения, подключённый последовательно к выходу удвоителя V(3). Тем не менее, V(1) является фиксированной версией V(4).

Рис. 9. Учетверитель напряжения: постоянное напряжение доступно на V(3) и V(2). Волны промежуточных сигналов: фиксаторы V(5), V(4), V(1).
*SPICE 03441.eps
*SPICE 03286.eps
C22 4 5 1000p
C11 3 0 1000p
D11 0 5 diode
D22 5 3 diode
C1 2 3 1000p
D1 1 2 diode
C2 4 1 1000p
D2 3 1 diode
V1 4 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Замечания по умножителям напряжения и источникам питания с линейным приводом

Здесь уместно сделать несколько ремарок по умножителям напряжения. Параметры схемы, использованные в примерах (V = 5 В, 1 кГц, C = 1000 пФ), не обеспечивают большого тока, там только уровень микроампер. Кроме того, везде отсутствовали нагрузочные резисторы. Нагрузка дополнительно снижает напряжения по сравнению с показанными значениями. Если схемы должны управляться источником питания с частотой в килогерцах при низком напряжении, как в приведённых выше примерах, то конденсаторы в таких случаях обычно имеют номинал от 0,1 до 1,0 мкФ, чтобы на выходе был миллиамперный ток. Если умножители работают с частотой 50/60 Гц, конденсатор составляет от нескольких сотен до нескольких тысяч микрофарад, чтобы обеспечить выходной ток в сотни миллиампер. При питании от сетевого напряжения обратите внимание на полярность и номинальное напряжение конденсаторов.

И наконец, любой источник питания с прямым питанием от сети (без трансформатора) опасен как для самого экспериментатора, так и для испытательного оборудования, работающего от сети. Коммерческие источники питания с прямым приводом безопасны, поскольку опасная электрическая схема находится в корпусе, что обеспечивает защиту пользователя. При установке в эти схемы электролитических конденсаторов любого напряжения, конденсаторы взорвутся при изменении полярности. Если уж и экспериментируете с такими цепями, то включать их следует за защитным экраном.

Умножитель Кокрофта-Уолтона

Умножитель напряжения, состоящий из каскада (из любого количества) полуволновых удвоителей известен как умножитель Ко́крофта-Уо́лтона, как показано на рисунке 10 ниже. Этот умножитель используется, когда требуется высокое напряжение при низком токе. Преимущество перед обычным источником питания состоит в том, что не требуется дорогой высоковольтный трансформатор – по крайней мере, не равный всей выходной мощности.

Рис. 10. Умножитель (×8) напряжения Кокрофта-Уолтона; вывод на узел 8.

Пара диодов и конденсаторов слева от узлов 1 и 2 на рисунке выше составляет полуволновой удвоитель. Диоды, повёрнутые на 45° против часовой стрелки и нижние конденсаторы, делает схему похожей на то, что изображено на рисунке 1.а выше (там также эквивалентный блок из двух диодов и конденсатора). Четыре секции удвоения каскадно располагаются слева-направо, что теоретически должно дать коэффициент умножения ×8. Узел 1 имеет волну сигнала, характерную для фиксатора уровня (не показано на рисунке 11 ниже), т.е. синусоиду, сдвинутую вверх на ×1 (5 В). Остальные узлы с нечётными номерами представляют собой синусоиды, ограниченные последовательно более высокими напряжениями. Узел 2, выход первого удвоителя, представляет собой двойное постоянное напряжение V(2) на рисунке 11 ниже. Последовательные узлы с чётными номерами последовательно показывают всё более высокие напряжения: V(4), V(6), V(8).

Рис. 11. Осциллограммы для умножителя Кокрофта-Уолтона (×8). Выход – V(8).
D1 7 8 diode
C1 8 6 1000p
D2 6 7 diode
C2 5 7 1000p
D3 5 6 diode
C3 4 6 1000p
D4 4 5 diode
C4 3 5 1000p
D5 3 4 diode
C5 2 4 1000p
D6 2 3 diode
D7 1 2 diode
C6 1 3 1000p
C7 2 0 1000p
C8 99 1 1000p
D8 0 1 diode
V1 99 0 SIN(0 5 1k)
.model diode d
.tran 0.01m 50m
.end

Без падений на диодах каждый удвоитель дает 2VВход. или 10 В. Если же учесть два диодных падения (10 - 1,4) = 8,6 В, то это ближе к реальному значению. Всего для 4-х удвоителей ожидается 4 × 8,6 = 34,4 В из теоретически максимально возможных 40 В.

Если взглянуть на рисунок 11 выше, то примерно правильным представляется V(2); однако получаем выход V(8) < 30 В вместо ожидаемых 34,4 В. Проблема с множителем Кокрофта-Уолтона заключается в том, что каждая дополнительная ступень увеличивает в меньшей степени, чем предыдущая. Таким образом, на практике сталкиваемся с пределом в максимальном количестве секций. Это ограничение преодолевается, если изменить базовую схему. Также обратите внимание на временну́ю шкалу 40 мс по сравнению с 5 мс для предыдущих схем. Потребовалось аж 40 мс для повышения напряжения до предельного значения для этой цепи. В списке соединений на рисунке выше есть команда «.tran 0.010m 50m» для увеличения времени моделирования до 50 мс; правда, отображается только первые 40 мс.

Умножитель Кокрофта-Уолтона служит более эффективным источником высокого напряжения для фотоэлектронных умножителей, требующих до 2000 В. Я даже больше скажу, трубка имеет множество динодов, клемм, требующих подключения к узлам «с чётными номерами» с более низким напряжением. Последовательный ряд отводов умножителя заменяет теплогенерирующий резистивный делитель напряжения в предыдущих схемах.

Умножитель Кокрофта-Уолтона, работающий от сети переменного тока, подаёт высокое напряжение на «ионные генераторы» для нейтрализации электростатического заряда и для очистителей воздуха.

Итог

  • Умножитель напряженияКурсивное начертание выдаёт постоянный ток, кратный (×2, ×3, ×4 и т.д.) пиковому входному напряжению переменного тока.
  • Самый базовый умножитель – это полуволновой удвоитель.
  • Двухполупериодный удвоитель – наилучший.
  • Утроитель – однополупериодный удвоитель + обычный выпрямитель (пиковый детектор).
  • Учетверитель – пара полуволновых удвоителей.
  • Цепочка, состоящая из полуволновых удвоителей известна как умножитель Кокрофта-Уолтона.

См.также

Внешние ссылки