Arduino:Примеры/Регистратор прохода через дверь

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Проверка/Оформление/Редактирование: Мякишев Е.А.


Cat poo.png Черновик


Регистратор прохода через дверь

Данный пример демонстрирует создание регистратора прохода через дверь с использованием платы Arduino Uno, любой платы расширения(шилд), работающей с SD-картами или MicroSD-картами(Cooking HAcks Micro SD shiled, Arduino Wireless SD shiled, Arduino Ethernet SD shiled, Arduino Wi-Fi SD shield, Adafruit data logging shield, SparkFun MicroSD shield), любой платы расширения(шилд) RTC и ИК-датчика расстояния Sharp GP2Y0A41SK0F.

Необходимые компоненты

Монтажная схема

Соедините выбранную вами плату расширения работающую с SD-картами или MicroSD-картами, плату расширения часов реального времени, ИК-датчик расстояния Sharp GP2Y0A41SK0F и плату Arduino Uno.

Для примеры мы взяли Arduino Ethernet SD shiled + Arduino Uno + Плата расширения RTC + ИК-датчик расстояния Sharp GP2Y0A41SK0F.

Arduino uno ethernet shield rtc ir sensor 1.png

Код

#include <SD.h>                                             // Подключаем библиотеку SD для работы с платой расширения, оснащенной SD-слотом
#include <Wire.h>                                           // Подключаем библиотеку Wire для работы с I2C устройствами, в данном случае с платой расширения RTC
#include "RTClib.h"                                         // Подключаем библиотеку RTClib

/*
Используемые по умолчанию контакты для библиотеки SD.
Если вы используете Arduino Ethernet SD shiled или любую
другую плату расширения использующую эти контакты,
то ничего менять не надо
MOSI = 11 контакт
MISO = 12 контакт
SCLK = 13 контакт
*/
 
#define CS_PIN 10                                           // Контакт выбора
                                                            // Примечание: если вы используете Arduino Ethernet SD shiled
                                                            // необходимо изменить номер контакта на 4.
                                                            // Если ваша плата расширения использует другой контакт
                                                            // вам необходимо его изменить на правильный.    
 
#define IR_PIN 0                                            // Датчик расстояния подключен к 0-му аналоговому входу
 
RTC_DS1307 RTC;                                             // Объявляем RTC объект

String year, month, day, hour, minute, second, time, date;  // Объявляем строковые переменный для хранения даты и времени

int raw = 0;                                                // Текущее значение датчика расстояния
int raw_prev = 0;                                           // Предыдущее значение датчика расстояния
boolean active = false;                                     // Переменная для хранения значения активности датчика расстояния
int update_time = 0;                                        // Счетчик для обновления                                  

void setup()
{
  Serial.begin(9600);                                       // Инициализация последовательного соединения на скорости 9600 бод
  Serial.println(F("Initializing Card"));                   // Распечатываем в мониторе последовательного порта "Initializing Card"("Инициализация карты")
  pinMode(CS_PIN, OUTPUT);                                  // Определяем CS(контакт выбора) контакт как выход
   
  Wire.begin();                                             // Инициализация шины I2C
  RTC.begin();                                              // Инициализация библиотеки RTC
 
  // Если микросхема RTC не запущена, то записываем данные часов компьютера при компиляции в RTC
  if (! RTC.isrunning())
  {
    Serial.println(F("RTC is NOT running!"));               // Распечатываем в мониторе последовательного порта "RTC is NOT running!"("Микросхема RTC не запущена!")
    RTC.adjust(DateTime(__DATE__, __TIME__)); 
  }
 
  // Инициализация SD-карты
  if (!SD.begin(CS_PIN))
  {
    Serial.println(F("Card Failure"));                      // Распечатываем в мониторе последовательного порта "Card Failure"("Сбой подключения к SD-карте")
    return;                                                 // Останавливаем выполнение программы
  }
  Serial.println(F("Card Ready"));                          // Распечатываем в мониторе последовательного порта "Card Ready"("Карта готова к работе")
 
  // Открываем файл и создаем заголовки
  File dataFile = SD.open("log.csv", FILE_WRITE);
  if (dataFile)
  {
    dataFile.println(F("\nNew Log Started!"));
    dataFile.println(F("Date,Time,Phrase"));
    dataFile.close();                                        // Внимание! Данные не будут записаны, пока вы не закроете соединение!
  
    // Распечатываем в мониторе последовательного порта те же данные для отладки 
    Serial.println(F("\nNew Log Started!"));                 // Распечатываем в мониторе последовательного порта "\nNew Log Started!"("Новый лог начат")
    Serial.println(F("Date,Time,Phrase"));                   // Распечатываем в мониторе последовательного порта "Date,Time,Phrase"
  }
  else
  {
    Serial.println(F("Couldn't open log file"));             // Распечатываем в мониторе последовательного порта "Couldn't open log file"("Не удалось открыть файл журнала")
  }
 
}

void loop()
{
  // Получаем текущую дату и время и сохраняем в строковых переменных
  DateTime datetime = RTC.now();
  year  = String(datetime.year(),  DEC);
  month = String(datetime.month(), DEC);
  day  = String(datetime.day(),  DEC);
  hour  = String(datetime.hour(),  DEC);
  minute = String(datetime.minute(), DEC);
  second = String(datetime.second(), DEC);
 
  // Объединяем строки для получения полной даты и времени
  date = year + "/" + month + "/" + day;
  time = hour + ":" + minute + ":" + second;
 
  raw = analogRead(IR_PIN);                                  // Счиитываем данные с датчика расстояния  
  
  // Если разница между текущим и предыдущим значением расстояния больше 75, то фиксируем проход через дверь
  if (abs(raw  -raw_prev) > 75)
    active = true;
  else
    active = false;
  raw_prev = raw;
 
  // Открываем файл и записываем в него данные если есть факт прохода через дверь или значение счетчика равно 20
  if (active || update_time == 20)
  {
    File dataFile = SD.open("log.csv", FILE_WRITE);
    if (dataFile)
    {
      dataFile.print(date);
      dataFile.print(F(","));
      dataFile.print(time);
      dataFile.print(F(","));
      dataFile.print(raw);
      dataFile.print(F(","));
      dataFile.println(active);
      dataFile.close();                                       // Внимание! Данные не будут записаны, пока вы не закроете соединение!
   
      // Распечатываем в мониторе последовательного порта те же данные для отладки 
      Serial.print(date);
      Serial.print(F(","));
      Serial.print(time);
      Serial.print(F(","));
      Serial.print(raw);
      Serial.print(F(","));
      Serial.println(active);
    }
    else
    {
      Serial.println(F("Couldn't open log file"));            // Распечатываем в мониторе последовательного порта "Couldn't open log file"("Не удалось открыть файл журнала") 
    }
    update_time = 0;                                          // Обнуляем счетчик
  }
  delay(50);                                                  // Задержка 50 мс.
  update_time++;                                              // Инструментируем счетчик
}

См.также

Внешние ссылки