Arduino:Примеры/Series2 Rx

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Получение пакетов и преобразование в ШИМ-сигнал (Series 2)

Этот пример показывает, как при помощи библиотеки XBee настроить XBee-модуль типа Series 2 на получение пакетов. Информация из полученных пакетов конвертируется в ШИМ-сигнал.

Код

/**
 * Автор – Эндрю Рэпп (Andrew Rapp). 2009 год, все права защищены.
 *
 * Этот файл – часть библиотеки XBee-Arduino.
 *
 * Библиотека XBee для Arduino – это бесплатное ПО: его можно 
 * распространять и/или модифицировать согласно условиям Универсальной 
 * общественной лицензии GNU, изданной Фондом свободного ПО – будь то 
 * 3-тья или более поздняя версия этой лицензии (на ваш выбор).
 *
 * Библиотека XBee-Arduino распространяется бесплатно в надежде на то, 
 * что окажется полезной, но БЕЗО ВСЯКОЙ ГАРАНТИИ; включая даже 
 * обязательную гарантию на КОММЕРЧЕСКОЕ КАЧЕСТВО и ПРИГОДНОСТЬ 
 * КОНКРЕТНОЙ ЦЕЛИ. Более подробно читайте в Универсальной 
 * общественной лицензии GNU.
 *
 * Вы должны получить копию Универсальной общественной лицензии GNU 
 * вместе с библиотекой XBee-Arduino. Если не получили, ее можно найти 
 * на http://www.gnu.org/licenses/.
 */
 
#include <XBee.h>

/*
Этот пример – для XBee-модуля Series 2. Он получает RX-пакет ZB, а затем использует эти данные, чтобы задать ШИМ-значение. Если будет получен какой-то непредусмотренный пакет, загорится светодиод, сообщающий об ошибках (errorLed).
*/

XBee xbee = XBee();
XBeeResponse response = XBeeResponse();
// Создаем многоразовые объекты для обрабатываемых ответов:
ZBRxResponse rx = ZBRxResponse();
ModemStatusResponse msr = ModemStatusResponse();

int statusLed = 13;
int errorLed = 13;
int dataLed = 13;

void flashLed(int pin, int times, int wait) {
    
    for (int i = 0; i < times; i++) {
      digitalWrite(pin, HIGH);
      delay(wait);
      digitalWrite(pin, LOW);
      
      if (i + 1 < times) {
        delay(wait);
      }
    }
}

void setup() {
  pinMode(statusLed, OUTPUT);
  pinMode(errorLed, OUTPUT);
  pinMode(dataLed,  OUTPUT);
  
  // Запускаем последовательную коммуникацию:
  Serial.begin(9600);
  xbee.begin(Serial);
  
  flashLed(statusLed, 3, 50);
}

// Постоянно считываем пакеты, ищем RX-пакет ZB или статус модема:
void loop() {
    
    xbee.readPacket();
    
    if (xbee.getResponse().isAvailable()) {
      // Что-то получили
      
      if (xbee.getResponse().getApiId() == ZB_RX_RESPONSE) {
        // Получили RX-пакет ZB
        
        // Теперь заполняем объект «rx»:
        xbee.getResponse().getZBRxResponse(rx);
            
        if (rx.getOption() == ZB_PACKET_ACKNOWLEDGED) {
            // отправитель получил подтверждение
            flashLed(statusLed, 10, 10);
        } else {
            // мы получили пакет, но отправитель не получил подтверждения
            flashLed(errorLed, 2, 20);
        }
        // Задаем ШИМ на светодиоде dataLed в соответствии 
        // с первым байтом в данных: 
        analogWrite(dataLed, rx.getData(0));
      } else if (xbee.getResponse().getApiId() == MODEM_STATUS_RESPONSE) { 
        xbee.getResponse().getModemStatusResponse(msr);
        // Локальный XBee-модуль отправляет это в ответ на 
        // определенные события (вроде ассоциации или диссоциации)
        
        if (msr.getStatus() == ASSOCIATED) {
          // Ассоциировались. Здорово! Активируем светодиод
          flashLed(statusLed, 10, 10);
        } else if (msr.getStatus() == DISASSOCIATED) {
          // Диссоциация... Активируем светодиод, чтобы сообщить об этом
          flashLed(errorLed, 10, 10);
        } else {
          // Другой статус
          flashLed(statusLed, 5, 10);
        }
      } else {
      	// Не то, что мы ожидали: 
        flashLed(errorLed, 1, 25);    
      }
    } else if (xbee.getResponse().isError()) {
      //nss.print("Error reading packet.  Error code: ");  //  "Ошибка при чтении пакета. Код ошибки: "
      //nss.println(xbee.getResponse().getErrorCode());
    }
}