Arduino:Справочник языка Arduino/Библиотеки/Mouse/Mouse.move()

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Функция Mouse.move()[1]

Передвигает курсор на экране компьютера, к которому подключена Arduino. Расчет новой позиции курсора выполняется всегда относительно предыдущей позиции курсора. Перед использованием функции Mouse.move() нужно сначала запустить функцию Mouse.begin().

Внимание! При использовании Mouse.move() «мышиный» функционал перейдет под управление Arduino. Поэтому перед тем, как использовать команду, убедитесь, что ваша цепь настроена таким образом, чтобы не терять управление компьютером. Для этого можно воспользоваться, к примеру, специальной кнопкой, которая будет включать/выключать управление мышью при помощи Arduino.

Синтаксис

Mouse.move(xVal, yPos, wheel)

Параметры

xVal  то, насколько нужно переместиться на оси X (signed char)
yPos  то, насколько нужно переместиться по оси Y (signed char)
wheel  то, насколько нужно прокрутить колесико мыши (signed char)

Что возвращает

Ничего.

Пример

const int xAxis = A1;         // данные от датчика по оси X  
const int yAxis = A2;         // данные от датчика по оси Y

int range = 12;               // результирующий диапазон для осей X и Y
int responseDelay = 2;        // задержка отклика мыши (в миллисекундах)
int threshold = range/4;      // пороговое значение, которое нужно преодолеть, чтобы курсор переместился
int center = range/2;         // значение, которое используется при расчете преодоления порога threshold
int minima[] = { 
  1023, 1023};                // минимальные значения для исходных данных от осей X и Y
int maxima[] = {
  0,0};                       // максимальные значения для исходных данных от осей X и Y
int axis[] = {
  xAxis, yAxis};              // номера контактов для X и Y
int mouseReading[2];          // результирующие значения для X и Y

void setup() {
 Mouse.begin();
}

void loop() {

// Считываем данные с обеих осей:
  int xReading = readAxis(0);
  int yReading = readAxis(1);

// Двигаем курсор мыши:
    Mouse.move(xReading, yReading, 0);
    delay(responseDelay);
}

/*
Считываем данные с осей (0 для X, 1 для Y), а затем подгоняем их под диапазон от 0 до <range>.
*/

int readAxis(int axisNumber) {
  int distance = 0;    // расстояние от центра результирующего диапазона (range)

  // Считываем входящие аналоговые данные:
  int reading = analogRead(axis[axisNumber]);

// Если считанное значение выходит за пределы максимума/минимума для этой оси,
// то делаем перерасчет этих максимума/минимума:
  if (reading < minima[axisNumber]) {
    minima[axisNumber] = reading;
  }
  if (reading > maxima[axisNumber]) {
    maxima[axisNumber] = reading;
  }

  // подгоняем считанное значение от аналогового датчика
  // к диапазону от 0 до <range>: 
  reading = map(reading, minima[axisNumber], maxima[axisNumber], 0, range);

 // если результирующее значение превышает порог threshold,
 // используем это значение:
  if (abs(reading - center) > threshold) {
    distance = (reading - center);
  } 

  // Ось X нужно инвертировать, чтобы подгонка данных 
  // для перемещения курсора прошла корректно:
  if (axisNumber == 1) {
    distance = -distance;
  }

  // Возвращаем distance для этой оси:
  return distance;
}

См.также

  1. Mouse.begin()
  2. Mouse.click()
  3. Mouse.end()
  4. Mouse.press()
  5. Mouse.release()
  6. Mouse.isPressed()

Внешние ссылки