Arduino:Библиотеки/EEPROM/put()

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.

Функция EEPROM.put()[1]

Записывает данные в EEPROM-память, но не напрямую, а через указание объекта (например, переменной), хранящего записываемое значение.

Синтаксис

EEPROM.put(address, data)

Параметры

address  участок EEPROM-памяти, куда будет выполнена запись. Значения начинаются с «0». Тип данных  int.
data  объект, значение которого нужно прочесть. Это может быть и примитивный тип данных (например, float), и пользовательский struct.

Что возвращает

Отсылку к объекту, где хранятся обработанные данные.

Примечание

Эта функция работает по принципу EEPROM.update(). То есть если записываемое значение идентично тому, что уже хранится в указанном участке EEPROM-памяти, то запись выполнена не будет.

Пример

/***
    Пример eeprom_put 

    Это пример, демонстрирующий работу функции EEPROM.put().
    Кроме того, этот скетч подготавливает EEPROM-данные 
    для скетча-примера eeprom_get.

    Обратите внимание, что функция EEPROM.put()
    работает по тому же принципу, что и EEPROM.update(). 
    То есть запись будет выполнена лишь в том случае,
    если новое значение отличается от предыдущего. 

    Автор – Кристофер Эндрюс (Christopher Andrews), 2015 год.
    Выпущено под лицензией MIT.
***/

#include <EEPROM.h>

struct MyObject {
  float field1;
  byte field2;
  char name[10];
};

void setup() {

  Serial.begin(9600);
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для моделей Arduino со штатным USB-портом)
  }

  float f = 123.456f;  // переменная для записи в EEPROM-память
  int eeAddress = 0;   // участок EEPROM-памяти, куда будут записаны данные


  // теперь одна простая функция, где первый аргумент – это адрес, а второй – объект:
  EEPROM.put(eeAddress, f);

  Serial.println("Written float data type!"); // "float-данные записаны!"

  /** функцию EEPROM.put() можно использовать и для пользовательских структур. **/

  // данные, которые будут записаны:
  MyObject customVar = {
    3.14f,
    65,
    "Working!" 
  }; // "Работает!"

  eeAddress += sizeof(float); // перемещаемся к участку EEPROM-памяти, находящемуся вслед за тем, где хранится переменная «f»

  EEPROM.put(eeAddress, customVar);
  Serial.print("Written custom data type! \n\nView the example sketch eeprom_get to see how you can retrieve the values!"); // "Данные пользовательского типа записаны! \n\nО том, как извлечь эти данные, смотрите в скетче-примере eeprom_get"
}

void loop() {
  /* пустой цикл */
}

См.также

  1. EEPROM.read()
  2. EEPROM.write()
  3. EEPROM.update()
  4. EEPROM.get()


Внешние ссылки