Arduino:Примеры/Series2 IoSamples

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Получение данных от удаленного XBee-модуля (Series 2)

Этот пример показывает, как при помощи библиотеки XBee настроить XBee-модуль на получение данных от удаленного XBee-модуля. Работает только для XBee-модуля типа Series 2.

Код

/**
 * Автор – Эндрю Рэпп (Andrew Rapp). 2009 год, все права защищены.
 *
 * Этот файл – часть библиотеки XBee-Arduino.
 *
 * Библиотека XBee для Arduino – это бесплатное ПО: его можно 
 * распространять и/или модифицировать согласно условиям Универсальной 
 * общественной лицензии GNU, изданной Фондом свободного ПО – будь то 
 * 3-тья или более поздняя версия этой лицензии (на ваш выбор).
 *
 * Библиотека XBee-Arduino распространяется бесплатно в надежде на то, 
 * что окажется полезной, но БЕЗО ВСЯКОЙ ГАРАНТИИ; включая даже 
 * обязательную гарантию на КОММЕРЧЕСКОЕ КАЧЕСТВО и ПРИГОДНОСТЬ 
 * КОНКРЕТНОЙ ЦЕЛИ. Более подробно читайте в Универсальной 
 * общественной лицензии GNU.
 *
 * Вы должны получить копию Универсальной общественной лицензии GNU 
 * вместе с библиотекой XBee-Arduino. Если не получили, ее можно найти 
 * на http://www.gnu.org/licenses/.
 */

#include <XBee.h>
#include <SoftwareSerial.h> 

/*
Этот пример – только для XBee-модуля типа Series 2 (ZigBee).
Он принимает данные от удаленного XBee-модуля. У удаленного 
XBee-модуля IR должно быть больше «0», а также должен быть активирован 
как минимум один цифровой или аналоговый входной контакт.
Также к Arduino должен быть подключен XBee-координатор.
 
Чтобы видеть информацию об XBee-коммуникации, этот пример использует 
библиотеку SoftSerial. Я использую плату Modern Device USB BUB
(http://moderndevice.com/connect) и просматриваю выдачу при помощи 
монитора порта в IDE Arduino.
*/ 

// Задаем TX и RX контакты для NewSoftSerial.
// Подключаем 8-ой контакт Arduino к TX-контакту конвертера USB-Serial:
uint8_t ssRX = 8;
// Подключаем 9-ый контакт Arduino к RX-контакту конвертера USB-Serial:
uint8_t ssTX = 9;
// Не забудьте подключить все устройства к общей «земле»: XBee, 
// Arduino и конвертер USB-Serial
SoftwareSerial nss(ssRX, ssTX);

XBee xbee = XBee();

ZBRxIoSampleResponse ioSample = ZBRxIoSampleResponse();

XBeeAddress64 test = XBeeAddress64();

void setup() { 
  Serial.begin(9600);
  xbee.setSerial(Serial);
  // Запускаем коммуникацию SoftSerial:
  nss.begin(9600);
}

void loop() {
  // Пытаемся прочесть пакет:
  xbee.readPacket();

  if (xbee.getResponse().isAvailable()) {
    // Что-то получили

    if (xbee.getResponse().getApiId() == ZB_IO_SAMPLE_RESPONSE) {
      xbee.getResponse().getZBRxIoSampleResponse(ioSample);

      nss.print("Received I/O Sample from: ");  //  "Получили I/O порцию от: "
      
      nss.print(ioSample.getRemoteAddress64().getMsb(), HEX);  
      nss.print(ioSample.getRemoteAddress64().getLsb(), HEX);  
      nss.println("");
      
      if (ioSample.containsAnalog()) {
        nss.println("Sample contains analog data");  //  "Порция содержит аналоговые данные "
      }

      if (ioSample.containsDigital()) {
        nss.println("Sample contains digtal data");  //  "Порция содержит цифровые данные"
      }      

      // Считываем входные аналоговые данные:
      for (int i = 0; i <= 4; i++) {
        if (ioSample.isAnalogEnabled(i)) {
          nss.print("Analog (AI");
          nss.print(i, DEC);
          nss.print(") is ");
          nss.println(ioSample.getAnalog(i), DEC);
        }
      }

      // Считываем входные цифровые данные:
      for (int i = 0; i <= 12; i++) {
        if (ioSample.isDigitalEnabled(i)) {
          nss.print("Digital (DI");
          nss.print(i, DEC);
          nss.print(") is ");
          nss.println(ioSample.isDigitalOn(i), DEC);
        }
      }
      
      // Отображаем все данные, находящиеся в секции «frame data» API-фрейма:
      //for (int i = 0; i < xbee.getResponse().getFrameDataLength(); i++) {
      //  nss.print("byte [");
      //  nss.print(i, DEC);
      //  nss.print("] is ");
      //  nss.println(xbee.getResponse().getFrameData()[i], HEX);
      //}
    } 
    else {
      nss.print("Expected I/O Sample, but got ");  //  "Ожидалась I/O порция, но получили "
      nss.print(xbee.getResponse().getApiId(), HEX);
    }     
  } else if (xbee.getResponse().isError()) {
    nss.print("Error reading packet.  Error code: ");  //  "Ошибка при чтении пакета. Код ошибки: "  
    nss.println(xbee.getResponse().getErrorCode());
  }
}