Arduino:Примеры/RobotRunawayRobot

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Избегание препятствий[1]

Ваш робот врезается в стены? Данный скетч быстро решает эту проблему. Будучи оснащенным ультразвуковым дальномером, робот сможет понимать, есть ли впереди него препятствие, и уклониться от него, чтобы избежать столкновения.

Необходимое оборудование

  • Arduino Robot;
  • Ультразвуковой дальномер;
  • Кабель для подключения дальномера;

Инструкция

  1. Подключите дальномер к контакту TK1;
  2. Зафиксируйте датчик в передней части робота;
  3. Загрузите скетч, отключите USB и включите питание;
  4. Поставьте робота на пол;
  5. Робот начнет перемещаться, избегая находящиеся впереди него препятствия;
  6. Если вы хотите поменять дальность обнаружения, найдите в коде строчку «while (getDistance() <20)», где «20» означает «20 сантиметров». Поменяйте эту цифру на какую-нибудь другую и попробуйте, какой получится новая чувствительность;
  7. Кроме того, вы можете поменять и скорость робота. Небольшая подсказка – ищите в коде функцию motorWrite();

Пробуем

LottieLemon Runaway 780.png

Робот, избегающий препятствия

Код

/* Уклонение от препятствий

Поиграем в салочки? Благодаря ультразвуковому дальномеру робот
получает возможность определять и уклоняться от находящихся
впереди него препятствий. Отныне он больше никогда не врежется 
в стену!
 
Вам надо подключить ультразвуковой дальномер к контакту M1.

Цепь:
* Arduino Robot
* Ультразвуковой дальномер вроде Maxbotix EZ10 (с аналоговым выходом)

Создан 1 мая 2013 Х. Янгом (X. Yang),
модифицирован 12 мая 2013 Д. Куартиллье (D. Cuartielles).

Этот код не защищен авторским правом.
*/

// Подключаем библиотеку робота:
#include <ArduinoRobot.h>
#include <Wire.h>
#include <SPI.h>

int sensorPin = M1;  // контакт, используемый для датчика

void setup() {
  // Инициализируем робота, SD-карту и дисплей:
  Serial.begin(9600);
  Robot.begin();
  Robot.beginTFT();
  Robot.beginSD();
  Robot.displayLogos();

  // Рисуем на экране лицо:
  setFace(true);
}

void loop() {
  // Если путь заблокирован, поворачиваем, пока он не освободится:
  while (getDistance() < 40) { // если до преграды как минимум 20 см
    setFace(false); // делаем лицо печальным
    Robot.motorsStop(); // останавливаем моторы
    delay(1000); // немного ждем
    Robot.turn(90); // поворачиваем вправо и пробуем снова
    setFace(true); // делаем счастливое лицо
  }
  // если впереди нет никаких преград, продолжаем движение:
  Robot.motorsWrite(255, 255);
  delay(100);
}

// Функция, с помощью которой мы будем возвращать
// информацию о дистанции в сантиметрах:
float getDistance() {
  // Считываем данные от датчика:
  int sensorValue = Robot.analogRead(sensorPin);
  // Конвертируем данные от датчика в сантиметры:
  float distance_cm = sensorValue * 1.27;
  return distance_cm;
}

// Функция для «перемены настроения», т.е. для того, чтобы
// лицо робота становилось либо печальным, либо счастливым:
void setFace(boolean onOff) {
  if (onOff) {
    // Если «true», делаем счастливое лицо:
    Robot.background(0, 0, 255);
    Robot.setCursor(44, 60);
    Robot.stroke(0, 255, 0);
    Robot.setTextSize(4);
    Robot.print(":)");
  } else {
    // Если «false», делаем печальное лицо:
    Robot.background(255, 0, 0);
    Robot.setCursor(44, 60);
    Robot.stroke(0, 255, 0);
    Robot.setTextSize(4);
    Robot.print("X(");
  }
}

См.также

  1. begin()
  2. motorsWrite()
  3. turn()

Внешние ссылки