Processing:Примеры/Движение объекта по кривой

Содержание

Среда разработки Processing

Справочник языка Processing

Библиотеки

Примеры

Режимы программирования

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Описание

В этом скетче-примере эллипс движется по кривой, рассчитываемой с помощью формулы y = x^4. Кликните мышкой в какой-либо части экрана, чтобы эллипс переместился на это место.

Пример

float beginX = 20.0;  // начальная координата X
float beginY = 10.0;  // начальная координата Y
float endX = 570.0;   // конечная координата X
float endY = 320.0;   // конечная координата Y
float distX;          // дистанция движения по оси X
float distY;          // дистанция движения по оси Y
float exponent = 4;   // переменная для расчета кривой
float x = 0.0;        // текущая координата X
float y = 0.0;        // текущая координата Y
float step = 0.01;    // шаг пути
float pct = 0.0;      // пройдено процентов пути (от 0.0 до 1.0)

void setup() {
  size(640, 360);
  noStroke();
  distX = endX - beginX;
  distY = endY - beginY;
}

void draw() {
  fill(0, 2);
  rect(0, 0, width, height);
  pct += step;
  if (pct < 1.0) {
    x = beginX + (pct * distX);
    y = beginY + (pow(pct, exponent) * distY);
  }
  fill(255);
  ellipse(x, y, 20, 20);
}

void mousePressed() {
  pct = 0.0;
  beginX = x;
  beginY = y;
  endX = mouseX;
  endY = mouseY;
  distX = endX - beginX;
  distY = endY - beginY;
}