ESP8266:Примеры/Датчик открывания двери, передающий данные на EasyIoT Cloud

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 1848 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


Датчик открывания двери, передающий данные на EasyIoT Cloud[1]

Эта статья рассказывает, как собрать систему с датчиком открывания/закрывания двери, через WiFi подключенным к облачному сервису EasyIoT Cloud. Для этого проекта понадобятся модуль с чипом ESP8266, электромагнитный переключатель и среда разработки IDE Arduino.

Введение

Видео, показывающее проект в действии:

[Видео – https://www.youtube.com/watch?v=5k5F5IpOKm4]

Браузерное меню с модулями EasyIoT Cloud:

ESP8266 WiFi doorwindow sensor (EasyIoT Cloud REST API V1.0) 1.png

График, показывающий, когда происходило открытие/закрытие двери:

ESP8266 WiFi doorwindow sensor (EasyIoT Cloud REST API V1.0) 2.png

Необходимые компоненты

  • Один модуль с ESP8266 (например, плата NodeMCU, ESP-01, ESP-02 или пр.)
  • Один электромагнитный переключатель
  • Один 3,3-вольтовый источник питания (регулятор напряжения или батерея)

Настройка EasyIoT Cloud

Зарегистрируйтесь в EasyIoT Cloud. Если вам не пришло письмо с подтверждением регистрации, проверьте папку со спамом. Если письма нет и там, свяжитесь с нами, и мы активируем ваш аккаунт.

Никаких настроек в EasyIoT Cloud не требуется – модуль работает по принципу «plug and play» (т.е. «подключи и работай»). Вам нужно будет лишь запомнить токен безопасности для подключения к EasyIoT Cloud. Для этого пройдите в меню Configure > Tokens и нажмите на кнопку «Add Token». Запомните этот токен – он пригодится позже (его нужно будет вписать в программу). Если удалить токен из аккаунта, модуль перестанет отправлять данные на EasyIoT Cloud. Один токен можно использовать для нескольких устройств.

ESP8266 WiFi doorwindow sensor (EasyIoT Cloud REST API V1.0) 3.png

Программа

Программа написана в IDE Arduino. О том, как установить в IDE Arduino аддон для ESP8266, смотрите тут. Дальнейшие действия зависят от того, какой модуль ESP8266 вы используете. Если ваш модуль не оснащен адаптером USB-Serial, то его нужно будет подключить. Не забудьте настроить его на 3,3 вольта. Иногда адаптеры не обеспечивают ESP8266 достаточным напряжением. В этом случае ESP8266 нужно питать только от внешнего источника питания (т.е. нужно отключить от адаптера линию Vcc). Если вы используете адаптерную плату вроде той, что выпускает NodeMCU, просто подключите ее к компьютеру через USB-кабель. Этот способ рекомендуется для новичков.

Саму программу можно скачать с нашего GitHub-репозитория. Вам также понадобится библиотека «EIoTCloudRestApiV1.0». О том, как установить ее в IDE Arduino, читайте тут.

В самой программе нужно будет поменять строчки с SSID, паролем к SSID и токеном безопасности.

#define AP_USERNAME "xxx"
#define AP_PASSWORD "xxx"
#define TOKEN "xxx"

Если вы используете другой GPIO-контакт ESP8266, в программе также понадобится поменять строчку с используемым GPIO-контактом.

  1. /*
  2.  Программа написана Игорем Ярком (Igor Jarc).
  3.  Более подробно смотрите по ссылке http://iot-playground.com.
  4.  Пожалуйста не пишите автору напрямую.
  5.  Используйте для этого форум сообщества на сайте.
  6.  
  7.  Эта программа бесплатна. Вы можете повторно распространять
  8.  и/или модифицировать ее согласно правилам лицензии
  9.  GNU General Public License (2-ая версия),
  10.  опубликованной Фондом свободного ПО.
  11. */
  12.  
  13. #include <ESP8266WiFi.h>
  14. #include "EIoTCloudRestApiV1.0.h"
  15. #include <EEPROM.h>
  16.  
  17. #define DEBUG_PROG
  18.  
  19. #ifdef DEBUG_PROG
  20.   #define DEBUG_PRINTLN(x)  Serial.println(x)
  21.   #define DEBUG_PRINT(x)    Serial.print(x)
  22. #else
  23.   #define DEBUG_PRINTLN(x)
  24.   #define DEBUG_PRINT(x)
  25. #endif
  26.  
  27. EIoTCloudRestApi eiotcloud;
  28.  
  29. // это строчки с SSID, паролем к SSID и токеном безопасности;
  30. // поменяйте их:
  31. #define AP_USERNAME "xxx"
  32. #define AP_PASSWORD "xxx"
  33.  
  34. #define TOKEN "xxx"
  35.  
  36. #define CONFIG_START 0
  37. #define CONFIG_VERSION "v01"
  38.  
  39.  
  40. #define INPUT_PIN        D5
  41.  
  42. struct StoreStruct {
  43.   // это лишь для того, чтобы определить, ваши ли это настройки:
  44.   char version[4];
  45.   // переменные для ваших настроек:
  46.   uint moduleId;
  47. } storage = {
  48.   CONFIG_VERSION,
  49.   // модуль с ID «0» – неправильный модуль
  50.   0,
  51. };
  52.  
  53. String moduleId = "";
  54. String parameterId = "";
  55. bool oldInputState;
  56.  
  57. void setup() {
  58.     Serial.begin(9600);
  59.     DEBUG_PRINTLN("Start...");  //  "Запуск..."
  60.  
  61.     EEPROM.begin(512);
  62.     loadConfig();
  63.  
  64.     eiotcloud.begin(AP_USERNAME, AP_PASSWORD);
  65.     eiotcloud.SetToken(TOKEN);
  66.  
  67.     // если это первый раз, когда вы получаете новый токен
  68.     // и регистрируете новый модуль, этот фрагмент кода
  69.     // автоматически добавит модуль в Cloud:
  70.     if (storage.moduleId == 0)
  71.     {      
  72.       // добавляем новый модуль и настраиваем его:
  73.       moduleId = eiotcloud.ModuleNew();
  74.       DEBUG_PRINT("ModuleId: ");
  75.       DEBUG_PRINTLN(moduleId);
  76.       storage.moduleId = moduleId.toInt();
  77.      
  78.       // если ID модуля – неправильный, останавливаемся:
  79.       if (storage.moduleId == 0)
  80.       {
  81.         DEBUG_PRINTLN("Check Account limits -> module limit.");
  82.                   //  "Проверьте Account limits -> module limit."
  83.         while(true) delay(1);
  84.       }
  85.       // задаем тип модуля:
  86.       bool modtyperet = eiotcloud.SetModulType(moduleId, "MT_DIGITAL_INPUT");
  87.       DEBUG_PRINT("SetModulType: ");
  88.       DEBUG_PRINTLN(modtyperet);
  89.      
  90.       // задаем название модуля:
  91.       bool modname = eiotcloud.SetModulName(moduleId, "Door/window sensor");
  92.       DEBUG_PRINT("SetModulName: ");
  93.       DEBUG_PRINTLN(modname);
  94.  
  95.       // добавляем картинку для параметра:
  96.       String parameterImgId = eiotcloud.NewModuleParameter(moduleId, "Settings.Icon1");
  97.       DEBUG_PRINT("parameterImgId: ");
  98.       DEBUG_PRINTLN(parameterImgId);
  99.  
  100.       // добавляем картинку для модуля:
  101.       bool valueRet1 = eiotcloud.SetParameterValue(parameterImgId, "door_1.png");
  102.       DEBUG_PRINT("SetParameterValue: ");
  103.       DEBUG_PRINTLN(valueRet1);
  104.  
  105.  
  106.       // добавляем картинку для параметра:
  107.       String parameterImgId2 = eiotcloud.NewModuleParameter(moduleId, "Settings.Icon2");
  108.       DEBUG_PRINT("parameterImgId2: ");
  109.       DEBUG_PRINTLN(parameterImgId2);
  110.  
  111.       // добавляем картинку для модуля:
  112.       bool valueRet3 = eiotcloud.SetParameterValue(parameterImgId2, "door_2.png");
  113.       DEBUG_PRINT("SetParameterValue: ");
  114.       DEBUG_PRINTLN(valueRet3);
  115.  
  116.      
  117.       // теперь добавляем значение параметру:
  118.       parameterId = eiotcloud.NewModuleParameter(moduleId, "Sensor.Parameter1");
  119.       DEBUG_PRINT("ParameterId: ");
  120.       DEBUG_PRINTLN(parameterId);
  121.  
  122.       // задаем параметр LogToDatabase:
  123.       bool valueRet4 = eiotcloud.SetParameterLogToDatabase(parameterId, true);
  124.       DEBUG_PRINT("SetLogToDatabase: ");
  125.       DEBUG_PRINTLN(valueRet4);
  126.  
  127.       // задаем параметр ChartSteps:
  128.       valueRet4 = eiotcloud.SetParameterChartSteps(parameterId, true);
  129.       DEBUG_PRINT("SetLogToDatabase: ");
  130.       DEBUG_PRINTLN(valueRet4);
  131.  
  132.  
  133.       // добавляем параметр StatusText1:
  134.       String parameterStatTxt1 = eiotcloud.NewModuleParameter(moduleId, "Settings.StatusText1");
  135.       DEBUG_PRINT("parameterStatTxt1: ");
  136.       DEBUG_PRINTLN(parameterStatTxt1);
  137.  
  138.       // добавляем текст для параметра StatusText1:
  139.       bool valueRet5 = eiotcloud.SetParameterValue(parameterStatTxt1, "Open");
  140.       DEBUG_PRINT("SetParameterValue: ");
  141.       DEBUG_PRINTLN(valueRet5);
  142.  
  143.       // добавляем параметр StatusText2:
  144.       String parameterStatTxt2 = eiotcloud.NewModuleParameter(moduleId, "Settings.StatusText2");
  145.       DEBUG_PRINT("parameterStatTxt2: ");
  146.       DEBUG_PRINTLN(parameterStatTxt2);
  147.  
  148.       // добавляем текст для параметра StatusText2:
  149.       bool valueRet6 = eiotcloud.SetParameterValue(parameterStatTxt2, "Close");
  150.       DEBUG_PRINT("SetParameterValue: ");
  151.       DEBUG_PRINTLN(valueRet6);
  152.  
  153.       // сохраняем настройки:
  154.       saveConfig();
  155.     }
  156.  
  157.     // если что-то пошло не так, ждем:
  158.     if (storage.moduleId == 0)
  159.       while(true) delay(1);
  160.  
  161.     // считываем из памяти ID модуля:
  162.     moduleId = String(storage.moduleId);
  163.     // считываем из облака ID параметра Sensor.Parameter1:
  164.     parameterId = eiotcloud.GetModuleParameterByName(moduleId, "Sensor.Parameter1");
  165.     DEBUG_PRINT("parameterId: ");
  166.     DEBUG_PRINTLN(parameterId);
  167.  
  168.     pinMode(INPUT_PIN, INPUT_PULLUP);
  169.    
  170.     oldInputState = !digitalRead(INPUT_PIN);
  171. }
  172.  
  173. void loop() {
  174.   int inputState = digitalRead(INPUT_PIN);;  
  175.  
  176.   if (inputState != oldInputState)
  177.   {
  178.     bool valueRet = eiotcloud.SetParameterValue(parameterId, String(inputState));
  179.     DEBUG_PRINT("SetParameterValue: ");
  180.     DEBUG_PRINTLN(valueRet);
  181.     oldInputState = inputState;
  182.   }
  183. }
  184.  
  185. void loadConfig() {
  186.   // это чтобы убедиться, что настройки есть, и это ваши настройки;
  187.   // если программа не найдет настройки, то воспользуется
  188.   // настройками по умолчанию:
  189.   if (EEPROM.read(CONFIG_START + 0) == CONFIG_VERSION[0] &&
  190.       EEPROM.read(CONFIG_START + 1) == CONFIG_VERSION[1] &&
  191.       EEPROM.read(CONFIG_START + 2) == CONFIG_VERSION[2])
  192.     for (unsigned int t=0; t<sizeof(storage); t++)
  193.       *((char*)&storage + t) = EEPROM.read(CONFIG_START + t);
  194. }
  195.  
  196.  
  197. void saveConfig() {
  198.   for (unsigned int t=0; t<sizeof(storage); t++)
  199.     EEPROM.write(CONFIG_START + t, *((char*)&storage + t));
  200.  
  201.   EEPROM.commit();
  202. }

Подключение компонентов

В нашем случае используется плата NodeMCU, но вы можете воспользоваться любым другим модулем ESP8266. Правда, в этом случае вам дополнительно понадобится программатор FTDI. Для питания можно воспользоваться двумя батарейками типа AA или 3,3-вольтовым регулятором.

Кроме того, один провод, идущий от электромагнитного переключателя, нужно подключить к 5-ому GPIO-контакту, а другой – к GND.

ESP8266 WiFi doorwindow sensor (EasyIoT Cloud REST API V1.0) 4.jpg

См.также

Внешние ссылки

  1. iot-playground.com - ESP8266 WiFi door/window sensor (EasyIoT Cloud REST API V1.0)