Processing:Справочник языка Processing/size()

Содержание

Среда разработки Processing

Справочник языка Processing

Библиотеки

Примеры

Режимы программирования

Проверка/Оформление/Редактирование: Мякишев Е.А.

Черновик

size()

Обозначение

size()

Описание

Устанавливает ширину и высоту окна дисплея в пикселях. При наличии в программе функции setup(), функция size() должна быть вызвана вначале функции setup().

Значения встроенных переменных width и height задаются параметрами, передаваемыми этой функции. Например, при вызове size(640, 480) значение 640 присваивается переменной width, а 480 — переменной height.

Если size() не используется, размер окна по умолчанию равен 100 на 100 пикселей.

Функция size() может использоваться только один раз внутри скетча и не может использоваться для изменения размера.

Начиная с Processing версии 3.0, чтобы сделать окно выполнения на весь экран, используйте функцию fullScreen(), а не более старый способ size(displayWidth, displayHeight).

Максимальная ширина и высота ограничены используемой операционной системой, и обычно это ширина и высота используемого дисплея. На некоторых машинах это может быть просто количество пикселей на текущем экране, что означает, что экран размером 800 на 600 может поддерживать size(1600, 300), так как это то же количество пикселей. Это сильно варьируется, поэтому вам придется попробовать разные режимы и размеры рендеринга, пока не получите то, что ищете. Если вам нужно что-то большее, используйте createGraphics для создания невидимой поверхности рисования.

Минимальная ширина и высота — около 100 пикселей в каждом направлении. Это наименьшее поддерживаемое значение в Windows, macOS и Linux. Processing обеспечивает минимальный размер, чтобы скетчи выполнялись одинаково на разных машинах.

Параметр renderer выбирает, какой движок рендеринга использовать. Например, если вы будете рисовать 3D-фигуры, используйте P3D. В дополнение к средству рендеринга по умолчанию другие средства визуализации:

• P2D (Processing 2D): Визуализация 2D графики, которая использует OpenGL-совместимое графическое оборудование.
• P3D (Processing 3D): Визуализация 3D графики, которая использует, OpenGL-совместимое графическое оборудование.
• FX2D (JavaFX 2D): Визуализация 2D графики, которая использует JavaFX, может быть быстрее для некоторых приложений, но имеет некоторые особенности совместимости.
• PDF: рендеринг PDF рисует 2D-графику непосредственно в файл Acrobat PDF. Это дает отличные результаты, когда вам нужны векторные формы для вывода или печати с высоким разрешением. Для использования библиотеки сначала необходимо ее импортировать Import Library → PDF. Более подробную информацию можно найти в справочнике по библиотеке PDF.

Начиная с Processing версии 3.0, чтобы использовать переменные в качестве параметров функции size(), поместите функцию size() в функцию settings() (вместо setup()). Дополнительную информацию об этом вы найдете на странице про функцию settings().

Синтаксис

size(width, height)
size(width, height, renderer)

Параметры

width  - тип int, ширина окна в пикселях.
height - тип int, высота окна в пикселях.

Возвращаемое значение

void

Пример

№1

size(200, 100);
background(153);
line(0, 0, width, height);

№2

void setup() {
  size(320, 240);
}

void draw() {
  background(153);
  line(0, 0, width, height);
}

№3

size(150, 200, P3D);  // Указываем средство визуализации P3D.
background(153);

// С P3D мы можем использовать значения z (глубина)...
line(0, 0, 0, width, height, -100);
line(width, 0, 0, width, height, -100);
line(0, height, 0, width, height, -100);

//...и функции, специфичные для 3D, такие как box()
translate(width/2, height/2);
rotateX(PI/6);
rotateY(PI/6);
box(35);