Arduino:Примеры/Dump File

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Извлечение данных из файла на SD-карте и их отправка на компьютер

Этот пример показывает, как при помощи библиотеки SD считывать файл с SD-карты, а затем передавать его через последовательный порт. Более подробно о библиотеке SD можно прочесть тут.

Необходимое оборудование

• Плата Arduino или Genuino
• Модуль Arduino Ethernet Shield (или другая плата с SD-слотом)
• Отформатированная карта с файлом datalog.txt, содержащим какой-нибудь текст

Цепь

Плата Arduino или Genuino должна быть подключена к Ethernet-модулю, а также через USB-кабель – к компьютеру.

Схема

Код

Скетч ниже настроен для использования с Ethernet-модулем, который имеет встроенный SD-слот. В блоке setup() вызываем функцию SD.begin(), а затем в качестве CS-контакта делаем 4-ый контакт. Однако если вместо модуля Arduino Ethernet Shield будет использоваться другой модуль, вам нужно будет задействовать другой контакт.

На SD-карте должен быть файл под названием datalog.txt. В блоке loop() открываем этот файл при помощи функции SD.open(). Чтобы отправить файл на компьютер через последовательную коммуникацию, используем функцию Serial.print(), а чтобы прочитать данные, находящиеся в файле – dataFile.read().

/*
  Извлечение данных из файла на SD-карте и их отправка на компьютер 

 Этот пример показывает, как при помощи библиотеки SD 
 считывать файл, находящийся на SD-карте, и передавать его
 через последовательный порт.

 Цепь:
 * SD-карта, подключенная к шине SPI следующим образом: 
 ** MOSI – к 11-ому контакту на Arduino 
 ** MISO - к 12-ому контакту на Arduino 
 ** CLK – к 13-ому контакту на Arduino 
 ** CS – к 4-ому контакту

 Создан 22 декабря 2010 года Лимор Фрид (Limor Fried),
 модифицирован 9 апреля 2012 года Томом Иго (Tom Igoe).

 Этот код не защищен авторским правом.

 */

#include <SPI.h>
#include <SD.h>

const int chipSelect = 4;

void setup() {
  // запускаем последовательную коммуникацию и ждем открытия порта:
  Serial.begin(9600);
  while (!Serial) {
    ; // ждем подключения последовательного порта (нужно только для плат со штатным USB-портом)
  }


  Serial.print("Initializing SD card...");  //  "Инициализация SD-карты..."

  // смотрим, присутствует ли карта и может ли она быть инициализирована:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");  //  "Карта повреждена или отсутствует"
    // ничего не делаем:
    return;
  }
  Serial.println("card initialized.");  //  "карта инициализирована."

  // открываем файл (обратите внимание, что одновременно может быть 
  // открыт только один файл; то есть перед тем, как открывать
  // следующий файл, закройте этот):
  File dataFile = SD.open("datalog.txt");

  // если файл доступен, записываем в него данные:
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
    dataFile.close();
  }
  // если файл не открылся, сообщаем об ошибке:
  else {
    Serial.println("error opening datalog.txt");  //  "ошибка при открытии datalog.txt"
  }
}

void loop() {
}

См.также

1. SD library - Your reference for the SD Card library.
2. Notes on using SD cards – What you need to know when you use SD cards
3. CardInfo - Get info about your SD card.
4. Datalogger - How to log data from three analog sensors to an SD card.
5. Files - How to create and destroy an SD card file.
6. Listfiles - How print out the files in a directory on a SD card.
7. ReadWrite - How to read and write data to and from an SD card.