Arduino:Библиотеки/GSM/Класс GSM SMS/flush()

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Функция flush()

Очищает память модема от всех отправленных сообщений после того, как все исходящие символы будут отправлены. Эта функция наследует у класса Stream.

Синтаксис

SMS.flush()

Параметры

Нет.

Что возвращает

Ничего.

Пример

/*
 Получатель SMS-сообщений

 Это скетч для GSM-модуля Arduino. 
 Он считывает входящие SMS и отображает их через монитор порта. 

 Цепь:
 * GSM-модуль 

 Создан 25 февраля 2012 года Хавьером Зорзано (Javier Zorzano) / TD

 Этот скетч не защищен авторским правом.
*/

// библиотеки:
#include <GSM.h>

// PIN-код:
#define PINNUMBER ""

// инициализируем экземпляр библиотеки:
GSM gsmAccess; // чтобы включить режим отладки, в скобочках нужно поставить параметр «true»
GSM_SMS sms;

char remoteNumber[20];  // массив для хранения исходящего номера

void setup() 
{
  // инициализируем последовательную коммуникацию:
  Serial.begin(9600); 

  Serial.println("SMS Messages Receiver");  //  "Получатель SMS-сообщений"

  // состояние соединения:
  boolean notConnected = true;

  // запускаем GSM-модуль; если у SIM-карты есть PIN-код,
  // вписываем его в скобочки функции begin():
  while(notConnected)
  {
    if(gsmAccess.begin(PINNUMBER)==GSM_READY)
      notConnected = false;
    else
    {
      Serial.println("Not connected");  //  "Соединение не удалось"
      delay(1000);
    }
  }

  Serial.println("GSM initialized");  //  "GSM инициализирован"
  Serial.println("Waiting for messages");  //  "Ожидание сообщений"
}

void loop() 
{
  char c;

  // проверяем, есть ли SMS, которые можно прочесть:  
  if (sms.available())
  {
    Serial.println("Message received from:");  //  "Сообщение получено от: "

    // Извлекаем исходящий номер:
    sms.remoteNumber(remoteNumber, 20);
    Serial.println(remoteNumber);

    // это пример того, как можно отклонить пришедшее SMS;    
    // в данном случае будут отклонены все SMS, начинающиеся с «#»:
    if(sms.peek()=='#')
    {
      Serial.println("Discarded SMS");  //  "Сообщение отклонено"
      sms.flush();
    }

    // считываем байты сообщения и выводим их на монитор порта:
    while(c=sms.read())
      Serial.print(c);

    Serial.println("\nEND OF MESSAGE");  //  "\nКОНЕЦ СООБЩЕНИЯ"

    // удаляем сообщение из памяти модема:
    sms.flush();
    Serial.println("MESSAGE DELETED");  //  "СООБЩЕНИЕ УДАЛЕНО"
  }

  delay(1000);

}

См.также

1. beginSMS()
2. ready()
3. endSMS()
4. available()
5. remoteNumber()
6. read()
7. write()
8. print()
9. peek()
10. flush()