Arduino:Примеры/AnalogWriteMega

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Использование функции AnalogWrite для затухания-загорания светодиодов на Arduino Mega

В этом примере демонстрируется, как сделать так, чтобы один за одним затухали и загорались 12 светодиодов, подключенных к плате Arduino Mega.

Необходимое оборудование

• Плата Arduino Mega - 1 шт.;
• Светодиод - 12 шт.;
• Резистор на 220 Ом - 12 шт.;
• Провода-перемычки;
• Макетная плата - 1 шт. ;

Цепь

Рис. 1. Подключение 12 светодиодов к плате Arduino Mega.

Аноды (длинные ноги с положительным зарядом) 12-ти светодиодов подключите к цифровым контактам Arduino (со 2-го по 13-ый), но не напрямую, а через токоограничивающие резисторы номиналом 220 Ом. Катоды (короткие ноги с отрицательным зарядом) подключите к «земле» (GND).

Схема

Рис. 2. Схема подключения 12 светодиодов к плате Arduino Mega.

Код

Вначале займемся секцией * setup()‎ и впишем туда функцию for, задача которой – задать цифровые контакты со 2-го по 13-ый как выходные контакты. Далее перемещаемся в секцию loop(), где воспользуемся сразу тремя функциями for. Ниже – первая из них. С ее помощью код будет перемещаться от одного светодиода к другому – от самого «низкого» (lowestPin, т.е. от того, чья цифра меньше) к самому «высокому» (highestPin, т.е. к тому, чья цифра больше):

for (int thisPin =lowestPin; thisPin <= highestPin; thisPin++)

Теперь вторая – делаем так, чтобы светодиоды загорались один а другим. Программа последовательно выбирает то один, то другой выходной контакт (соответствующий тому или иному светодиоду), а затем передает ему значение переменной brightness. Значение этой переменной, тем временем, постоянно увеличивается по принципу: один цикл – плюс один пункт.

for (int brightness = 0; brightness < 255; brightness++) {
      analogWrite(thisPin, brightness);
      delay(2);
}

Когда широтно-импульсная модуляция (ШИМ) на выходном контакте достигает максимума (255), в дело вступает третья for. Ее задача – не увеличивать значение переменной brightness, а уменьшать ( по тому же принципу: один цикл – минус один пункт), тем самым снижая яркость светодиода, пока он не погаснет совсем:

for (int brightness = 255; brightness >= 0; brightness--) {
      analogWrite(thisPin, brightness);
      delay(2);
}

По достижении нуля программа делает задержку в 100 миллисекунд, а затем снова возвращается к первой for, берется за следующий светодиод и начинает все заново.

/*
  Использование функции analogWrite() на Arduino Mega
    
  Задает одновременное затухание/загорание светодиодов, 
подключенных к нескольким цифровым контактам – со 2-го по 13-ый.
  Скетч написан для Arduino Mega и с другими платами работать не будет.  
    
  Цепь:
  * Светодиоды подключены к цифровым контактам – со 2-го по 13-ый

  Создан 8 февраля 2009 Томом Иго (Tom Igoe)
  
  Этот код не защищен авторским правом.
  
 */
// Это константы – значения, которые не меняются. 
// Воспользуемся ими для того, чтобы дать названия используемым контактам:
const int lowestPin = 2;
const int highestPin = 13;


void setup() {
  // сделаем контакты со 2-го по 13-ый выходными контактами:
  for (int thisPin =lowestPin; thisPin <= highestPin; thisPin++) { 
    pinMode(thisPin, OUTPUT); 
  }
}

void loop() {
  // делаем перебор контактов – один за другим:
  for (int thisPin =lowestPin; thisPin <= highestPin; thisPin++) { 
    // повышаем яркость выбранного светодиода (thisPin) от нуля до максимума:
    for (int brightness = 0; brightness < 255; brightness++) {
      analogWrite(thisPin, brightness);
      delay(2);
    } 
    // понижаем яркость выбранного светодиода (thisPin) с максимума до нуля:
    for (int brightness = 255; brightness >= 0; brightness--) {
      analogWrite(thisPin, brightness);
      delay(2);
    } 
    // делаем задержку между манипуляциями со светодиодами:
    delay(100);
  }
}

См.также

1. for
2. analogWrite()
3. delay()
4. AnalogInput
5. AnalogInOutSerial
6. Fade
7. Calibration
8. ForLoop