Processing:Примеры/Двухмерный массив

Содержание

Среда разработки Processing

Справочник языка Processing

Библиотеки

Примеры

Режимы программирования

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Описание

В этом примере демонстрируется синтаксис для создания двухмерного (2D) массива. Доступ к данным 2D-массива осуществляется при помощи двух индексных значений. Двухмерные массивы удобно использовать для хранения изображений. В примере ниже цвет каждой точки зависит от расстояния до центра изображения.

Пример

float[][] distances;
float maxDistance;
int spacer;

void setup() {
  size(640, 360);
  maxDistance = dist(width/2, height/2, width, height);
  distances = new float[width][height];
  for (int y = 0; y < height; y++) {
    for (int x = 0; x < width; x++) {
      float distance = dist(width/2, height/2, x, y);
      distances[x][y] = distance/maxDistance * 255;
    }
  }
  spacer = 10;
  strokeWeight(6);
  noLoop();  // программа сделает только один цикл и остановится
}

void draw() {
  background(0);
  // вложенный цикл for() пропускает некоторые значения массива,
  // опираясь на значение в переменной «spacer»,
  // поэтому в массиве больше значений, чем нарисовано на экране;
  // чтобы поменять плотность точек,
  // поменяйте значение в переменной «spacer»:
  for (int y = 0; y < height; y += spacer) {
    for (int x = 0; x < width; x += spacer) {
      stroke(distances[x][y]);
      point(x + spacer/2, y + spacer/2);
    }
  }
}