Arduino:Примеры/Calibration

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Калибровка

В данном примере демонстрируется один из методов для калибровки входных сенсорных данных. В течение первых пяти секунд с момента запуска Arduino считывает данные, поступающие от сенсора, отслеживая самые высокие и низкие значения – они будут определены как максимум и минимум этого 5-секундного цикла.

Необходимое оборудование

• Плата Arduino;
• Светодиод;
• Аналоговый сенсор (к примеру, фотоэлемент или потенциометр);
• Резистор на 10 кОм;
• Резистор на 220 Ом;
• Макетная плата Breadboard;
• Провода-перемычки;

Цепь

Светодиод подсоедините к 9-ому цифровому контакту и к «земле» (через 220-омовый резистор). Одну ногу фотоэлемента подсоедините к 5-вольтовому контакту, а другую – к 0-ому аналоговому контакту и к «земле» (через 10 кОм резистор).

Схема

Код

Перед секцией setup()‎ задаем начальные значения для минимума и максимума.

int sensorMin = 1023;        // минимальное значение от сенсора
int sensorMax = 0;           // максимальное значение от сенсора

Может показаться, что тут нет никакой логики – максимум обозначен как 0, а минимум как 1023. Но дело в том, что это лишь исходные значения, от которых программа будет отталкиваться, определяя реальные максимум и минимум. То есть в переменной sensorMin изначально задается самый высокий минимум (1023), и самое маленькое число, которое будет ниже этого минимума, будет определено как новый минимум. В то же время в переменной sensorMax изначально задается самый низкий максимум (0), и самое большое число, которое будет выше этого максимума, будет определено как новый максимум. Делается это при помощи следующего фрагмента:

// считываем данные в течение первых пяти секунд:
 while (millis() < 5000) {
   sensorValue = analogRead(sensorPin);

   // записываем максимальное значение, считанное от сенсора:
   if (sensorValue > sensorMax) {
     sensorMax = sensorValue;
   }

   // записываем минимальное значение, считанное от сенсора:
   if (sensorValue < sensorMin) {
     sensorMin = sensorValue;
   }
 }

Таким образом, полученные максимум и минимум можно подогнать под диапазон между 0 и 255:

// калибруем данные от сенсора:
sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);

Вся программа будет выглядеть следующим образом:

/*
  Калибровка
 
 Демонстрирует один из методов для калибровки входных данных от сенсора. В течение первых 5 секунд программа определяет максимальное и минимальное значение этих данных. 
 Может показаться, что в исходных минимуме (1023) и максимуме (0) нет никакой логики. Но дело в том, что это лишь исходные значения, от которых программа будет отталкиваться, определяя реальные максимум и минимум. 
 То есть в переменной sensorMin изначально задается самый высокий минимум (1023), и самое маленькое число, которое будет ниже этого минимума, будет определено как новый минимум. В то же время в переменной sensorMax изначально задается самый низкий максимум (0), и самое большое число, которое будет выше этого максимума, будет определено как новый максимум.
 
 Цепь:
 * Аналоговый сенсор (например, потенциометр) подсоединен к 0-ому входному контакту, 5-вольтовому напряжению и «земле»
 * Светодиод подсоединен к 9-ому цифровому контакту и «земле»
 
Создан 29 октября 2008 Дэвидом А. Меллисом (David A Mellis),
модифицирован 30 августа 2011 Томом Иго (Tom Igoe)
 
 http://arduino.cc/en/Tutorial/Calibration
 
 Этот код не защищен авторским правом.
 
 */

// это константы – значения, которые не изменятся:
const int sensorPin = A0;    // контакт, к которому подсоединен сенсор
const int ledPin = 9;        // контакт, к которому подсоединен светодиод

// переменные:
int sensorValue = 0;         // значение, полученное от сенсора
int sensorMin = 1023;        // минимальное значение от сенсора
int sensorMax = 0;           // максимальное значение от сенсора


void setup() {
  // включаем светодиод, чтобы оповестить о начале калибровочного периода:
  pinMode(13, OUTPUT);
  digitalWrite(13, HIGH);

  // считываем данные в течение первых пяти секунд: 
  while (millis() < 5000) {
    sensorValue = analogRead(sensorPin);

    // записываем максимальное значение, считанное от сенсора:
    if (sensorValue > sensorMax) {
      sensorMax = sensorValue;
    }

    // записываем минимальное значение, считанное от сенсора:
    if (sensorValue < sensorMin) {
      sensorMin = sensorValue;
    }
  }

  // выключаем светодиод, оповещая о конце калибровочного периода:
  digitalWrite(13, LOW);
}

void loop() {
  // считываем данные от сенсора:
  sensorValue = analogRead(sensorPin);

  // калибруем данные от сенсора:
  sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);

  // на тот случай, если данные от сенсора будут за пределами необходимого диапазона, делаем так:
  sensorValue = constrain(sensorValue, 0, 255);

  // задаем светодиоду уровень яркости, опираясь на откалиброванное значение:
  analogWrite(ledPin, sensorValue);
}

См.также

1. while
2. millis()
3. constrain()
4. map()
5. if
6. AnalogInput
7. AnalogInOutSerial
8. Fade
9. Smoothing