Arduino:Примеры/pcdtest

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Тестовый скетч для библиотеки PCD8544

Это текстовый скетч для библиотеки PCD8544, который при помощи платы Arduino совершает с LCD-дисплеем PCD8544 различные действия: печатает текст, картинки, заставку и пр.

Код

 
/*********************************************************************
Это скетч-пример для монохромного LCD-дисплея Nokia 5110.

Купить его можно в магазине adafruit!
  ------> http://www.adafruit.com/products/338

Эти дисплеи используют SPI-коммуникацию: для интерфейса 
требуется 4-5 контактов.

Adafruit инвестировала время и ресурсы, создавая эту библиотеку
с открытым кодом. Пожалуйста, поддержите Adafruit и оборудование
с открытым кодом, покупая продукты Adafruit!

Написана Лимор Фрид (Limor Fried, Ladyada) для Adafruit Industries.
Лицензия BSD license, подробней читайте в файле «license.txt».

Весь текст выше и экран заставка должны быть включены 
при любом повторном распространении этой библиотеки.
*********************************************************************/

#include <SPI.h>
#include <Adafruit_GFX.h>
#include <Adafruit_PCD8544.h>

// Программный SPI-интерфейс (медленный, но есть гибкость 
// в выборе контактов):
// контакт 7 – тактовая частота (SCLK)
// контакт 6 – передача данных (DIN)
// контакт 5 – выбор между инструкциями и данными (D/C)
// контакт 4 – выбор чипа LCD-дипслея (CS)
// контакт 3 – сброс LCD-дисплея (RST)
Adafruit_PCD8544 display = Adafruit_PCD8544(7, 6, 5, 4, 3);

// Аппаратный SPI-интерфейс (более быстрый, но нужно использовать 
// строго определенные контакты):
// контакт 13 (на Arduino Uno; SCK) - тактовая частота (SCLK)
// контакт 11 (на Arduino Uno; MOSI) – передача данных (DIN)
// контакт 5 - выбор между инструкциями и данными (D/C)
// контакт 4 – выбор чипа LCD-дисплея (CS)
// контакт 3 – сброс LCD-дисплея (RST)
// Adafruit_PCD8544 display = Adafruit_PCD8544(5, 4, 3);
// Обратите внимание, что при использовании аппаратного SPI-интерфейса 
// контакты MISO и SS не используются, однако во время передачи данных 
// на них по-прежнему будет осуществляться запись и считывание. 
// Повнимательней с этими контактами!

#define NUMFLAKES 10
#define XPOS 0
#define YPOS 1
#define DELTAY 2


#define LOGO16_GLCD_HEIGHT 16
#define LOGO16_GLCD_WIDTH  16

static const unsigned char PROGMEM logo16_glcd_bmp[] =
{ B00000000, B11000000,
  B00000001, B11000000,
  B00000001, B11000000,
  B00000011, B11100000,
  B11110011, B11100000,
  B11111110, B11111000,
  B01111110, B11111111,
  B00110011, B10011111,
  B00011111, B11111100,
  B00001101, B01110000,
  B00011011, B10100000,
  B00111111, B11100000,
  B00111111, B11110000,
  B01111100, B11110000,
  B01110000, B01110000,
  B00000000, B00110000 };

void setup()   {
  Serial.begin(9600);

  display.begin();
  // инициализация завершена

  // здесь можно поменять контрастность:
  display.setContrast(50);

  display.display(); // показываем заставку
  delay(2000);
  display.clearDisplay();   // очищаем экран и буфер

  // рисуем один пиксель:
  display.drawPixel(10, 10, BLACK);
  display.display();
  delay(2000);
  display.clearDisplay();

  // рисуем много линий:
  testdrawline();
  display.display();
  delay(2000);
  display.clearDisplay();

  // рисуем прямоугольники:
  testdrawrect();
  display.display();
  delay(2000);
  display.clearDisplay();

  // рисуем много прямоугольников:
  testfillrect();
  display.display();
  delay(2000);
  display.clearDisplay();

  // рисуем много кругов:
  testdrawcircle();
  display.display();
  delay(2000);
  display.clearDisplay();

  // рисуем круг с радиусом в 10 пикселей:
  display.fillCircle(display.width()/2, display.height()/2, 10, BLACK);
  display.display();
  delay(2000);
  display.clearDisplay();

  testdrawroundrect();
  delay(2000);
  display.clearDisplay();

  testfillroundrect();
  delay(2000);
  display.clearDisplay();

  testdrawtriangle();
  delay(2000);
  display.clearDisplay();
   
  testfilltriangle();
  delay(2000);
  display.clearDisplay();

  // рисуем первые 12 символов шрифта:
  testdrawchar();
  display.display();
  delay(2000);
  display.clearDisplay();

  // тесты, проверяющие печать текста:
  display.setTextSize(1);
  display.setTextColor(BLACK);
  display.setCursor(0,0);
  display.println("Hello, world!");  //  "Привет, мир!"
  display.setTextColor(WHITE, BLACK); // «инвертированный» текст
  display.println(3.141592);
  display.setTextSize(2);
  display.setTextColor(BLACK);
  display.print("0x"); display.println(0xDEADBEEF, HEX);
  display.display();
  delay(2000);

  // демонстрация вращения:
  display.clearDisplay();
  display.setRotation(1);  // вращаем на 90 градусов по часовой стрелке; чтобы вращать еще дальше, используйте «2» или «3»
  display.setTextSize(1);
  display.setTextColor(BLACK);
  display.setCursor(0,0);
  display.println("Rotation");    //  "Вращение"
  display.setTextSize(2);
  display.println("Example!");  //  "Пример!"
  display.display();
  delay(2000);

  // инвертируем вращение:
  display.setRotation(0);

  // миниатюрная картинка:
  display.clearDisplay();
  display.drawBitmap(30, 16,  logo16_glcd_bmp, 16, 16, 1);
  display.display();

  // инвертируем дисплей:
  display.invertDisplay(true);
  delay(1000); 
  display.invertDisplay(false);
  delay(1000); 

  // рисуем иконку и «анимируем» движение:
  testdrawbitmap(logo16_glcd_bmp, LOGO16_GLCD_WIDTH, LOGO16_GLCD_HEIGHT);
}


void loop() {
  
}


void testdrawbitmap(const uint8_t *bitmap, uint8_t w, uint8_t h) {
  uint8_t icons[NUMFLAKES][3];
  randomSeed(666);     // любое значение
 
  // инициализируем:
  for (uint8_t f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS] = random(display.width());
    icons[f][YPOS] = 0;
    icons[f][DELTAY] = random(5) + 1;
    
    Serial.print("x: ");
    Serial.print(icons[f][XPOS], DEC);
    Serial.print(" y: ");
    Serial.print(icons[f][YPOS], DEC);
    Serial.print(" dy: ");
    Serial.println(icons[f][DELTAY], DEC);
  }

  while (1) {
    // рисуем каждую иконку:
    for (uint8_t f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], logo16_glcd_bmp, w, h, BLACK);
    }
    display.display();
    delay(200);
    
    // затем стираем и двигаем:
    for (uint8_t f=0; f< NUMFLAKES; f++) {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS],  logo16_glcd_bmp, w, h, WHITE);
      // двигаем:
      icons[f][YPOS] += icons[f][DELTAY];
      // если исчезла, инициализируем заново:
      if (icons[f][YPOS] > display.height()) {
	icons[f][XPOS] = random(display.width());
	icons[f][YPOS] = 0;
	icons[f][DELTAY] = random(5) + 1;
      }
    }
   }
}


void testdrawchar(void) {
  display.setTextSize(1);
  display.setTextColor(BLACK);
  display.setCursor(0,0);

  for (uint8_t i=0; i < 168; i++) {
    if (i == '\n') continue;
    display.write(i);
    //if ((i > 0) && (i % 14 == 0))
      //display.println();
  }    
  display.display();
}

void testdrawcircle(void) {
  for (int16_t i=0; i<display.height(); i+=2) {
    display.drawCircle(display.width()/2, display.height()/2, i, BLACK);
    display.display();
  }
}

void testfillrect(void) {
  uint8_t color = 1;
  for (int16_t i=0; i<display.height()/2; i+=3) {
    // alternate colors
    display.fillRect(i, i, display.width()-i*2, display.height()-i*2, color%2);
    display.display();
    color++;
  }
}

void testdrawtriangle(void) {
  for (int16_t i=0; i<min(display.width(),display.height())/2; i+=5) {
    display.drawTriangle(display.width()/2, display.height()/2-i,
                     display.width()/2-i, display.height()/2+i,
                     display.width()/2+i, display.height()/2+i, BLACK);
    display.display();
  }
}

void testfilltriangle(void) {
  uint8_t color = BLACK;
  for (int16_t i=min(display.width(),display.height())/2; i>0; i-=5) {
    display.fillTriangle(display.width()/2, display.height()/2-i,
                     display.width()/2-i, display.height()/2+i,
                     display.width()/2+i, display.height()/2+i, color);
    if (color == WHITE) color = BLACK;
    else color = WHITE;
    display.display();
  }
}

void testdrawroundrect(void) {
  for (int16_t i=0; i<display.height()/2-2; i+=2) {
    display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, BLACK);
    display.display();
  }
}

void testfillroundrect(void) {
  uint8_t color = BLACK;
  for (int16_t i=0; i<display.height()/2-2; i+=2) {
    display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, color);
    if (color == WHITE) color = BLACK;
    else color = WHITE;
    display.display();
  }
}
   
void testdrawrect(void) {
  for (int16_t i=0; i<display.height()/2; i+=2) {
    display.drawRect(i, i, display.width()-2*i, display.height()-2*i, BLACK);
    display.display();
  }
}

void testdrawline() {  
  for (int16_t i=0; i<display.width(); i+=4) {
    display.drawLine(0, 0, i, display.height()-1, BLACK);
    display.display();
  }
  for (int16_t i=0; i<display.height(); i+=4) {
    display.drawLine(0, 0, display.width()-1, i, BLACK);
    display.display();
  }
  delay(250);
  
  display.clearDisplay();
  for (int16_t i=0; i<display.width(); i+=4) {
    display.drawLine(0, display.height()-1, i, 0, BLACK);
    display.display();
  }
  for (int8_t i=display.height()-1; i>=0; i-=4) {
    display.drawLine(0, display.height()-1, display.width()-1, i, BLACK);
    display.display();
  }
  delay(250);
  
  display.clearDisplay();
  for (int16_t i=display.width()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, i, 0, BLACK);
    display.display();
  }
  for (int16_t i=display.height()-1; i>=0; i-=4) {
    display.drawLine(display.width()-1, display.height()-1, 0, i, BLACK);
    display.display();
  }
  delay(250);

  display.clearDisplay();
  for (int16_t i=0; i<display.height(); i+=4) {
    display.drawLine(display.width()-1, 0, 0, i, BLACK);
    display.display();
  }
  for (int16_t i=0; i<display.width(); i+=4) {
    display.drawLine(display.width()-1, 0, i, display.height()-1, BLACK); 
    display.display();
  }
  delay(250);
}