Arduino:Примеры/EsploraLedShow2

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Световое шоу при помощи RGB-светодиода на Esplora (вариант 2)

Этот пример демонстрирует, как при помощи значений, считанных с аналоговых датчиков, менять яркость трех цветных светодиодов, из которых состоит RGB-светодиод.

В данном примере вы будете считывать амплитуду звука, «пойманного» микрофоном, количество света, «пойманного» световым датчиком, а также положение линейного потенциометра. Три этих датчика будут управлять яркостью красного, зеленого и синего цветов RGB-светодиода.

Необходимое оборудование

• Плата Arduino Esplora;

Цепь

Для этого примера нужна лишь Arduino Esplora.

Расположение на Esplora микрофона, слайдера-потенциометра, светового сенсора и управляемого ими RGB-светодиода

Код

RGB-светодиод состоит из трех «подсветодиодов», отвечающих за три основных цвета: красный, зеленый и синий. Каждым из них можно отдельно управлять при помощи трех функций из библиотеки Esplora: writeRed(), writeGreen() и writeBlue().

Впрочем, всеми тремя цветами можно управлять с помощью всего одной функции – writeRGB(), и в данном примере мы воспользуемся именно ей.

В этом примере для управления RGB-светодиодом (а точнее, трех «подсветодиодов», из которых он состоит) используется три разных датчика, имеющихся на Arduino Esplora. Амплитуда звука, «пойманного» микрофоном, будет отвечать за яркость красного светодиода. Позиция слайдера на линейном потенциометре будет отвечать за яркость зеленого светодиода. Интенсивность света, улавливаемого световым датчиком, будет отвечать за яркость синего светодиода.

/*

Управление RGB-светодиодом с помощью трех разных датчиков

Этот простой скетч считывает значения с микрофона, светового датчика и потенциометра-слайдера.
Затем эти значения используются, чтобы задать яркость 
красного, зеленого и синего каналов RGB-светодиода.
Красный канал будет меняться в зависимости от громкости звука, «услышанного» микрофоном,
зеленый – в зависимости от комнатного освещения,
а синий – в зависимости от позиции линейного потенциометра.

Создан 22 ноября 2012 Энрико Гуэли (Enrico Gueli, enrico.gueli@gmail.com),
модифицирован 24 ноября 2012 Томом Иго (Tom Igoe).

*/

#include <Esplora.h>

void setup() {
  // Инициализируем последовательную передачу данных:
  Serial.begin(9600);
}

int lowLight = 400;   // значение от светового датчика, когда он чем-нибудь прикрыт
int highLight = 1023; // максимальное значение, которое можно будет сосчитать со светового датчика
int minGreen = 0;     // минимальная яркость зеленого «подсветодиода»
int maxGreen = 100;   // максимальная яркость зеленого «подсветодиода»

void loop() {
  // Считываем значения от датчиков в переменные:
  int mic = Esplora.readMicrophone();
  int light = Esplora.readLightSensor();
  int slider = Esplora.readSlider();

  // Конвертируем данные от датчиков в уровни яркости:
  byte red   = constrain(mic, 0, 255);
  byte green = constrain(
                 map(light, lowLight, highLight, minGreen, maxGreen),
                 0, 255);
  byte blue  = slider / 4;

  // Выводим информацию об уровнях яркости на Serial Monitor (чтобы видеть, что происходит):
  Serial.print(red);
  Serial.print(' ');
  Serial.print(green);
  Serial.print(' ');
  Serial.println(blue);

  // Передаем информацию об уровнях яркости RGB-светодиоду.
  // Обратите внимание, что green всегда «0»:
  Esplora.writeRGB(red, green, blue);

  // Добавляем задержку, чтобы светодиод не моргал:
  delay(10);
}

См.также

1. readMicrophone()
2. readSlider()
3. readLightSensor()
4. writeRed()
5. writeGreen()
6. writeBlue()
7. writeRGB()