Arduino:Примеры/Регулировка яркости светодиодов с помощью двух SPI цифровых потенциометров MCP4231

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Проверка/Оформление/Редактирование: Мякишев Е.А.

Регулировка яркости светодиодов с помощью двух SPI цифровых потенциометров MCP4231

Данный пример демонстрирует управление яркостью светодиодов с помощью цифровых потенциометров с использованием библиотеки SPI.

Необходимые компоненты

• Плата Arduino Uno, 1 шт.;
• Цифровой потенциометр MCP4231, 2 шт.;
• Резистор на 100 Ом, 4 шт.;
• Светодиод(можно разных цветов), 4 шт.;
• Макетная плата;
• Провода перемычки;

Монтажная схема

Соберите схему согласно монтажной схеме.

Схема подключения светодиода к потенциометру

Распиновка цифрового потенциометра MCP4231

Код

#include <SPI.h>                              // Подключение SPI библиотеки

// Помните при подключении библиотеки SPI
// контактами MOSI, MISO и CLK по умолчанию 
// будут следующие цифровые контакты Arduino:
// 11 = MOSI, 12 = MISO, 13 = CLK
const int SS1=10;                            // SS-контакт(Slave Select, т.е. контакт выбора ведомого устройства) 1-ой микросхемы MCP4231
const int SS2=9;                             // SS-контакт(Slave Select, т.е. контакт выбора ведомого устройства) 2-ой микросхемы MCP4231

const byte REG0=B00000000;                   // Команда записи в регистр 0 т.е. выбор 1-го потенциометра
const byte REG1=B00010000;                   // Команда записи в регистр 1 т.е. выбор 2-го потенциометра

void setup()
{
  pinMode(SS1, OUTPUT);                      // Установка SS1-контакта как выход
  pinMode(SS2, OUTPUT);                      // Установка SS2-контакта как выход
 
  SPI.begin();                               // Инициализация SPI-интерфейса
}

/*
* Функция управления яркостью светодиодов
* SS    - контакт выбора ведомого устройства(микросхемы MCP4231)
* reg   - адрес регистра потенциометра выбранной микросхемы MCP4231
* level - значение сопротивления
* Возможные варианты вызова:
* setLed(SS1, REG0, значение от 0 до 128) - выбор 1-ой микросхемы MCP4231, 1-го потенциометра и 1-ый светодиод(в данном случае)
* setLed(SS1, REG1, значение от 0 до 128) - выбор 1-ой микросхемы MCP4231, 2-го потенциометра и 3-ый светодиод(в данном случае)
* setLed(SS2, REG0, значение от 0 до 128) - выбор 2-ой микросхемы MCP4231, 1-го потенциометра и 2-ый светодиод(в данном случае)
* setLed(SS2, REG1, значение от 0 до 128) - выбор 2-ой микросхемы MCP4231, 2-го потенциометра и 4-ый светодиод(в данном случае)
*/
void setLed(int SS, int reg, int level)
{
  digitalWrite(SS, LOW);                    // Установить низкий уровень на контакте SS
  SPI.transfer(reg);                        // Отправка команды (адрес регистра 1-го или 2-го потенциометра)
  SPI.transfer(level);                      // Отправка значений (0-128) величины сопротивления
  digitalWrite(SS, HIGH);                   // Установить высокий уровень на контакте SS
}

void loop()
{
  for (int i = 0; i <= 128; i++)
  {
    setLed(SS1, REG0, i);
    setLed(SS1, REG1, i);
    setLed(SS2, REG0, i);
    setLed(SS2, REG1, i);
    delay(10);
  }
  delay(300);

  for (int i = 128; i >= 0; i--)
  {
    setLed(SS1, REG0, i);
    setLed(SS1, REG1, i);
    setLed(SS2, REG0, i);
    setLed(SS2, REG1, i);
    delay(10);
  } 
  delay(300);
}