Arduino:Примеры/ButtonMouseControl

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Управление мышью при помощи кнопок

При помощи библиотеки Mouse и платы Arduino (в версиях Leonardo, Micro или Due) вы можете управлять экранным курсором компьютера. Конкретно в этом примере для этого используются пять кнопок: четыре отвечают за движение курсора (вверх, вниз, влево, вправо), а пятая – за левый клик мышью.

При перемещении курсора за точку отчета берется его предыдущее положение. То есть, при нажатии на одну из «двигающих» кнопок новая позиция курсора будет высчитываться в зависимости от его предыдущей позиции. Таким образом, при нажатии на одну из «двигающих» кнопок Arduino передвинет курсор в соответствующем направлении – значение HIGH («кнопка нажата»), поданное на определенный контакт, будет сигналом для перемещения курсора на 5 пунктов.

Пятая кнопка отвечает за клик левой кнопкой мыши – если на нее нажать, Arduino перешлет информацию об этом на компьютер. Впрочем, компьютер распознает это действие только после того, как вы уберете палец с кнопки.

Внимание! При использовании команды Mouse.move() Arduino перехватит роль мышки на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над мышкой при использовании этого скетча. Его задача заключается лишь в том, чтобы обновлять позицию курсора при нажатии на «двигающие» кнопки.

Необходимое оборудование

• Плата Arduino (Leonardo, Micro или Due);
• 5 кнопок;
• Пять резисторов на 10 кОм;
• Провода-перемычки;
• Макетная плата Breadboard;

Цепь

Подсоедините плату к компьютеру при помощи microUSB-кабеля. Кнопки подключите к цифровым контактам – со 2-ого по 6-ой. Обязательно воспользуйтесь стягивающими резисторами.

Схема

Код

/*
  Управление мышью при помощи кнопок
 
  Управляет мышью при помощи пяти кнопок, подсоединенных к Arduino (Leonardo или Micro).
 
  Оборудование:
 * Пять кнопок, подсоединенных ко 2-ому, 3-ему, 4-ому, 5-ому и 6-ому цифровым контактам
 
 
 Движение мыши высчитывается относительно предыдущей позиции курсора. 
 Этот скетч считывает данные от 4 кнопок, а затем использует их для перемещения курсора.
 
 ВНИМАНИЕ: При использовании команды Mouse.move() плата перехватывает управление мышью на себя! Поэтому перед использованием этой команды убедитесь, что у вас есть средства управления компьютером.
 
 Создан 15 марта 2012,
 модифицирован 27 марта 2012 Томом Иго (Tom Igoe). 
 
 Этот код не защищен авторским правом.
 
 */

// Задаем номера контактов для пяти кнопок:
const int upButton = 2;     
const int downButton = 3;        
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;

int range = 5;              // значение для дистанции перемещения курсора по оси X или Y (своего рода скорость перемещения курсора)
int responseDelay = 10;     // значение для задержки в отклике мыши (в миллисекундах)

void setup() {
  // Делаем «кнопочные» контакты входными:
  pinMode(upButton, INPUT);       
  pinMode(downButton, INPUT);       
  pinMode(leftButton, INPUT);       
  pinMode(rightButton, INPUT);       
  pinMode(mouseButton, INPUT);
  // Инициализируем управление мышью:
  Mouse.begin();
}

void loop() {
  // Считываем данные с кнопок:
  int upState = digitalRead(upButton);
  int downState = digitalRead(downButton);
  int rightState = digitalRead(rightButton);
  int leftState = digitalRead(leftButton);
  int clickState = digitalRead(mouseButton);

  // Высчитываем перемещение курсора, основываясь на состоянии кнопок:
  int  xDistance = (leftState - rightState)*range;
  int  yDistance = (upState - downState)*range;

  // Если X или Y не равно нулю, двигаемся:
  if ((xDistance != 0) || (yDistance != 0)) {
    Mouse.move(xDistance, yDistance, 0);
  }

  // Если пятая кнопка, отвечающая за левую кнопку мыши, нажата:
  if (clickState == HIGH) {
    // и если не нажата кнопка настоящей мыши:
    if (!Mouse.isPressed(MOUSE_LEFT)) {
    // то аналоговое нажатие переводим в цифровое:
      Mouse.press(MOUSE_LEFT); 
    }
  } 
  // Кроме того, если пятая кнопка, отвечающая за левую кнопку мыши, не нажата:
  else {
    // и если нажата левая кнопка реальной мышки:
    if (Mouse.isPressed(MOUSE_LEFT)) {
    // то аналоговое «ненажатие» переводим в цифровое
    // (другими словами, отпускаем кнопку):
      Mouse.release(MOUSE_LEFT); 
    }
  }

  // делаем задержку, чтобы мышь не двигалась слишком быстро:
  delay(responseDelay);
}

См.также

1. Mouse.click()
2. Mouse.move()
3. Mouse.press()
4. Mouse.release()
5. Mouse.isPressed()