Arduino:Примеры/EsploraLightCalibrator

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Калибровка данных от светового датчика на Esplora[1]

Этот пример показывает, как считывать и калибровать значения от светового датчика Esplora. Калибровка может потребоваться, например, в том случае, если Esplora не будет постоянно находиться на одном и том же месте. То есть, если перенести плату из одной комнаты в другую, то там уровень освещения может быть другим, и этот пример как раз демонстрирует, как откалибровать данные от светового датчика, чтобы адаптировать его под максимум и минимум освещения, характерные для нового места. Для этого мы будем в течение нескольких секунд считывать значения с датчика, попутно сохраняя самые высокие и самые низкие значения, тем самым определяя их как новые минимум и максимум.

Считанные данные будут откалиброваны, а затем использованы для управления яркостью RGB-светодиода путем адаптации под меньший числовой диапазон.

Необходимое оборудование

  • Плата Arduino Esplora;

Цепь

Для этого примера нужна лишь Arduino Esplora. При помощи USB-кабеля подключите ее к компьютеру и откройте окно Serial Monitor.

Esplora LightCalibrator.png

Расположение на Esplora светового датчика и RGB-светодиода

Код

Создаем несколько переменных, в которых будем хранить минимальное и максимальное значения от светового датчика, а также еще одну, благодаря которой Esplora будет знать, был ли датчик откалиброван или нет.

Чтобы передавать данные на компьютер, вам нужно запустить последовательную передачу данных. Для этого воспользуемся функцией Serial.begin() и установим скорость соединения в 9600 бод.

Также воспользуемся функцией Esplora.readButton(), чтобы определять, нажата ли 1-ая кнопка или нет. Если нажата, вызываем функцию calibrate(), которую нужно будет вписать строчкой ниже.

Чтобы считывать данные со светового датчика, воспользуемся функцией Esplora.readLightSensor(). Она будет возвращать значения в диапазоне от 0 до 1023, которые затем будут записываться в переменную light.

Затем мы приспособим эти данные к диапазону работы RGB-светодиода. Чтобы сделать это, воспользуемся функцией map(), для которой потребуется 5 аргументов – название переменной, минимальное значение от датчика, максимальное значение от датчика, минимальное значение яркости для светодиода (0) и максимальное значение яркости для светодиода (255). Конвертированные значения запишем в новую переменную под названием brightness.

Функция map() не в силах ограничить значения диапазоном от 0 до 255. Поэтому, если значения от датчика будут меньше минимума или больше максимума, map() вернет значения которые будут меньше 0 и больше 255. Следовательно, чтобы остаться в пределах необходимого диапазона, воспользуемся функцией constrain().

Чтобы при помощи этих новых значений (в диапазоне от 0 до 255) поменять цвет светодиода, воспользуемся функцией Esplora.writeBlue().

Откалибровав данные, запускаем отправку данных на Serial Monitor при помощи функции Serial.print(). В итоге система должна показать примерно следующее:

light sensor level: 256 blue brightness: 10

Впрочем, пока не пройдет калибровка, а переменная calibrated не получит значение true, эти данные на Serial Monitor выведены не будут. Далее создаем свою собственную функцию под названием calibrate(). Чтобы сделать это вне блока loop(), пишем следующее:

void calibrate (){

}

Весь код, написанный между скобочками, будет выполняться всякий раз, когда вы будете использовать в своем скетче функцию calibrate().

В самой calibrate() вписываем функцию while(), чтобы код работал, пока будет нажата кнопка.

Считываем значения с датчика и сохраняем их в переменную. Затем задаем начальный минимум и, сравнивая его с поступающими данными, определяем новый минимум. Точно также поступаем и с максимумом.

Присваиваем переменной calibrated значение true, тем самым оповещая скетч о том, что датчик был откалиброван.

Когда вы отпустите кнопку, действие функции calibrate() завершится, и скетч вернется к блоку loop().

/*	
Калибровка светодиода на Esplora

Этот скетч демонстрирует, как считывать и калибровать данные от светового датчика.
Поскольку от места к месту уровень освещения может варьироваться,
данным от светового датчика может потребоваться калибровка.
Чтобы сделать это, мы будем несколько секунд считывать данные от датчика, определять самые высокие и самые низкие значения, 
а затем сохранять их в качестве новых максимума и минимума. 
И, наконец, эти максимум и минимум будут приспособлены под определенный числовой диапазон 
(в данном случае – диапазон яркости светодиода). 

Создан 22 декабря 2012 Томом Иго (Tom Igoe).

Этот код не защищен авторским правом.

*/

#include <Esplora.h>

// Переменные:
int lightMin = 1023;        // максимальное значение от датчика
int lightMax = 0;           // минимальное значение от датчика
boolean calibrated = false;  // переменная для обозначения того, прошел ли процесс калибровки или нет

void setup() {
  // Инициализируем последовательную передачу данных:
  Serial.begin(9600);

  // Выводим на Serial Monitor начальное сообщение:
  Serial.println("To calibrate the light sensor, press and hold Switch 1");  //  "Чтобы откалибровать световой датчик, нажмите и удерживайте 1-ую кнопку"
}

void loop() {
  // Если 1-ая кнопка нажата, запускаем функцию калибровки:
  if (Esplora.readButton(1) == LOW) {
    calibrate();
  }
  // Считываем данные от датчика в переменную:
  int light = Esplora.readLightSensor();

  // Адаптируем уровень освещения под диапазон яркости светодиода 
  // при помощи откалиброванных максимума и минимума:
  int brightness = map(light, lightMin, lightMax, 0, 255);
  // Ограничиваем яркость числовым диапазоном от 0 до 255:
  brightness = constrain(brightness, 0, 255);
  // Передаем эти данные на синий канал RGB-светодиода:
  Esplora.writeBlue(brightness);

  // Если калибровка прошла успешно,
  if (calibrated == true) {
  // выводим на Serial Monitor 
  // информацию об уровнях окружающего освещения и яркости светодиода
  // (чтобы быть в курсе того, что происходит):
    Serial.print("light sensor level: ");  //  "Уровень освещения: "
    Serial.print(light);
    Serial.print(" blue brightness: ");  //  "Яркость синего светодиода: "
    Serial.println(brightness);
  }
  // Добавляем задержку , чтобы светодиод не моргал:
  delay(10);
}

void calibrate() {
  // При помощи Serial Monitor говорим пользователю, что делать:
  Serial.println("While holding switch 1, shine a light on the light sensor, then cover it.");  //  "Нажимая на 1-ую кнопку, сначала посветите на световой датчик, а затем прикройте его рукой"

  // Пока пользователь нажимает на 1-ую кнопку, проводим калибровку:
  while (Esplora.readButton(1) == LOW) {
    // Считываем значения со светового датчика:
    int light  = Esplora.readLightSensor();

    // Записываем самое высокое значение, полученное от датчика:
    if (light > lightMax) {
      lightMax = light;
    }

    // Записываем самое низкое значение, полученное от датчика:
    if (light < lightMin) {
      lightMin = light;
    }
    // Отмечаем, что датчик был откалиброван
    calibrated = true;
  }
}

См.также

  1. Esplora.readButton()
  2. Esplora.readLightSensor()
  3. Esplora.writeBlue()
  4. Serial.begin()
  5. while()
  6. map()

Внешние ссылки