Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Processing:Библиотеки/SVG Export

Материал из Онлайн справочника
Перейти к: навигация, поиск


Перевод: Максим Кузьмин (Cubewriter)
Перевел 2680 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Ambox content.png Черновик


SVG Export[1]

Библиотека SVG дает возможность сохранять SVG-файлы прямо из Processing. Это файлы с векторной графикой, которую можно масштабировать до любого размера, благодаря чему они хорошо подходят для изображений с высоким разрешением. Библиотека SVG умеет «сплющивать» 3D-данные в векторную 2D-графику, но для экспорта 3D-данных используйте библиотеку DXF. Исходный код библиотеки можно скачать на GitHub-репозитории Processing. О найденных багах сообщайте сюда.

Экспорт SVG-файла (без использования дисплейного окна)

Этот скетч-пример рисует в SVG-файл один кадр, а затем завершается. Обратите внимание, что дисплейное окно в процессе не откроется – это полезно при создании больших SVG-изображений, которые гораздо больше размера экрана.

  1. import processing.svg.*;
  2.  
  3. void setup() {
  4.   size(400, 400, SVG, "filename.svg");
  5. }
  6.  
  7. void draw() {
  8.   // рисуем тут что-нибудь интересное:
  9.   line(0, 0, width/2, height);
  10.  
  11.   // выходим из программы:
  12.   println("Finished.");  //  "Завершено."
  13.   exit();
  14. }

Экспорт SVG-файла (с использованием дисплейного окна)

Чтобы нарисовать что-то на экране, одновременно с этим сохраняя SVG-файл, используйте функции beginRecord() и endRecord(). В отличие от визуализатора PDF, визуализатор SVG сохраняет только последний кадр из серии кадров. Это медленнее, но позволяет видеть, что именно происходит на экране во время сохранения файла.

  1. import processing.svg.*;
  2.  
  3. void setup() {
  4.   size(400, 400);
  5.   noLoop();
  6.   beginRecord(SVG, "filename.svg");
  7. }
  8.  
  9. void draw() {
  10.   // рисуем тут что-нибудь интересное:
  11.   line(0, 0, width/2, height);
  12.  
  13.   endRecord();
  14. }

Сохранение одного кадра из анимации (с использованием дисплейного окна)

Эта библиотека также позволяет сохранять один кадр из скетча с двигающимися элементами. Создаем булеву переменную для включения/выключения процесса записи SVG-файла.

  1. import processing.svg.*;
  2.  
  3. boolean record;
  4.  
  5. void setup() {
  6.   size(400, 400);
  7. }
  8.  
  9. void draw() {
  10.   if (record) {
  11.     // обратите внимание, что #### будет заменено на номер кадра:
  12.     beginRecord(SVG, "frame-####.svg");
  13.   }
  14.  
  15.   // рисуем тут что-нибудь интересное:
  16.   background(255);
  17.   line(mouseX, mouseY, width/2, height/2);
  18.  
  19.   if (record) {
  20.     endRecord();
  21.         record = false;
  22.   }
  23. }
  24.  
  25. // используем нажатия на кнопку мыши,
  26. // чтобы не плодить тысячи файлов:
  27. void mousePressed() {
  28.   record = true;
  29. }

Сохранение SVG-файлов из 3D-графики (с использованием дисплейного окна)

Чтобы создать векторы из 3D-данных, воспользуйтесь функциями beginRaw() и endRaw(). Они считывают данные фигур прямо перед тем, как они будут нарисованы на экране. В этот момент вся сцена – это не более, чем просто длинный список линий и треугольников. Это значит, что фигура, сделанная при помощи метода sphere(), будет состоять из сотен треугольников, а не из одного объекта. Вместе с функциями beginRaw() и endRaw() можно использовать и 2D-, и в 3D-визуализатор. К примеру, использование beginRaw() вместе с библиотекой SVG запишет графику в виде «сплющенных» (т.е. превращенных в 2D-графику) треугольников и линий.

  1. import processing.svg.*;
  2.  
  3. boolean record;
  4.  
  5. void setup() {
  6.   size(500, 500, P3D);
  7. }
  8.  
  9. void draw() {
  10.   if (record) {
  11.     beginRaw(SVG, "output.svg");
  12.   }
  13.  
  14.   // здесь рисуем графику:
  15.   background(204);
  16.   translate(width/2, height/2, -200);
  17.   rotateZ(0.2);
  18.   rotateY(mouseX/500.0);
  19.   box(200);
  20.  
  21.   if (record) {
  22.     endRaw();
  23.     record = false;
  24.   }
  25. }
  26.  
  27. // нажмите «R», чтобы записать текущий кадр:
  28. void keyPressed() {
  29.   if (key == 'r') {
  30.     record = true;
  31.   }
  32. }

Использование createGraphics() для создания SVG-файла

Чтобы сохранить SVG-файл при помощи функции createGraphics() – не используя блоки setup() и draw() – на объекте PGraphics необходимо вызвать функцию dispose(). Это то же самое, что и exit(), но без выхода из программы.

  1. import processing.svg.*;
  2.  
  3. PGraphics svg = createGraphics(300, 300, SVG, "output.svg");
  4. svg.beginDraw();
  5. svg.background(128, 0, 0);
  6. svg.line(50, 50, 250, 250);
  7. svg.dispose();
  8. svg.endDraw();

Дополнительные примечания к использованию визуализатора SVG

  • Если вам нужны 3D-данные, вместо SVG воспользуйтесь библиотекой DXF.
  • Использование hint(ENABLE_DEPTH_SORT) может улучшить визуальное качество 3D-графики, сохраняемой в 2D-файлы.
  • Многие функции (особенно для работы с пикселями) использовать с визуализатором SVG бессмысленно. Например, loadPixels(), updatePixels(), get(), set(), mask(), filter(), copy(), blend(), save() и image().
  • Опять же, функция exit() очень важна при использовании SVG вместе с size().

См.также

Внешние ссылки

  1. processing.org - SVG Export