Arduino:Примеры/KeyboardLogout

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Выход из текущей пользовательской сессии

Этот пример демонстрирует, как при помощи библиотеки Keyboard выйти из текущей пользовательской сессии, просто подключив 2-ой цифровой контакт вашей Leonardo или Due к контакту с «землей».

Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Его задача заключается лишь в том, чтобы отправить на компьютер клавиатурную команду после того, как контакт будет подключен к «земле».

Необходимое оборудование

• Плата Arduino Leonardo, Arduino Micro или Arduino Due;
• Провод-перемычка;

Цепь

Подключите плату к компьютеру через microUSB-кабель. Чтобы запустить скетч, при помощи привода-перемычки соедините 2-ой контакт с «землей».

Код

Перед тем, как ставить программу на плату, не забудьте закомментировать (т.е. прикрыть слешами) в коде те ОС, которые не используете.

/*
  Выход из пользовательской сессии при помощи клавиатурных команд
 
  Этот скетч демонстрирует использование библиотеки Keyboard.
 
  Если вы подсоедините 2-ой контакт к «земле», это спровоцирует выход из пользовательской сессии.
  Для этого программа будет использовать следующие комбинации клавиш:
  На Windows – CTRL-ALT-DEL, а затем ALT-l
  На Ubuntu – CTRL-ALT-DEL и ENTER
  На OSX – CMD-SHIFT-q
 
  Для того, чтобы снова войти, нажмите пробел. 
 
  Цепь:
 * Плата Arduino Leonardo или Arduino Micro
 * Подключите 2-ой цифровой контакт к «земле».
 
  Создан 6 марта 2012,
  модифицирован 27 марта 2012 Томом Иго (Tom Igoe).
 
  Этот код не защищен авторским правом.
 
 http://www.arduino.cc/en/Tutorial/KeyboardLogout
 */
 
#define OSX 0
#define WINDOWS 1
#define UBUNTU 2

// Поменяйте значение этой переменной, если требуется, чтобы оно соответствовало вашей ОС:
int platform = OSX;

void setup() {
  // Делаем 2-ой цифровой контакт входным,
  // и включаем встроенный подтягивающий резистор,
  // чтобы значение на этом контакте было HIGH,
  // за исключением тех случаев, когда он будет подключен к «земле»:
  pinMode(2, INPUT_PULLUP);
  Keyboard.begin();
}
 
void loop() {
  while (digitalRead(2) == HIGH) {
    // Пока на 2-ой контакт не будет подано значение LOW, ничего не делаем:
    delay(500);
  }
  delay(1000);

  switch (platform) {
  case OSX:
   Keyboard.press(KEY_LEFT_GUI);
     // Выход из пользовательской сессии через комбинацию Shift-Q:
   Keyboard.press(KEY_LEFT_SHIFT); 
   Keyboard.press('Q');
    delay(100);
    Keyboard.releaseAll();
     // Жмем Enter, чтобы подтвердить выход:
    Keyboard.write(KEY_RETURN);  
    break;
  case WINDOWS:
     // Выход из пользовательской сессии через комбинацию CTRL-ALT-DEL:
    Keyboard.press(KEY_LEFT_CTRL);
    Keyboard.press(KEY_LEFT_ALT);
    Keyboard.press(KEY_DELETE);
    delay(100);
    Keyboard.releaseAll();
    // Жмем ALT-s, чтобы подтвердить выход:
    delay(2000);
    Keyboard.press(KEY_LEFT_ALT);
    Keyboard.press('l');
    Keyboard.releaseAll();
    break;
  case UBUNTU:
    // Выход из пользовательской сессии через комбинацию CTRL-ALT-DEL:
    Keyboard.press(KEY_LEFT_CTRL);
    Keyboard.press(KEY_LEFT_ALT);
    Keyboard.press(KEY_DELETE);
    delay(1000);
    Keyboard.releaseAll();
    // Жмем Enter, чтобы подтвердить выход:
    Keyboard.write(KEY_RETURN);
    break;
  }
// Ничего не делаем:
  while(true);
}

См.также

1. Keyboard.write()
2. Keyboard.print()
3. Keyboard.println()